[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     2e76ff58543bc024fdae702d423289f0923f8c4a
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  9 11:52:06 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul  9 11:52:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2e76ff58

sys-kernel/gentoo-kernel-bin: bump to 5.10.48-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.10.48-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index a7b24216ed0..9812742063c 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -65,6 +65,7 @@ DIST gentoo-kernel-5.10.47-1.amd64.xpak 65480161 BLAKE2B 60863347327dbb67ba16881
 DIST gentoo-kernel-5.10.47-1.arm64.xpak 59021827 BLAKE2B 7a322a113ffd53ec9c8ea8fbe06b9d4a4cc43b2519c3f33ea4b875c53192e58cbac345c21904f9f4a718576bf59d5062e7a0b46cea6c51453565afe8e01fdd55 SHA512 c7fb021069e49177605eca80b9b5ece948394dacc0b2fb280bfb834606db5d4e05f7516f20539c5a5f5075fe7ad216b8b5cef7d6e829099ca80a0b2c03ed21fb
 DIST gentoo-kernel-5.10.47-1.x86.xpak 57221591 BLAKE2B e069b66b20c0c9fe3ab35cea65dbe797b1a5a9b2c80b11d5e49113ace7d9df5eff6a5b1aafcd7a65f5df96d21796fa89ea75b825cfef61058a5f5af13f6e5c7e SHA512 14982da4f9fd7ac365641a5a7f6eda290691bf4c36d67a2f4353d1e16c0bd3e64e3c9cf47c517c295c229cacf70c157614808054b3b96363f128c71d6fb8abed
 DIST gentoo-kernel-5.10.48-1.amd64.xpak 65536136 BLAKE2B be9827d86c0fe12b750aa5ea9236287a80612774e04e2226828d1224428133fcea711690b0680e9831235d6b38a6c96cdea5b0047b54291d27178d3d562e18f7 SHA512 9d029ac037d5ec184c12bc9a7f4b6383205185dfa88a9624c5b207087c4094a020f9c972ddf233ec2a0335aef9ca65feebb92b9b7a6241d04fe6f098e251297a
+DIST gentoo-kernel-5.10.48-1.arm64.xpak 59043938 BLAKE2B 3747e7835e6d3ac4b0659d97a9d45eb9276a09258dac16488e7d701202d524a91406c179a388e215dea878614d66d01a5ffb4d45e898662d11dc597535993571 SHA512 167b5760026c6fff7bcc1ee4b5ae6e6befc287dab065495fdd712fef5249571ba6c72a270e54d9ff4ba41b81a08cced954994016b63e37813911372d686e3046
 DIST gentoo-kernel-5.10.48-1.x86.xpak 57223594 BLAKE2B cdaf9e1f4d49cfb1e772a5c5ad92bfcdca846a16a540032136845c1fc7256c6df405e2d1613377dc5046209a750bfb9b6d543203d604853b2f2d7dfb6e786c5e SHA512 3c1e1895a89cff6f03fda61613c8bc1c62cce4c98992e354b9572965728ece2e7556121edc725a942a23b9eccdc52d6282ef3bd929cb79052ce2ff495a849db4
 DIST gentoo-kernel-5.12.10-1.amd64.xpak 66370289 BLAKE2B 74f9046d711902b5cb650c0c1eac07f4dab42037fc93ee3f9ec70b14a708d1244ec65d54e11e1ab169384bdf2663816dba33e58d22853f30133341296ce65db8 SHA512 e42a2d5122d17a6abfe75c17585e96d0fcb87ab21dd3bfbddce6f22c7b73b66daf358b642c4b3658d2d5e43a3c586da5bd48e90e00520ec2cbd696493510f410
 DIST gentoo-kernel-5.12.10-1.arm64.xpak 62567249 BLAKE2B e20ff0b59f3f0781cbb7d1a2eb290e46cdb8fc0f4aa189bb70f7ad5d02b54a5a30bdb3d91c779bfdb04daf01efe5c85376c4a3faa52cead80743aae588993e26 SHA512 ee5daf6872844476018ddab8445e3dbd25d1585a8cd2b6195028b8f8690cb262befcfdef3e0267a422f30c4ca0036dd6c985331cbacdc0c8e79f9c7c9755f4ba

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.48-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.48-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.48-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}