[gentoo-commits] gentoo-x86 commit in app-backup/snapper: snapper-9999.ebuild ChangeLog snapper-0.2.2-r1.ebuild snapper-0.2.2.ebuild

[Yixun Lan (dlan)]

dlan        14/05/22 09:56:05

  Modified:             snapper-9999.ebuild ChangeLog
  Added:                snapper-0.2.2-r1.ebuild
  Removed:              snapper-0.2.2.ebuild
  Log:
  drop using base.eclass, prune la, minor update
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xAABEFD55)

Revision  Changes    Path
1.2                  app-backup/snapper/snapper-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-9999.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-9999.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-9999.ebuild?r1=1.1&r2=1.2

Index: snapper-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-9999.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- snapper-9999.ebuild	21 May 2014 02:52:36 -0000	1.1
+++ snapper-9999.ebuild	22 May 2014 09:56:05 -0000	1.2
@@ -1,29 +1,21 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-9999.ebuild,v 1.1 2014/05/21 02:52:36 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-9999.ebuild,v 1.2 2014/05/22 09:56:05 dlan Exp $
 
 EAPI=5
 
-inherit base
-
-if [[ ${PV} = *9999* ]]; then
-	EGIT_REPO_URI="git://github.com/openSUSE/snapper.git"
-	AUTOTOOLS_AUTORECONF=1
-	AUTOTOOLS_IN_SOURCE_BUILD=1
-	inherit autotools-utils git-2
-	SRC_URI=""
-	KEYWORDS=""
-else
-	SRC_URI="ftp://ftp.suse.com/pub/projects/snapper/${P}.tar.bz2"
-	DOCS="AUTHORS README package/snapper.changes"
-	KEYWORDS="~amd64 ~x86"
-fi
+EGIT_REPO_URI="git://github.com/openSUSE/snapper.git"
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_IN_SOURCE_BUILD=1
+inherit eutils autotools-utils git-2
 
 DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
 HOMEPAGE="http://snapper.io/"
+SRC_URI=""
 
 LICENSE="GPL-2"
 SLOT="0"
+KEYWORDS=""
 IUSE="+btrfs ext4 lvm pam xattr"
 
 RDEPEND="dev-libs/boost[threads]
@@ -44,16 +36,17 @@
 	sys-devel/gettext
 	virtual/pkgconfig"
 
-DOCS="AUTHORS README"
+DOCS=( AUTHORS README package/snapper.changes )
 
-PATCHES=(
-	"${FILESDIR}"/cron-confd.patch
-	)
+src_prepare() {
+	epatch "${FILESDIR}"/cron-confd.patch
+	autotools-utils_src_prepare
+}
 
 src_configure() {
 	econf  \
 	--with-conf="/etc/conf.d" \
-	--docdir="/usr/share/doc/${P}" \
+	--docdir="/usr/share/doc/${PF}" \
 	$(use_enable btrfs) \
 	$(use_enable ext4) \
 	$(use_enable lvm) \
@@ -66,6 +59,7 @@
 	default
 	# Existing configuration file required to function
 	newconfd data/sysconfig.snapper snapper
+	prune_libtool_files
 }
 
 pkg_postinst() {



1.2                  app-backup/snapper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	21 May 2014 02:52:36 -0000	1.1
+++ ChangeLog	22 May 2014 09:56:05 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for app-backup/snapper
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v 1.1 2014/05/21 02:52:36 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/ChangeLog,v 1.2 2014/05/22 09:56:05 dlan Exp $
+
+*snapper-0.2.2-r1 (22 May 2014)
+
+  22 May 2014; Yixun Lan <dlan@g.o> -snapper-0.2.2.ebuild,
+  +snapper-0.2.2-r1.ebuild, snapper-9999.ebuild:
+  drop using base.eclass, prune la, minor update
 
 *snapper-9999 (21 May 2014)
 *snapper-0.2.2 (21 May 2014)



1.1                  app-backup/snapper/snapper-0.2.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-0.2.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-backup/snapper/snapper-0.2.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: snapper-0.2.2-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-backup/snapper/snapper-0.2.2-r1.ebuild,v 1.1 2014/05/22 09:56:05 dlan Exp $

EAPI=5

inherit eutils

DESCRIPTION="Command-line program for btrfs and ext4 snapshot management"
HOMEPAGE="http://snapper.io/"
SRC_URI="ftp://ftp.suse.com/pub/projects/snapper/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+btrfs ext4 lvm pam xattr"

RDEPEND="dev-libs/boost[threads]
	dev-libs/libxml2
	dev-libs/icu
	sys-apps/acl
	sys-apps/dbus
	sys-apps/util-linux
	sys-libs/zlib
	virtual/libintl
	btrfs? ( sys-fs/btrfs-progs )
	ext4? ( sys-fs/e2fsprogs )
	lvm? ( sys-fs/lvm2 )
	pam? ( sys-libs/pam )
	xattr? ( sys-apps/attr )"

DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/pkgconfig"

DOCS=( AUTHORS README )

src_prepare() {
	epatch "${FILESDIR}"/cron-confd.patch
}

src_configure() {
	econf  \
	--with-conf="/etc/conf.d" \
	--docdir="/usr/share/doc/${PF}" \
	$(use_enable btrfs) \
	$(use_enable ext4) \
	$(use_enable lvm) \
	$(use_enable pam) \
	$(use_enable xattr xattrs) \
	--disable-zypp
}

src_install() {
	default
	# Existing configuration file required to function
	newconfd data/sysconfig.snapper snapper
	prune_libtool_files
}

pkg_postinst() {
	elog "In order to use Snapper, you need to set up at least one config"
	elog "manually, or else the tool will get confused. Typically you should"
	elog "create a '/.snapshots' directory, then copy the file"
	elog "'/etc/snapper/config-templates/default' into '/etc/snapper/configs/',"
	elog "rename the file to 'root', and add its name into '/etc/conf.d/snapper'."
	elog "That will instruct Snapper to snapshot the root of the filesystem by"
	elog "default. For more information, see the snapper(8) manual page."
}