[gentoo-commits] gentoo-x86 commit in dev-libs/xerces-c: xerces-c-2.7.0-r1.ebuild metadata.xml ChangeLog xerces-c-2.8.0.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    07/12/19 20:31:13

  Modified:             xerces-c-2.7.0-r1.ebuild metadata.xml ChangeLog
  Added:                xerces-c-2.8.0.ebuild
  Log:
  Version bump (bug #196800). Redigested version 2.7.0-r1 for new tarball (bug #192829).
  (Portage version: 2.1.4_rc10)

Revision  Changes    Path
1.12                 dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild?r1=1.11&r2=1.12

Index: xerces-c-2.7.0-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- xerces-c-2.7.0-r1.ebuild	3 Oct 2007 10:59:04 -0000	1.11
+++ xerces-c-2.7.0-r1.ebuild	19 Dec 2007 20:31:13 -0000	1.12
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild,v 1.11 2007/10/03 10:59:04 uberlord Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild,v 1.12 2007/12/19 20:31:13 dev-zero Exp $
 
 inherit eutils multilib versionator
 
@@ -18,7 +18,7 @@
 
 DEPEND="doc? ( app-doc/doxygen )"
 
-S=${WORKDIR}/${MY_PN}
+S=${WORKDIR}/${MY_P}
 
 pkg_setup() {
 	eval unset ${!LC_*} LANG



1.6                  dev-libs/xerces-c/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	15 Jul 2006 10:48:53 -0000	1.5
+++ metadata.xml	19 Dec 2007 20:31:13 -0000	1.6
@@ -4,3 +4,18 @@
 	<herd>cpp</herd>
 	<longdescription>xerces-c is a C++ library specializing in XML parsing. It is released by the Apache Foundation</longdescription>
 </pkgmetadata>
+<use>
+	<flag name='iconv'>Use iconv as message loader and transcoder (in general it
+	would be possible to use iconv only as message loader and something else
+	like icu or the native method as transcoder and vice-versa, but this is a
+	less common case and hard to handle)</flag>
+	<flag name='icu'>Use ICU as message loader and transcoder. ICU supports over
+	180 different encodings and/or locale specific message support.</flag>
+	<flag name='libwww'>Use the libwww library for fetching URLs, instead
+	of the builtin method</flag>
+	<flag name='native'>Use the 'native' method to fetch URLs. Please read
+	the documentation for this. This is only available on MacOS X</flag>
+	<flag name='threads'>Enable threading support through pthread (or other
+	libraries on AIX, IRIX, HPUX, Solars). Highly recommended.</flag>
+</use>
+



1.50                 dev-libs/xerces-c/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	3 Oct 2007 10:59:04 -0000	1.49
+++ ChangeLog	19 Dec 2007 20:31:13 -0000	1.50
@@ -1,6 +1,15 @@
 # ChangeLog for dev-libs/xerces-c
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.49 2007/10/03 10:59:04 uberlord Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/ChangeLog,v 1.50 2007/12/19 20:31:13 dev-zero Exp $
+
+*xerces-c-2.8.0 (19 Dec 2007)
+
+  19 Dec 2007; Tiziano Müller <dev-zero@g.o>
+  +files/xerces-c-2.8.0-64bit_cast.patch, +files/50xerces-c,
+  +files/xerces-c-2.8.0-icu_ressource_fix.patch, metadata.xml,
+  xerces-c-2.7.0-r1.ebuild, +xerces-c-2.8.0.ebuild:
+  Version bump (bug #196800). Redigested version 2.7.0-r1 for new tarball (bug
+  #192829).
 
   03 Oct 2007; Roy Marples <uberlord@g.o> xerces-c-2.7.0-r1.ebuild:
   Keyworded ~x86-fbsd, #194578 thanks to Andreas Nilsson.



1.1                  dev-libs/xerces-c/xerces-c-2.8.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-2.8.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/xerces-c/xerces-c-2.8.0.ebuild?rev=1.1&content-type=text/plain

Index: xerces-c-2.8.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-2.8.0.ebuild,v 1.1 2007/12/19 20:31:13 dev-zero Exp $

EAPI="1"

inherit eutils multilib versionator flag-o-matic toolchain-funcs

MY_PN="xerces-c-src"
MY_P=${MY_PN}_$(replace_all_version_separators _)

DESCRIPTION="A validating XML parser written in a portable subset of C++."
HOMEPAGE="http://xerces.apache.org/xerces-c/"
SRC_URI="mirror://apache/xerces/c/sources/${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc iconv icu libwww +threads elibc_Darwin elibc_FreeBSD"

RDEPEND="icu? ( dev-libs/icu )
	libwww? ( net-libs/libwww )
	iconv? ( virtual/libiconv )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	export ICUROOT="/usr"

	if use iconv && use icu ; then
		ewarn "This package can use iconv or icu for loading messages"
		ewarn "and transcoding, but not both. ICU will precede."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i \
		-e 's|sh ./configure.*|/usr/bin/true|' \
		src/xercesc/runConfigure || die "sed failed"

	sed -i \
		-e 's|-L/usr/lib64 -L/usr/lib -L/usr/local/lib -L/usr/ccs/lib|-L${XERCESCROOT}/lib|g' \
		-e 's|-L/usr/lib -L/usr/local/lib -L/usr/ccs/lib|-L${XERCESCROOT}/lib|g' \
		{samples,src/xercesc,tests}/Makefile.incl || die "sed for fixing library include path failed"

	sed -i \
		-e 's|${PREFIX}/lib|${PREFIX}/${MLIBDIR}|g' \
		-e 's|$(PREFIX)/lib|$(PREFIX)/${MLIBDIR}|g' \
		obj/Makefile.in src/xercesc/Makefile.incl || die "sed for fixing install lib dir failed"

	sed -i \
		-e 's|$(PREFIX)/msg|$(PREFIX)/share/xerces-c/msg|g' \
		-e 's|${PREFIX}/msg|${PREFIX}/share/xerces-c/msg|g' \
		src/xercesc/util/Makefile.in || die "sed for changing message catalogue directory failed"

	epatch \
		"${FILESDIR}/${P}-64bit_cast.patch" \
		"${FILESDIR}/${P}-icu_ressource_fix.patch"
}

src_compile() {
	export XERCESCROOT="${S}"
	cd src/xercesc

	local myconf
	use debug && myconf="-d"

	local bitstobuild="32"
	$(has_m64) && bitstobuild="64"

	# We need a case-switch here for other platforms,
	# but we wait until there's a real use case
	local target="linux"
	use elibc_FreeBSD && target="freebsd"
	use elibc_Darwin && target="macosx"

	local mloader="inmem"
	use iconv && mloader="iconv"
	use icu && mloader="icu"

	local transcoder="native"
	if use iconv ; then
		transcoder="IconvGNU"
		use elibc_FreeBSD && transcoder="IconvFBSD"
	fi
	use icu && transcoder="icu"

	# Other options are available for AIX, HP-11, IRIX or Solaris
	local thread="none"
	use threads && thread="pthread"

	# 'native' is only available on OSX (see use.mask) and 'socket'
	# isn't supposed to work. But the docs aren't clear about it, so
	# we would need some testing...
	local netaccessor="socket"
	use elibc_Darwin && netaccessor="native"
	use libwww && netaccessor="libwww"

	./runConfigure -p ${target} -c "$(tc-getCC)" -x "$(tc-getCXX)" \
		${myconf} -m ${mloader} -n ${netaccessor} -t ${transcoder} \
		-r ${thread} -b ${bitstobuild} > configure.vars || die "runConfigure failed"

	# This should be safe since runConfigure includes our C[XX]FLAGS
	eval $(grep export configure.vars)
	econf || die "econf failed"
	# Parallel building is horribly broken when not using --as-needed
	emake -j1 || die "emake failed"

	if use doc ; then
		cd "${S}/doc"
		doxygen || die "making docs failed"
	fi
}

src_install () {
	export XERCESCROOT="${S}"
	cd src/xercesc
	emake DESTDIR="${D}" MLIBDIR=$(get_libdir) install || die "emake failed"

	cd "${S}"
	doenvd "${FILESDIR}/50xerces-c"

	# Upstream seems to have forgotten this
	if use icu ; then
		dolib.so lib/libXercesMessages.so.28.0
		dosym libXercesMessages.so.28.0 /usr/$(get_libdir)/libXercesMessages.so.28
		dosym libXercesMessages.so.28.0 /usr/$(get_libdir)/libXercesMessages.so
	fi

	if use doc; then
		insinto /usr/share/doc/${PF}
		rm -rf samples/config* samples/Makefile* samples/runConfigure samples/install-sh samples/*/Makefile*
		doins -r samples
		dohtml -r doc/html/*
	fi

	dodoc STATUS credits.txt version.incl
	dohtml Readme.html

	unset XERCESCROOT
}

# There are tests available, but without a script to run them



-- 
gentoo-commits@g.o mailing list