[gentoo-commits] gentoo-x86 commit in sys-devel/libtool: ChangeLog libtool-2.4-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    10/11/29 15:12:34

  Modified:             ChangeLog
  Added:                libtool-2.4-r1.ebuild
  Log:
  Add experimental revision without runtime dependency over autotools, trying to deal with bug #317309.
  
  (Portage version: 2.2.0_alpha6/cvs/Linux x86_64)

Revision  Changes    Path
1.182                sys-devel/libtool/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?rev=1.182&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?rev=1.182&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/ChangeLog?r1=1.181&r2=1.182

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v
retrieving revision 1.181
retrieving revision 1.182
diff -u -r1.181 -r1.182
--- ChangeLog	13 Nov 2010 12:02:17 -0000	1.181
+++ ChangeLog	29 Nov 2010 15:12:34 -0000	1.182
@@ -1,6 +1,12 @@
 # ChangeLog for sys-devel/libtool
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v 1.181 2010/11/13 12:02:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/ChangeLog,v 1.182 2010/11/29 15:12:34 flameeyes Exp $
+
+*libtool-2.4-r1 (29 Nov 2010)
+
+  29 Nov 2010; Diego E. Pettenò <flameeyes@g.o> +libtool-2.4-r1.ebuild:
+  Add experimental revision without runtime dependency over autotools, trying
+  to deal with bug #317309.
 
   13 Nov 2010; Raúl Porcel <armin76@g.o> libtool-2.2.10.ebuild:
   alpha/ia64/m68k/s390/sh/sparc stable wrt #338092



1.1                  sys-devel/libtool/libtool-2.4-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-2.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/libtool/libtool-2.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: libtool-2.4-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/libtool/libtool-2.4-r1.ebuild,v 1.1 2010/11/29 15:12:34 flameeyes Exp $

EAPI="3"

LIBTOOLIZE="true" #225559
inherit eutils autotools multilib

DESCRIPTION="A shared library tool for developers"
HOMEPAGE="http://www.gnu.org/software/libtool/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="vanilla"

RDEPEND="sys-devel/gnuconfig
	!<sys-devel/autoconf-2.62:2.5
	!<sys-devel/automake-1.10.1:1.10
	!=sys-devel/libtool-2*:1.5"
DEPEND="${RDEPEND}
	>=sys-devel/binutils-2.20
	|| ( app-arch/xz-utils app-arch/lzma-utils )"

src_prepare() {
	if ! use vanilla ; then
		epunt_cxx
		cd libltdl/m4
		epatch "${FILESDIR}"/1.5.20/${PN}-1.5.20-use-linux-version-in-fbsd.patch #109105
		cd ..
		AT_NOELIBTOOLIZE=yes eautoreconf
		cd ..
		AT_NOELIBTOOLIZE=yes eautoreconf
	fi
}

src_configure() {
	# the libtool script uses bash code in it and at configure time, tries
	# to find a bash shell.  if /bin/sh is bash, it uses that.  this can
	# cause problems for people who switch /bin/sh on the fly to other
	# shells, so just force libtool to use /bin/bash all the time.
	export CONFIG_SHELL=/bin/bash

	default
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog* NEWS README THANKS TODO doc/PLATFORMS

	for x in $(find "${D}" -name config.guess -o -name config.sub) ; do
		rm -f "${x}" ; ln -sf /usr/share/gnuconfig/${x##*/} "${x}"
	done
}

pkg_preinst() {
	preserve_old_lib /usr/$(get_libdir)/libltdl.so.3
}

pkg_postinst() {
	preserve_old_lib_notify /usr/$(get_libdir)/libltdl.so.3
}