[gentoo-commits] repo/gentoo:master commit in: app-misc/workrave/

[Gilles Dartiguelongue]

commit:     896364e4c2c936b97444ce4a3a2d76fdcdc59be7
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  7 23:15:37 2018 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Wed Feb  7 23:20:12 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=896364e4

app-misc/workrave: version bump 1.10.16 → 1.10.20

Support for newer Gnome Shell, fix activity monitoring in non-Gnome environment.

Closes: https://bugs.gentoo.org/636684
Package-Manager: Portage-2.3.24, Repoman-2.3.6

 app-misc/workrave/Manifest                |   1 +
 app-misc/workrave/workrave-1.10.20.ebuild | 106 ++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/app-misc/workrave/Manifest b/app-misc/workrave/Manifest
index 2352538fa34..accfd15e6dd 100644
--- a/app-misc/workrave/Manifest
+++ b/app-misc/workrave/Manifest
@@ -1 +1,2 @@
 DIST workrave-1.10.16.tar.gz 6375438 BLAKE2B 35d78a133b275e1c0adc8c21ceb91412f38667b9dde2ed9e08a8b01cde7b4d35780d317057d000bfa39ae0d5da4639f2e2252b1812acd66a3b81f7c1d1995dfb SHA512 f768c46a5b7dfbaca2984fabff92e64d5fd14f3b4e4d018f5a1cf46a87fbf7ec7fbaec9b660e899f7064a93338224d159b75052ed8e532ecaf507d2f249732f2
+DIST workrave-1.10.20.tar.gz 6377941 BLAKE2B 00f573c05ddacd61d50d80a4079d161b18e7e52606cf502f359cf51c4b64407c978fa944e79314146baea62fe77212fa623d54706c62e23fd1ca17cbf25db409 SHA512 fc8d98aa560946f00ee30be0c28648245a425cd3fddeba8fbdd61fb89d107cc8085d5c4d8a326c739b394e6baada2b28cf98ce9ccaf85dca6bfaa1ae78d4ce56

diff --git a/app-misc/workrave/workrave-1.10.20.ebuild b/app-misc/workrave/workrave-1.10.20.ebuild
new file mode 100644
index 00000000000..0d3fce130b0
--- /dev/null
+++ b/app-misc/workrave/workrave-1.10.20.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools gnome2 python-single-r1 versionator vcs-snapshot
+
+DESCRIPTION="Helpful utility to attack Repetitive Strain Injury (RSI)"
+HOMEPAGE="http://www.workrave.org/"
+MY_PV=$(replace_all_version_separators '_')
+SRC_URI="https://github.com/rcaelers/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+# dbus support looks to be used only for trying to use panel applets on gnome3!
+IUSE="ayatana doc gnome gstreamer introspection mate nls pulseaudio test xfce"
+REQUIRED_USE="ayatana? ( introspection ) ${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	>=dev-libs/glib-2.28.0:2
+	>=x11-libs/gtk+-3.0:3[introspection?,X]
+	>=dev-cpp/gtkmm-3.18.0:3.0
+	>=dev-cpp/glibmm-2.28.0:2
+	>=dev-libs/libsigc++-2.2.4.2:2
+	ayatana? (
+		>=dev-libs/libdbusmenu-0.4[gtk3,introspection]
+		>=dev-libs/libindicator-0.4:3 )
+	gnome? ( >=gnome-base/gnome-shell-3.6.2 )
+	gstreamer? (
+		media-libs/gstreamer:1.0[introspection?]
+		media-libs/gst-plugins-base:1.0[introspection?]
+		media-plugins/gst-plugins-meta:1.0 )
+	introspection? ( dev-libs/gobject-introspection:= )
+	mate? ( mate-base/mate-applets )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.15 )
+	xfce? (
+		>=x11-libs/gtk+-2.6.0:2[introspection?]
+		>=xfce-base/xfce4-panel-4.4 )
+	x11-libs/libXScrnSaver
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXtst
+	x11-libs/libXt
+	x11-libs/libXmu
+	${PYTHON_DEPS}
+"
+#        dbus? (
+#                >=sys-apps/dbus-1.2
+#                dev-libs/dbus-glib )
+
+DEPEND="${RDEPEND}
+	dev-python/cheetah
+	>=dev-util/intltool-0.40.0
+	sys-devel/autoconf-archive
+	x11-proto/xproto
+	x11-proto/inputproto
+	x11-proto/recordproto
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-sgml-utils
+		app-text/xmlto )
+	nls? ( >=sys-devel/gettext-0.17 )
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	vcs-snapshot_src_unpack
+}
+
+src_prepare() {
+	# Fix gstreamer slot automagic dependency, bug #563584
+	# http://issues.workrave.org/show_bug.cgi?id=1179
+	eapply "${FILESDIR}"/${PN}-1.10.6-automagic-gstreamer.patch
+
+	eautoreconf
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# gnet ("distribution") is dead for ages and other distributions stopped
+	# relying on it for such time too.
+	gnome2_src_configure \
+		--disable-dbus \
+		--disable-distribution \
+		--enable-exercises \
+		--disable-experimental \
+		--disable-gnome2 \
+		--disable-static \
+		--disable-xml \
+		$(use_enable ayatana indicator) \
+		$(use_enable doc manual) \
+		$(use_enable gnome gnome3) \
+		$(use_enable gstreamer) \
+		$(use_enable introspection) \
+		$(use_enable mate) \
+		$(use_enable nls) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable test tests) \
+		$(use_enable xfce)
+}