[gentoo-commits] repo/gentoo:master commit in: dev-python/doit/

[Sebastian Pipping]

commit:     d1d0ee931d3f5c836b103555edd0aa848f34d5f5
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 20 22:51:07 2020 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Mon Jan 20 22:52:16 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d1d0ee93

dev-python/doit: 0.32.0 + EAPI 7 + enable tests

Closes: https://bugs.gentoo.org/693278
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.84, Repoman-2.3.20

 dev-python/doit/Manifest           |  1 +
 dev-python/doit/doit-0.32.0.ebuild | 70 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/dev-python/doit/Manifest b/dev-python/doit/Manifest
index d8214a7a17a..1889fcc12d2 100644
--- a/dev-python/doit/Manifest
+++ b/dev-python/doit/Manifest
@@ -1 +1,2 @@
 DIST doit-0.29.0.tar.gz 222341 BLAKE2B 8489568fe9236af04f87debfb4889840aa162d17d20f82ac0a9a22d1034b4c58976cd6829486a15b941ac1f50e7137c052fe332657c2b3f529fe2345bbcba2fc SHA512 a686457df31b414d0c3797789e0ae1ae5cdfa3674025236419cb59b254f342cd2db07911ef18b2cb576d8d817b44035b9372265b34b786b2779fb7074b394de1
+DIST doit-0.32.0.tar.gz 1437939 BLAKE2B 39134341582cd964630a1667c78b0e44eeb32406a06e3567123b820fb61cbee0f6a7c8879a84eed750860a365aa4c792e461bb1534c66e4f20a6289522dc8183 SHA512 d5c28a0c6a38648aeef58027b2246fc26360e133e91933f2244bd484f70d6d26110acbfec19c74d53c796e0bbae07a4bf6d76542d45e8b1a6b503c186bf2a68a

diff --git a/dev-python/doit/doit-0.32.0.ebuild b/dev-python/doit/doit-0.32.0.ebuild
new file mode 100644
index 00000000000..66a6cbdfb34
--- /dev/null
+++ b/dev-python/doit/doit-0.32.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_6 )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit eutils distutils-r1
+
+DESCRIPTION="Automation tool"
+HOMEPAGE="http://python-doit.sourceforge.net/ https://pypi.org/project/doit/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/configparser[${PYTHON_USEDEP}]' python2_7 pypy)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+DEPEND="test? ( ${RDEPEND}
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pyflakes[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}] )
+"
+PDEPEND=">=dev-python/doit-py-0.3.0[${PYTHON_USEDEP}]"
+
+# Required for test phase
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Disable test failing due to impact on PATH run in a sandbox
+	sed -e s':test_target:_&:' -i tests/test_cmd_strace.py || die
+
+	# Test requires connection to an absent database
+	sed -e s':testIgnoreAll:_&:' -i tests/test_cmd_ignore.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	local -x TMPDIR="${T}"
+	# disable tests where pypy's treatment of some tests' use of a db is incompatible
+
+	if [[ "${EPYTHON}" == pypy ]]; then
+		sed -e 's:test_remove_all:_&:' -i tests/test_dependency.py || die
+		sed -e 's:testForgetAll:_&:' -i tests/test_cmd_forget.py || die
+		sed -e 's:test_not_picklable:_&:' \
+			-e 's:test_task_not_picklabe_multiprocess:_&:' \
+			-i tests/test_runner.py || die
+	fi
+
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+src_install() {
+	use doc && HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_src_install
+}