[gentoo-commits] gentoo-x86 commit in app-editors/bluefish: ChangeLog bluefish-2.0.2.ebuild

[Hanno Boeck (hanno)]

hanno       10/11/30 03:38:12

  Modified:             ChangeLog
  Added:                bluefish-2.0.2.ebuild
  Log:
  bluefish bump
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.75                 app-editors/bluefish/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.75&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.75&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/ChangeLog?r1=1.74&r2=1.75

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v
retrieving revision 1.74
retrieving revision 1.75
diff -u -r1.74 -r1.75
--- ChangeLog	29 Nov 2010 19:54:15 -0000	1.74
+++ ChangeLog	30 Nov 2010 03:38:12 -0000	1.75
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/bluefish
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.74 2010/11/29 19:54:15 hanno Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.75 2010/11/30 03:38:12 hanno Exp $
+
+*bluefish-2.0.2 (29 Nov 2010)
+
+  29 Nov 2010; Hanno Boeck <hanno@g.o> +bluefish-2.0.2.ebuild:
+  Version bump, minor fixes.
 
   29 Nov 2010; Hanno Boeck <hanno@g.o>
   -files/bluefish-1.3.8-gucharmap-automagic.patch:



1.1                  app-editors/bluefish/bluefish-2.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/bluefish-2.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/bluefish/bluefish-2.0.2.ebuild?rev=1.1&content-type=text/plain

Index: bluefish-2.0.2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/bluefish-2.0.2.ebuild,v 1.1 2010/11/30 03:38:12 hanno Exp $

EAPI=2

PYTHON_DEPEND="python? 2"

inherit autotools eutils fdo-mime python

MY_P=${P/_/-}

DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer."
SRC_URI="http://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
HOMEPAGE="http://bluefish.openoffice.nl/"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
IUSE="gucharmap nls python spell"

RDEPEND="
	x11-libs/gtk+:2
	spell? ( app-text/enchant )"

DEPEND="${RDEPEND}
	dev-libs/glib:2
	dev-libs/libxml2
	dev-util/pkgconfig
	x11-libs/pango
	gucharmap? ( gnome-extra/gucharmap )
	nls? ( sys-devel/gettext dev-util/intltool )"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	if use python ; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare () {
	intltoolize --copy --force || die "intltoolize failed"
	for po_dir in src/plugin_*/po ; do
		cp po/Makefile.in.in ${po_dir}
	done

	# Fixes automagic installation of charmap plugin
	# Upstream bug: https://bugzilla.gnome.org/show_bug.cgi?id=570990
	epatch "${FILESDIR}"/${PN}-2.0.0-gucharmap-automagic.patch
	eautoreconf
}

src_configure() {
	econf \
		--docdir="/usr/share/doc/${PF}" \
		--disable-dependency-tracking \
		--disable-update-databases \
		--disable-xml-catalog-update \
		$(use_enable nls) \
		$(use_enable spell spell-check) \
		$(use_enable gucharmap charmap) \
		$(use_enable python)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	einfo "Adding XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
		--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
		--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
		/etc/xml/catalog \
		|| ewarn "Failed to add XML catalog entries."
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	einfo "Removing XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--del 'Bluefish/DTD/Bflang' \
		--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
		--del 'http://bluefish.openoffice.nl/DTD' \
		/etc/xml/catalog \
		|| ewarn "Failed to remove XML catalog entries."
}