[gentoo-commits] repo/gentoo:master commit in: dev-db/pgadmin4/

[Aaron W. Swenson]

commit:     fad7f93efac8cb3f0530b63c4df5b72731c2e4bc
Author:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  4 15:06:36 2019 +0000
Commit:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
CommitDate: Thu Jul  4 15:06:39 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fad7f93e

dev-db/pgadmin4: Bump to 4.10

Package-Manager: Portage-2.3.66, Repoman-2.3.11
Signed-off-by: Aaron W. Swenson <titanofold <AT> gentoo.org>

 dev-db/pgadmin4/Manifest             |   1 +
 dev-db/pgadmin4/pgadmin4-4.10.ebuild | 124 +++++++++++++++++++++++++++++++++++
 2 files changed, 125 insertions(+)

diff --git a/dev-db/pgadmin4/Manifest b/dev-db/pgadmin4/Manifest
index 25f06e583f2..58070e21f70 100644
--- a/dev-db/pgadmin4/Manifest
+++ b/dev-db/pgadmin4/Manifest
@@ -1,2 +1,3 @@
+DIST pgadmin4-4.10.tar.gz 22809776 BLAKE2B 70a9857de31721b1cd5816b9e15abf325516f94ad5248f3ce5387cca5081ba96d7fca6c487265960ffac8d63c2fd09c3dea44d24a1cc9f8dbb170bd76d5de545 SHA512 b7f91d85fdc39766a294d9b66e8539f709b99f971726551d013345595161ff017e03505f05a41352575892be9d9622e86f4ccdbac76bcea435e2fb88a690b565
 DIST pgadmin4-4.5.tar.gz 22420769 BLAKE2B ae16e34c4cfce0ae78f06321ea1fc34aac0e081df4c0d5906fc4da0c82abb67e374477b8f9a9266d003579eb8887541e4224465ce6eccd86589129e1b3efff24 SHA512 835434612ac2a7ff89fab4c4bed89644e43506491ce12d2b74ffdbc25b33f2ac9ae566c95e886d4b4f8bca6499c40be5f0d776b18bfdcebd44d7ffe3b89deb5f
 DIST pgadmin4-4.8.tar.gz 22780924 BLAKE2B 7b64ef8ac3782e9c8207d5938f3638d67ddf5c86ca520afbfb296a824b39411362ca6e9d8b03920e35cca38d1303efe81750e5bfc849cfb363f370da3d25ac44 SHA512 68b35c1091435fbeb39e67c7f93038fcba95cd5ae7098434b5d3afee10595f875ef9fd997934f2bbd93c914bcd5c3c71bd43f032f788e55c5795f5ad63b57cd7

diff --git a/dev-db/pgadmin4/pgadmin4-4.10.ebuild b/dev-db/pgadmin4/pgadmin4-4.10.ebuild
new file mode 100644
index 00000000000..31cf045d0bf
--- /dev/null
+++ b/dev-db/pgadmin4/pgadmin4-4.10.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 qmake-utils
+
+DESCRIPTION="GUI administration and development platform for PostgreSQL"
+HOMEPAGE="https://www.pgadmin.org/"
+SRC_URI="mirror://postgresql/pgadmin/${PN}/v${PV}/source/${P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="doc"
+
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+"
+
+DEPEND="${COMMON_DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=app-text/htmlmin-0.1.12[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/click-6.6[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.2.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/extras-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.12.4[${PYTHON_USEDEP}]
+	>=dev-python/flask-babel-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-babelex-0.9.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-gravatar-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-htmlmin-1.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-migrate-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-paranoid-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-security-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-2.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.24[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7.3[${PYTHON_USEDEP}]
+	>=dev-python/linecache2-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-0.23[${PYTHON_USEDEP}]
+	>=dev-python/mimeparse-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pbr-3.1.1[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.4.7[${PYTHON_USEDEP}]
+	>=dev-python/psycopg-2.7.4[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7.1[${PYTHON_USEDEP}]
+	>=dev-python/python-sqlparse-0.2.4[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2018.3[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.13.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/speaklater-1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.2.5[${PYTHON_USEDEP}]
+	>=dev-python/sshtunnel-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/wtforms-2.1[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}"/${P}/runtime
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	default
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_compile() {
+	default
+	if use doc; then
+		cd "${WORKDIR}"/${P} || die
+		emake docs
+	fi
+}
+
+src_install() {
+	dobin pgAdmin4
+
+	cd "${WORKDIR}"/${P} || die
+
+	local APP_DIR=/usr/share/${PN}/web
+	insinto "${APP_DIR}"
+	doins -r web/*
+	cat > "${D}${APP_DIR}"/config_local.py <<-EOF
+		SERVER_MODE = False
+		UPGRADE_CHECK_ENABLED = False
+	EOF
+	python_optimize "${D}${APP_DIR}"
+
+	local CONFIG_DIR="/etc/xdg/pgadmin"
+	dodir "${CONFIG_DIR}"
+	cat > "${D}${CONFIG_DIR}"/pgadmin4.conf <<-EOF
+		[General]
+		ApplicationPath=${APP_DIR}
+		PythonPath=$(python_get_sitedir)
+	EOF
+
+	if use doc; then
+		rm -r docs/en_US/_build/html/_sources || die
+		insinto /usr/share/${PN}/docs/en_US/_build
+		doins -r docs/en_US/_build/html
+	fi
+}