[gentoo-commits] gentoo-x86 commit in media-sound/mt-daapd: ChangeLog mt-daapd-0.2.4.1.ebuild mt-daapd-0.3.0_pre1376.ebuild

[Samuli Suominen (drac)]

drac        07/10/28 22:13:40

  Modified:             ChangeLog
  Added:                mt-daapd-0.2.4.1.ebuild
  Removed:              mt-daapd-0.3.0_pre1376.ebuild
  Log:
  Version bump dropping howl support.
  (Portage version: 2.1.3.16)

Revision  Changes    Path
1.52                 media-sound/mt-daapd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mt-daapd/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mt-daapd/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mt-daapd/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/mt-daapd/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	4 Aug 2007 21:09:37 -0000	1.51
+++ ChangeLog	28 Oct 2007 22:13:40 -0000	1.52
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/mt-daapd
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mt-daapd/ChangeLog,v 1.51 2007/08/04 21:09:37 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mt-daapd/ChangeLog,v 1.52 2007/10/28 22:13:40 drac Exp $
+
+*mt-daapd-0.2.4.1 (28 Oct 2007)
+
+  28 Oct 2007; Samuli Suominen <drac@g.o>
+  +files/mt-daapd-0.2.4.1-libsorder.patch,
+  +files/mt-daapd-0.2.4.1-pidfile.patch, +mt-daapd-0.2.4.1.ebuild:
+  Version bump dropping howl support.
 
 *mt-daapd-0.3.0_pre1586 (04 Aug 2007)
 



1.1                  media-sound/mt-daapd/mt-daapd-0.2.4.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mt-daapd/mt-daapd-0.2.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/mt-daapd/mt-daapd-0.2.4.1.ebuild?rev=1.1&content-type=text/plain

Index: mt-daapd-0.2.4.1.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/mt-daapd/mt-daapd-0.2.4.1.ebuild,v 1.1 2007/10/28 22:13:40 drac Exp $

inherit autotools eutils

DESCRIPTION="A multi-threaded implementation of Apple's DAAP server"
HOMEPAGE="http://www.mt-daapd.org"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~sh ~sparc ~x86"
IUSE="avahi vorbis"

DEPEND="media-libs/libid3tag
	sys-libs/gdbm
	avahi? ( net-dns/avahi )
	!avahi? ( net-misc/mDNSResponder )
	vorbis? ( media-libs/libvorbis )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-0.2.3-sparc.patch
	epatch "${FILESDIR}"/${P}-libsorder.patch
	epatch "${FILESDIR}"/${P}-pidfile.patch
	eautoreconf

	cp "${FILESDIR}"/${PN}.init.2 initd

	if use avahi; then
		sed -i -e 's:#USEHOWL need mDNSResponder:need avahi-daemon:' initd
	else
		sed -i -e 's:#USEHOWL ::' initd
	fi
}

src_compile() {
	local myconf

	if use avahi; then
		myconf="--enable-avahi --disable-mdns"
	else
		myconf="--disable-avahi --enable-mdns"
	fi

	econf $(use_enable vorbis oggvorbis) \
		${myconf}

	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed."

	insinto /etc
	newins contrib/mt-daapd.conf mt-daapd.conf.example
	doins contrib/mt-daapd.playlist

	newinitd initd ${PN}

	keepdir /var/cache/mt-daapd /etc/mt-daapd.d
	dodoc AUTHORS ChangeLog CREDITS NEWS README TODO
}

pkg_postinst() {
	einfo
	elog "You have to configure your mt-daapd.conf following"
	elog "/etc/mt-daapd.conf.example file."
	einfo

	if use vorbis; then
		einfo
		elog "You need to edit you extensions list in /etc/mt-daapd.conf"
		elog "if you want your mt-daapd to serve ogg files."
		einfo
	fi

	einfo
	elog "If you want to start more than one ${PN} service, symlink"
	elog "/etc/init.d/${PN} to /etc/init.d/${PN}.<name>, and it will"
	elog "load the data from /etc/${PN}.d/<name>.conf."
	elog "Make sure that you have different cache directories for them."
	einfo
}



-- 
gentoo-commits@g.o mailing list