[gentoo-commits] gentoo-x86 commit in dev-python/basemap: basemap-1.0.5.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     12/08/24 07:44:59

  Modified:             ChangeLog
  Added:                basemap-1.0.5.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.0_alpha122/cvs/Linux x86_64)

Revision  Changes    Path
1.28                 dev-python/basemap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/basemap/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/basemap/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/basemap/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/basemap/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	27 Jun 2012 07:19:01 -0000	1.27
+++ ChangeLog	24 Aug 2012 07:44:59 -0000	1.28
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/basemap
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/basemap/ChangeLog,v 1.27 2012/06/27 07:19:01 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/basemap/ChangeLog,v 1.28 2012/08/24 07:44:59 patrick Exp $
+
+*basemap-1.0.5 (24 Aug 2012)
+
+  24 Aug 2012; Patrick Lauer <patrick@g.o> +basemap-1.0.5.ebuild:
+  Bump
 
 *basemap-1.0.4 (27 Jun 2012)
 



1.1                  dev-python/basemap/basemap-1.0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/basemap/basemap-1.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/basemap/basemap-1.0.5.ebuild?rev=1.1&content-type=text/plain

Index: basemap-1.0.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/basemap/basemap-1.0.5.ebuild,v 1.1 2012/08/24 07:44:59 patrick Exp $

EAPI=4
PYTHON_DEPEND="2"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"

inherit eutils distutils

DESCRIPTION="matplotlib toolkit to plot map projections"
HOMEPAGE="http://matplotlib.sourceforge.net/basemap/doc/html/ http://pypi.python.org/pypi/basemap"
SRC_URI="mirror://sourceforge/matplotlib/${P}.tar.gz"

IUSE="examples test"
SLOT="0"
KEYWORDS="~amd64 ~x86"
LICENSE="MIT GPL-2"

CDEPEND="sci-libs/shapelib
	>=dev-python/matplotlib-0.98
	>=sci-libs/geos-3.3.1[python]"

DEPEND="${CDEPEND}
	dev-python/setuptools"

RDEPEND="${CDEPEND}
	>=dev-python/pupynere-1.0.8
	dev-python/httplib2
	dev-python/dap"

DOCS="FAQ API_CHANGES"

REQUIRED_USE="test? ( examples )"

src_prepare() {
	# use /usr/share/data
	sed -i \
		-e "/_datadir.*=.*join/s|\(.*datadir.*=\).*|\1'${EROOT}usr/share/${PN}'|g" \
		"${S}"/lib/mpl_toolkits/basemap/*.py || die
	distutils_src_prepare
}

# This one works. examples appear to be need be installed to run.
src_test() {
	testing() {
		pushd "$(find build-${PYTHON_ABI}/ -namelib.linux-*)/mpl_toolkits/basemap/"
		PYTHONPATH=.:../../ "$(PYTHON)" test.py
		popd
	}
	VIRTUALX_COMMAND=python_execute_function virtualmake testing
}

src_install() {
	distutils_src_install --install-data="${EPREFIX}/usr/share/${PN}"

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples || die
	fi

	# respect FHS
	mv "${ED}$(python_get_sitedir -f)/mpl_toolkits/basemap/data" "${ED}usr/share/basemap"

	cleaning() {
		# clean up collision with matplotlib
		rm -f "${ED}$(python_get_sitedir)/mpl_toolkits/__init__.py"
		# respect FHS
		rm -fr "${ED}$(python_get_sitedir)/mpl_toolkits/basemap/data"
	}
	python_execute_function -q cleaning
}