[gentoo-commits] proj/kde:master commit in: kde-apps/print-manager/

[Andreas Sturmlechner]

commit:     ffc42d3c3698cb176b6d54f11e219f83fd2f67a0
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  1 09:03:23 2022 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Mar  1 09:03:23 2022 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=ffc42d3c

kde-apps/print-manager: 21.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../print-manager/print-manager-21.12.3.ebuild     | 62 ++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/kde-apps/print-manager/print-manager-21.12.3.ebuild b/kde-apps/print-manager/print-manager-21.12.3.ebuild
new file mode 100644
index 0000000000..ee4dbcb97b
--- /dev/null
+++ b/kde-apps/print-manager/print-manager-21.12.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.88.0
+PLASMA_MINIMAL=5.16.5
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Manage print jobs and printers in Plasma"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+gtk"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+	net-print/cups
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PLASMA_MINIMAL}:5
+	gtk? ( app-admin/system-config-printer )
+"
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! use gtk ; then
+		ewarn "By switching off \"gtk\" USE flag, you have chosen to do without"
+		ewarn "an important, though optional, runtime dependency:"
+		ewarn
+		ewarn "app-admin/system-config-printer"
+		ewarn
+		ewarn "${PN} will work nevertheless, but is going to be less comfortable"
+		ewarn "and will show the following error status during runtime:"
+		ewarn
+		ewarn "\"Failed to group devices: 'The name org.fedoraproject.Config.Printing"
+		ewarn "was not provided by any .service files'\""
+	fi
+}