[gentoo-commits] gentoo-x86 commit in media-libs/phonon-gstreamer: phonon-gstreamer-4.7.1.ebuild ChangeLog phonon-gstreamer-4.7.0.ebuild

[Johannes Huber (johu)]

johu        13/12/06 13:02:43

  Modified:             ChangeLog
  Added:                phonon-gstreamer-4.7.1.ebuild
  Removed:              phonon-gstreamer-4.7.0.ebuild
  Log:
  Version bump, remove old.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

Revision  Changes    Path
1.46                 media-libs/phonon-gstreamer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog?rev=1.46&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog?rev=1.46&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog?r1=1.45&r2=1.46

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog,v
retrieving revision 1.45
retrieving revision 1.46
diff -u -r1.45 -r1.46
--- ChangeLog	11 Nov 2013 21:07:10 -0000	1.45
+++ ChangeLog	6 Dec 2013 13:02:43 -0000	1.46
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/phonon-gstreamer
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog,v 1.45 2013/11/11 21:07:10 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/ChangeLog,v 1.46 2013/12/06 13:02:43 johu Exp $
+
+*phonon-gstreamer-4.7.1 (06 Dec 2013)
+
+  06 Dec 2013; Johannes Huber <johu@g.o> +phonon-gstreamer-4.7.1.ebuild,
+  -phonon-gstreamer-4.7.0.ebuild:
+  Version bump, remove old.
 
 *phonon-gstreamer-4.7.0 (11 Nov 2013)
 



1.1                  media-libs/phonon-gstreamer/phonon-gstreamer-4.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.1.ebuild?rev=1.1&content-type=text/plain

Index: phonon-gstreamer-4.7.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/phonon-gstreamer/phonon-gstreamer-4.7.1.ebuild,v 1.1 2013/12/06 13:02:43 johu Exp $

EAPI=5

[[ ${PV} == *9999 ]] && git_eclass="git-r3"
EGIT_REPO_URI=( "git://anongit.kde.org/${PN}" )

MY_PN="phonon-backend-gstreamer"
MY_P=${MY_PN}-${PV}

inherit cmake-utils multibuild ${git_eclass}

DESCRIPTION="Phonon GStreamer backend"
HOMEPAGE="https://projects.kde.org/projects/kdesupport/phonon/phonon-gstreamer"
[[ ${PV} == *9999 ]] || SRC_URI="mirror://kde/stable/phonon/${MY_PN}/${PV}/${MY_P}.tar.xz"

LICENSE="LGPL-2.1"
if [[ ${PV} == *9999 ]]; then
	KEYWORDS=""
else
	KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~x64-macos"
fi
SLOT="0"
IUSE="alsa debug +network +qt4 qt5"
REQUIRED_USE="|| ( qt4 qt5 )"

RDEPEND="
	media-libs/gstreamer:0.10
	media-plugins/gst-plugins-meta:0.10[alsa?,ogg,vorbis]
	>=media-libs/phonon-4.7.0[qt4?,qt5?]
	qt4? (
		dev-qt/qtcore:4[glib]
		dev-qt/qtgui:4[glib]
		dev-qt/qtopengl:4
	)
	qt5? (
		dev-qt/qtcore:5[glib]
		dev-qt/qtgui:5[glib]
		dev-qt/qtopengl:5
	)
	virtual/opengl
	network? ( media-plugins/gst-plugins-soup:0.10 )
"
DEPEND="${RDEPEND}
	qt4? ( >=dev-util/automoc-0.9.87 )
	virtual/pkgconfig
"

[[ ${PV} == 9999 ]] || S=${WORKDIR}/${MY_P}

pkg_setup() {
	MULTIBUILD_VARIANTS=()
	if use qt4; then
		MULTIBUILD_VARIANTS+=(qt4)
	fi
	if use qt5; then
		MULTIBUILD_VARIANTS+=(qt5)
	fi
}

src_configure() {
	myconfigure() {
		local mycmakeargs=()
		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=OFF)
		fi
		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
			mycmakeargs+=(-DPHONON_BUILD_PHONON4QT5=ON)
		fi
		cmake-utils_src_configure
	}

	multibuild_foreach_variant myconfigure
}

src_compile() {
	multibuild_foreach_variant cmake-utils_src_compile
}

src_install() {
	multibuild_foreach_variant cmake-utils_src_install
}

src_test() {
	multibuild_foreach_variant cmake-utils_src_test
}