[gentoo-commits] gentoo-x86 commit in media-libs/libmediainfo: metadata.xml ChangeLog libmediainfo-0.7.62.ebuild

[Tim Harder (radhermit)]

radhermit    13/03/02 06:51:52

  Modified:             metadata.xml ChangeLog
  Added:                libmediainfo-0.7.62.ebuild
  Log:
  Version bump. Add myself and upstream info to metadata.
  
  (Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.5                  media-libs/libmediainfo/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	22 Dec 2012 10:21:04 -0000	1.4
+++ metadata.xml	2 Mar 2013 06:51:52 -0000	1.5
@@ -1,5 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>video</herd>
+	<maintainer>
+		<email>radhermit@g.o</email>
+		<name>Tim Harder</name>
+	</maintainer>
+	<herd>video</herd>
+	<upstream>
+		<remote-id type="sourceforge">mediainfo</remote-id>
+	</upstream>
 </pkgmetadata>



1.63                 media-libs/libmediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.63&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?rev=1.63&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/ChangeLog?r1=1.62&r2=1.63

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v
retrieving revision 1.62
retrieving revision 1.63
diff -u -r1.62 -r1.63
--- ChangeLog	22 Dec 2012 10:21:53 -0000	1.62
+++ ChangeLog	2 Mar 2013 06:51:52 -0000	1.63
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libmediainfo
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.62 2012/12/22 10:21:53 radhermit Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/ChangeLog,v 1.63 2013/03/02 06:51:52 radhermit Exp $
+
+*libmediainfo-0.7.62 (02 Mar 2013)
+
+  02 Mar 2013; Tim Harder <radhermit@g.o> +libmediainfo-0.7.62.ebuild,
+  metadata.xml:
+  Version bump. Add myself and upstream info to metadata.
 
   22 Dec 2012; Tim Harder <radhermit@g.o> -libmediainfo-0.7.58.ebuild,
   -libmediainfo-0.7.59.ebuild, -libmediainfo-0.7.60.ebuild:



1.1                  media-libs/libmediainfo/libmediainfo-0.7.62.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.62.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.62.ebuild?rev=1.1&content-type=text/plain

Index: libmediainfo-0.7.62.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libmediainfo/libmediainfo-0.7.62.ebuild,v 1.1 2013/03/02 06:51:52 radhermit Exp $

EAPI=5

inherit autotools eutils flag-o-matic multilib

MY_PN="MediaInfo"
DESCRIPTION="MediaInfo libraries"
HOMEPAGE="http://mediainfo.sourceforge.net/"
SRC_URI="mirror://sourceforge/mediainfo/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"

LICENSE="LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl doc mms static-libs"

RDEPEND="sys-libs/zlib
	dev-libs/tinyxml2
	>=media-libs/libzen-0.4.28[static-libs=]
	curl? ( net-misc/curl )
	mms? ( >=media-libs/libmms-0.6.1[static-libs=] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-doc/doxygen )"

S=${WORKDIR}/${MY_PN}Lib/Project/GNU/Library

src_prepare() {
	# Don't force -O2 by default
	sed -i -e "s:-O2::" configure.ac

	append-cppflags -DMEDIAINFO_LIBMMS_DESCRIBE_SUPPORT=0
	eautoreconf
}

src_configure() {
	econf \
		--enable-shared \
		--with-libtinyxml2 \
		$(use_with curl libcurl) \
		$(use_with mms libmms) \
		$(use_enable static-libs static) \
		$(use_enable static-libs staticlibs)
}

src_compile() {
	default

	if use doc; then
		cd "${WORKDIR}/${MY_PN}Lib/Source/Doc"
		doxygen Doxyfile || die
	fi
}

src_install() {
	default

	edos2unix ${PN}.pc #414545
	insinto /usr/$(get_libdir)/pkgconfig
	doins ${PN}.pc

	for x in ./ Archive Audio Duplicate Export Image Multiple Reader Tag Text Video; do
		insinto /usr/include/${MY_PN}/${x}
		doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}/${x}/*.h
	done

	insinto /usr/include/${MY_PN}DLL
	doins "${WORKDIR}"/${MY_PN}Lib/Source/${MY_PN}DLL/*.h

	dodoc "${WORKDIR}"/${MY_PN}Lib/*.txt
	if use doc; then
		dohtml -r "${WORKDIR}"/${MY_PN}Lib/Doc/*
	fi

	prune_libtool_files
}