[gentoo-commits] gentoo-x86 commit in media-video/mediainfo: mediainfo-0.7.63.ebuild ChangeLog

[Tim Harder (radhermit)]

radhermit    13/06/01 02:00:57

  Modified:             ChangeLog
  Added:                mediainfo-0.7.63.ebuild
  Log:
  Version bump and update license to BSD-2.
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.66                 media-video/mediainfo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?rev=1.66&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?rev=1.66&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/ChangeLog?r1=1.65&r2=1.66

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v
retrieving revision 1.65
retrieving revision 1.66
diff -u -r1.65 -r1.66
--- ChangeLog	10 Apr 2013 20:33:11 -0000	1.65
+++ ChangeLog	1 Jun 2013 02:00:57 -0000	1.66
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mediainfo
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.65 2013/04/10 20:33:11 vincent Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.66 2013/06/01 02:00:57 radhermit Exp $
+
+*mediainfo-0.7.63 (01 Jun 2013)
+
+  01 Jun 2013; Tim Harder <radhermit@g.o> +mediainfo-0.7.63.ebuild:
+  Version bump and update license to BSD-2.
 
   10 Apr 2013; Vicente Olivert Riera <vincent@g.o>
   mediainfo-0.7.62.ebuild:



1.1                  media-video/mediainfo/mediainfo-0.7.63.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/mediainfo-0.7.63.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/mediainfo/mediainfo-0.7.63.ebuild?rev=1.1&content-type=text/plain

Index: mediainfo-0.7.63.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/mediainfo-0.7.63.ebuild,v 1.1 2013/06/01 02:00:57 radhermit Exp $

EAPI=5
WX_GTK_VER="2.8"

inherit eutils autotools wxwidgets multilib

DESCRIPTION="MediaInfo supplies technical and tag information about media files"
HOMEPAGE="http://mediainfo.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${PN}_${PV}.tar.bz2"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="curl mms wxwidgets"

RDEPEND="sys-libs/zlib
	media-libs/libzen
	~media-libs/lib${P}[curl=,mms=]
	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/MediaInfo

pkg_setup() {
	TARGETS="CLI"
	use wxwidgets && TARGETS+=" GUI"
}

src_prepare() {
	local target
	for target in ${TARGETS}; do
		cd "${S}"/Project/GNU/${target}
		sed -i -e "s:-O2::" configure.ac
		eautoreconf
	done
}

src_configure() {
	local target
	for target in ${TARGETS}; do
		cd "${S}"/Project/GNU/${target}
		local args=""
		[[ ${target} == "GUI" ]] && args="--with-wxwidgets --with-wx-gui"
		econf ${args}
	done
}

src_compile() {
	local target
	for target in ${TARGETS}; do
		cd "${S}"/Project/GNU/${target}
		default
	done
}
src_install() {
	local target
	for target in ${TARGETS}; do
		cd "${S}"/Project/GNU/${target}
		default
		dodoc "${S}"/History_${target}.txt
		if [[ ${target} == "GUI" ]]; then
			newicon "${S}"/Source/Resource/Image/MediaInfo.png ${PN}.png
			make_desktop_entry ${PN}-gui MediaInfo ${PN} "AudioVideo;GTK"
		fi
	done
}