[gentoo-commits] gentoo-x86 commit in dev-util/dialog: ChangeLog dialog-1.1.20111020-r1.ebuild dialog-1.1.20111020.ebuild

[Jeroen Roovers (jer)]

jer         11/12/28 16:44:25

  Modified:             ChangeLog
  Added:                dialog-1.1.20111020-r1.ebuild
  Removed:              dialog-1.1.20111020.ebuild
  Log:
  Install examples properly by Ago (bug #396195).
  
  (Portage version: 2.2.0_alpha83/cvs/Linux x86_64)

Revision  Changes    Path
1.142                dev-util/dialog/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.142&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?rev=1.142&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/ChangeLog?r1=1.141&r2=1.142

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v
retrieving revision 1.141
retrieving revision 1.142
diff -u -r1.141 -r1.142
--- ChangeLog	28 Dec 2011 10:09:35 -0000	1.141
+++ ChangeLog	28 Dec 2011 16:44:25 -0000	1.142
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/dialog
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.141 2011/12/28 10:09:35 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/ChangeLog,v 1.142 2011/12/28 16:44:25 jer Exp $
+
+*dialog-1.1.20111020-r1 (28 Dec 2011)
+
+  28 Dec 2011; Jeroen Roovers <jer@g.o> -dialog-1.1.20111020.ebuild,
+  +dialog-1.1.20111020-r1.ebuild:
+  Install samples properly by Ago (bug #396195).
 
   28 Dec 2011; Agostino Sarubbo <ago@g.o> dialog-1.1.20110707-r1.ebuild:
   Stable for AMD64, wrt bug #396161



1.1                  dev-util/dialog/dialog-1.1.20111020-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.1.20111020-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/dialog/dialog-1.1.20111020-r1.ebuild?rev=1.1&content-type=text/plain

Index: dialog-1.1.20111020-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/dialog/dialog-1.1.20111020-r1.ebuild,v 1.1 2011/12/28 16:44:25 jer Exp $

EAPI="4"

inherit multilib

MY_PV="${PV/1.1./1.1-}"
S=${WORKDIR}/${PN}-${MY_PV}
DESCRIPTION="tool to display dialog boxes from a shell"
HOMEPAGE="http://invisible-island.net/dialog/dialog.html"
SRC_URI="ftp://invisible-island.net/${PN}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="examples minimal nls static-libs unicode"

RDEPEND="
	>=app-shells/bash-2.04-r3
	!unicode? ( >=sys-libs/ncurses-5.2-r5 )
	unicode? ( >=sys-libs/ncurses-5.2-r5[unicode] )
"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
	!minimal? ( sys-devel/libtool )
	!<=sys-freebsd/freebsd-contrib-8.9999
"

src_prepare() {
	sed -i configure -e '/LIB_CREATE=/s:${CC}:& ${LDFLAGS}:g' || die
}

src_configure() {
	local ncursesw
	use unicode && ncursesw="w"
	econf \
		$(use_enable nls) \
		$(use_with !minimal libtool) \
		--with-ncurses${ncursesw}
}

src_install() {
	if use minimal; then
		emake DESTDIR="${D}" install
	else
		emake DESTDIR="${D}" install-full
	fi

	dodoc CHANGES README VERSION

	if use examples; then
		docinto samples
		dodoc $( find samples -maxdepth 1 -type f )
		docinto samples/copifuncs
		dodoc $( find samples/copifuncs -maxdepth 1 -type f )
		docinto samples/install
		dodoc $( find samples/install -type f )
	fi

	if ! use static-libs; then
		rm -f \
			"${D}"usr/$(get_libdir)/libdialog.a \
			"${D}"usr/$(get_libdir)/libdialog.la
	fi
}