[gentoo-commits] gentoo-x86 commit in app-admin/puppet: ChangeLog puppet-0.25.0_rc1.ebuild

[Matsuu Takuto (matsuu)]

matsuu      09/08/25 23:11:31

  Modified:             ChangeLog
  Added:                puppet-0.25.0_rc1.ebuild
  Log:
  Version bumped, bug #280364.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.42                 app-admin/puppet/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/puppet/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	21 Jul 2009 22:12:15 -0000	1.41
+++ ChangeLog	25 Aug 2009 23:11:31 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/puppet
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/puppet/ChangeLog,v 1.41 2009/07/21 22:12:15 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/puppet/ChangeLog,v 1.42 2009/08/25 23:11:31 matsuu Exp $
+
+*puppet-0.25.0_rc1 (25 Aug 2009)
+
+  25 Aug 2009; MATSUU Takuto <matsuu@g.o> +puppet-0.25.0_rc1.ebuild:
+  Version bumped, bug #280364.
 
   21 Jul 2009; MATSUU Takuto <matsuu@g.o> -puppet-0.24.7-r1.ebuild,
   -puppet-0.24.8.ebuild, puppet-0.24.8-r1.ebuild, files/puppet.init,



1.1                  app-admin/puppet/puppet-0.25.0_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/puppet-0.25.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-admin/puppet/puppet-0.25.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: puppet-0.25.0_rc1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/puppet/puppet-0.25.0_rc1.ebuild,v 1.1 2009/08/25 23:11:31 matsuu Exp $

EAPI="2"
inherit elisp-common eutils ruby

MY_P="${P/_}"
DESCRIPTION="A system automation and configuration management software"
HOMEPAGE="http://reductivelabs.com/projects/puppet"
SRC_URI="http://reductivelabs.com/downloads/${PN}/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE="augeas emacs ldap rrdtool shadow vim-syntax"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"

DEPEND="dev-lang/ruby[ssl]
	emacs? ( virtual/emacs )
	>=dev-ruby/facter-1.5.0"
RDEPEND="${DEPEND}
	>=app-portage/eix-0.9.4
	augeas? ( dev-ruby/ruby-augeas )
	ldap? ( dev-ruby/ruby-ldap )
	rrdtool? ( >=net-analyzer/rrdtool-1.2.23[ruby] )
	shadow? ( dev-ruby/ruby-shadow )"
#	|| (
#		www-servers/webrick
#		www-servers/mongrel
#	)
#	dev-ruby/diff-lcs
#	dev-ruby/rails

S="${WORKDIR}/${MY_P}"
USE_RUBY="ruby18"

SITEFILE="50${PN}-mode-gentoo.el"

pkg_setup() {
	enewgroup puppet
	enewuser puppet -1 -1 /var/lib/puppet puppet
}

src_prepare() {
	epatch "${FILESDIR}/${PN}-0.24.6-eix.patch"
}

src_compile() {
	if use emacs ; then
		elisp-compile ext/emacs/puppet-mode.el || die "elisp-compile failed"
	fi
}

src_install() {
	DESTDIR="${D}" ruby_einstall "$@" || die
	DESTDIR="${D}" erubydoc

	#
	# bug #237071
	#
	#doinitd conf/gentoo/init.d/puppetmaster
	newinitd "${FILESDIR}"/puppetmaster.init puppetmaster
	#doconfd conf/gentoo/conf.d/puppetmaster
	newconfd "${FILESDIR}"/puppetmaster.confd puppetmaster
	#doinitd conf/gentoo/init.d/puppet
	newinitd "${FILESDIR}"/puppet.init puppet
	doconfd conf/gentoo/conf.d/puppet

	# Initial configuration files
	keepdir /etc/puppet/manifests
	insinto /etc/puppet
	doins conf/gentoo/puppet/*

	# Location of log and data files
	keepdir /var/run/puppet
	keepdir /var/log/puppet
	keepdir /var/lib/puppet/ssl
	keepdir /var/lib/puppet/files
	fowners -R puppet:puppet /var/{run,log,lib}/puppet

	if use emacs ; then
		elisp-install ${PN} ext/emacs/puppet-mode.el* || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi

	if use ldap ; then
		insinto /etc/openldap/schema; doins ext/ldap/puppet.schema
	fi

	if use vim-syntax ; then
		insinto /usr/share/vim/vimfiles/syntax; doins ext/vim/syntax/puppet.vim
		insinto /usr/share/vim/vimfiles/ftdetect; doins	ext/vim/ftdetect/puppet.vim
	fi

	# ext and examples files
	for f in $(find ext examples -type f) ; do
		docinto "$(dirname ${f})"; dodoc "${f}"
	done
	docinto conf; dodoc conf/namespaceauth.conf
}

pkg_postinst() {
	elog
	elog "Please, *don't* include the --ask option in EMERGE_EXTRA_OPTS as this could"
	elog "cause puppet to hang while installing packages."
	elog
	elog "Puppet uses eix to get information about currently installed	packages,"
	elog "so please keep the eix metadata cache updated so puppet is able to properly"
	elog "handle package installations."
	elog
	elog "Currently puppet only supports adding and removing services to the default"
	elog "runlevel, if you want to add/remove a service from another runlevel you may"
	elog "do so using symlinking."
	elog

	if [ \
		-f "${ROOT}/etc/puppet/puppetd.conf" -o \
		-f "${ROOT}/etc/puppet/puppetmaster.conf" -o \
		-f "${ROOT}/etc/puppet/puppetca.conf" \
	] ; then
		elog
		elog "Please remove deprecated config files."
		elog "	/etc/puppet/puppetca.conf"
		elog "	/etc/puppet/puppetd.conf"
		elog "	/etc/puppet/puppetmasterd.conf"
		elog
	fi
	use emacs && elisp-site-regen
}
pkg_postrm() {
	use emacs && elisp-site-regen
}