[gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: networkmanager-0.8.2-r9.ebuild ChangeLog networkmanager-0.8.2-r8.ebuild

[Mu Qiao (qiaomuf)]

qiaomuf     11/02/26 08:13:31

  Modified:             ChangeLog
  Added:                networkmanager-0.8.2-r9.ebuild
  Removed:              networkmanager-0.8.2-r8.ebuild
  Log:
  Display printable conn_name in nm-applet (bug #356337)
  
  (Portage version: 2.1.9.41/cvs/Linux x86_64)

Revision  Changes    Path
1.100                net-misc/networkmanager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.100&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.100&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.99&r2=1.100

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.99
retrieving revision 1.100
diff -u -r1.99 -r1.100
--- ChangeLog	26 Feb 2011 05:59:00 -0000	1.99
+++ ChangeLog	26 Feb 2011 08:13:31 -0000	1.100
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/networkmanager
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.99 2011/02/26 05:59:00 qiaomuf Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.100 2011/02/26 08:13:31 qiaomuf Exp $
+
+*networkmanager-0.8.2-r9 (26 Feb 2011)
+
+  26 Feb 2011; Mu Qiao <qiaomuf@g.o> -networkmanager-0.8.2-r8.ebuild,
+  +networkmanager-0.8.2-r9.ebuild,
+  files/networkmanager-0.8.2-ifnet-smarter-write.patch:
+  Display printable conn_name in nm-applet. (bug #356337)
 
 *networkmanager-0.8.2-r8 (26 Feb 2011)
 



1.1                  net-misc/networkmanager/networkmanager-0.8.2-r9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.8.2-r9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/networkmanager/networkmanager-0.8.2-r9.ebuild?rev=1.1&content-type=text/plain

Index: networkmanager-0.8.2-r9.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.8.2-r9.ebuild,v 1.1 2011/02/26 08:13:31 qiaomuf Exp $

EAPI="2"

inherit autotools eutils gnome.org linux-info

# NetworkManager likes itself with capital letters
MY_PN=${PN/networkmanager/NetworkManager}
MY_P=${MY_PN}-${PV}

DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
SRC_URI="${SRC_URI//${PN}/${MY_PN}}"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
IUSE="avahi bluetooth doc nss gnutls dhclient dhcpcd kernel_linux resolvconf connection-sharing"

RDEPEND=">=sys-apps/dbus-1.2
	>=dev-libs/dbus-glib-0.75
	>=net-wireless/wireless-tools-28_pre9
	>=sys-fs/udev-145[extras]
	>=dev-libs/glib-2.18
	>=sys-auth/polkit-0.92
	>=dev-libs/libnl-1.1
	>=net-misc/modemmanager-0.4
	>=net-wireless/wpa_supplicant-0.5.10[dbus]
	bluetooth? ( net-wireless/bluez )
	|| ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )
	avahi? ( net-dns/avahi[autoipd] )
	gnutls? (
		nss? ( >=dev-libs/nss-3.11 )
		!nss? ( dev-libs/libgcrypt
			net-libs/gnutls ) )
	!gnutls? ( >=dev-libs/nss-3.11 )
	dhclient? (
		dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
		!dhcpcd? ( net-misc/dhcp ) )
	!dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )
	resolvconf? ( net-dns/openresolv )
	connection-sharing? (
		net-dns/dnsmasq
		net-firewall/iptables )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-util/intltool
	>=net-dialup/ppp-2.4.5
	doc? ( >=dev-util/gtk-doc-1.8 )"

S=${WORKDIR}/${MY_P}

sysfs_deprecated_check() {
	ebegin "Checking for SYSFS_DEPRECATED support"

	if { linux_chkconfig_present SYSFS_DEPRECATED_V2; }; then
		eerror "Please disable SYSFS_DEPRECATED_V2 support in your kernel config and recompile your kernel"
		eerror "or NetworkManager will not work correctly."
		eerror "See http://bugs.gentoo.org/333639 for more info."
		die "CONFIG_SYSFS_DEPRECATED_V2 support detected!"
	fi
	eend $?
}

pkg_setup() {
	# FIXME. Required by -confchanges.patch, but the patch is invalid as
	# ConsoleKit and PolicyKit is enough to get authorization.
	enewgroup plugdev

	if use kernel_linux; then
		get_version
		if linux_config_exists; then
			sysfs_deprecated_check
		else
			ewarn "Was unable to determine your kernel .config"
			ewarn "Please note that if CONFIG_SYSFS_DEPRECATED_V2 is set in your kernel .config, NetworkManager will not work correctly."
			ewarn "See http://bugs.gentoo.org/333639 for more info."
		fi

	fi
}

src_prepare() {
	# dbus policy patch
	epatch "${FILESDIR}/${P}-confchanges.patch"
	# accept "gw" in /etc/conf.d/net (bug #339215)
	epatch "${FILESDIR}/${P}-accept-gw.patch"
	# fix shared connection wrt bug #350476
	# fix parsing dhclient.conf wrt bug #352638
	epatch "${FILESDIR}/${P}-shared-connection.patch"
	# Backports #1
	epatch "${FILESDIR}/${P}-1.patch"
	# won't crash upon startup for 32bit machines wrt bug #353807
	epatch "${FILESDIR}/${P}-fix-timestamp.patch"
	# fix tests wrt bug #353549
	epatch "${FILESDIR}/${P}-fix-tests.patch"
	# fix temporary files creation bug #349003
	epatch "${FILESDIR}/${P}-fix-tempfiles.patch"
	# won't write when nothing changed (bug #356339)
	epatch "${FILESDIR}/${P}-ifnet-smarter-write.patch"
	eautoreconf
}

src_configure() {
	ECONF="--disable-more-warnings
		--localstatedir=/var
		--with-distro=gentoo
		--with-dbus-sys-dir=/etc/dbus-1/system.d
		--with-udev-dir=/etc/udev
		--with-iptables=/sbin/iptables
		$(use_enable doc gtk-doc)
		$(use_with doc docs)
		$(use_with resolvconf)"

	# default is dhcpcd (if none or both are specified), ISC dchclient otherwise
	if use dhclient ; then
		if use dhcpcd ; then
			ECONF="${ECONF} --with-dhcpcd --without-dhclient"
		else
			ECONF="${ECONF} --with-dhclient --without-dhcpcd"
		fi
	else
		ECONF="${ECONF} --with-dhcpcd --without-dhclient"
	fi

	# default is NSS (if none or both are specified), GnuTLS otherwise
	if use gnutls ; then
		if use nss ; then
			ECONF="${ECONF} --with-crypto=nss"
		else
			ECONF="${ECONF} --with-crypto=gnutls"
		fi
	else
		ECONF="${ECONF} --with-crypto=nss"
	fi

	econf ${ECONF}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	# Need to keep the /var/run/NetworkManager directory
	keepdir /var/run/NetworkManager

	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
	keepdir /etc/NetworkManager/dispatcher.d

	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"

	# Add keyfile plugin support
	keepdir /etc/NetworkManager/system-connections
	insinto /etc/NetworkManager
	newins "${FILESDIR}/nm-system-settings.conf-ifnet" nm-system-settings.conf \
		|| die "newins failed"
}

pkg_postinst() {
	elog "You will need to reload DBus if this is your first time installing"
	elog "NetworkManager, or if you're upgrading from 0.7 or older."
	elog ""
}