[gentoo-commits] gentoo-x86 commit in sys-cluster/util-vserver: util-vserver-0.30.216_pre3038-r1.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     14/07/29 04:41:02

  Modified:             ChangeLog
  Added:                util-vserver-0.30.216_pre3038-r1.ebuild
  Log:
  Little revision bump that has deps changed to working dietlibc version
  
  (Portage version: 2.2.10/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.116                sys-cluster/util-vserver/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/util-vserver/ChangeLog?rev=1.116&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/util-vserver/ChangeLog?rev=1.116&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/util-vserver/ChangeLog?r1=1.115&r2=1.116

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/util-vserver/ChangeLog,v
retrieving revision 1.115
retrieving revision 1.116
diff -u -r1.115 -r1.116
--- ChangeLog	26 Jun 2014 14:00:22 -0000	1.115
+++ ChangeLog	29 Jul 2014 04:41:02 -0000	1.116
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/util-vserver
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/util-vserver/ChangeLog,v 1.115 2014/06/26 14:00:22 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/util-vserver/ChangeLog,v 1.116 2014/07/29 04:41:02 patrick Exp $
+
+*util-vserver-0.30.216_pre3038-r1 (29 Jul 2014)
+
+  29 Jul 2014; Patrick Lauer <patrick@g.o>
+  +util-vserver-0.30.216_pre3038-r1.ebuild:
+  Little revision bump that has deps changed to working dietlibc version
 
   26 Jun 2014; Michael Palimaka <kensington@g.o>
   -files/util-vserver-0.30.215-2718.patch,



1.1                  sys-cluster/util-vserver/util-vserver-0.30.216_pre3038-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/util-vserver/util-vserver-0.30.216_pre3038-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/util-vserver/util-vserver-0.30.216_pre3038-r1.ebuild?rev=1.1&content-type=text/plain

Index: util-vserver-0.30.216_pre3038-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/util-vserver/util-vserver-0.30.216_pre3038-r1.ebuild,v 1.1 2014/07/29 04:41:02 patrick Exp $

EAPI=4

inherit eutils bash-completion-r1

MY_P=${P/_/-}
S="${WORKDIR}"/${MY_P}

DESCRIPTION="Linux-VServer admin utilities"
HOMEPAGE="http://www.nongnu.org/util-vserver/"
SRC_URI="http://people.linux-vserver.org/~dhozac/t/uv-testing/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~sparc ~x86"

IUSE=""

CDEPEND="dev-libs/beecrypt
	net-firewall/iptables
	net-misc/vconfig
	sys-apps/iproute2
	|| ( >=sys-apps/coreutils-6.10-r1 sys-apps/mktemp )"

DEPEND=">dev-libs/dietlibc-0.33
	${CDEPEND}"

RDEPEND="${CDEPEND}"

pkg_setup() {
	if [[ -z "${VDIRBASE}" ]]; then
		einfo
		einfo "You can change the default vserver base directory (/vservers)"
		einfo "by setting the VDIRBASE environment variable."
	fi

	: ${VDIRBASE:=/vservers}

	einfo
	einfo "Using \"${VDIRBASE}\" as vserver base directory"
	einfo
}

src_test() {
	# do not use $D from portage by accident (#297982)
	sed -i -e 's/^\$D //' "${S}"/src/testsuite/vunify-test.sh
	default
}

src_prepare() {
	epatch "${FILESDIR}"/util-vserver-0.30.216-varlock.patch
}

src_configure() {
	econf --with-vrootdir=${VDIRBASE} \
		--with-initscripts=gentoo \
		--localstatedir=/var
}

src_compile() {
	emake -j1 || die "emake failed!"
}

src_install() {
	make DESTDIR="${D}" install install-distribution \
		|| die "make install failed!"

	# keep dirs
	keepdir /var/cache/vservers
	keepdir "${VDIRBASE}"
	keepdir "${VDIRBASE}"/.pkg

	# bash-completion
	newbashcomp "${FILESDIR}"/bash_completion ${PN}

	dodoc README ChangeLog NEWS AUTHORS THANKS util-vserver.spec
}

pkg_postinst() {
	# Create VDIRBASE in postinst, so it is (a) not unmerged and (b) also
	# present when merging.

	mkdir -p "${VDIRBASE}"
	setattr --barrier "${VDIRBASE}"

	rm /etc/vservers/.defaults/vdirbase
	ln -sf "${VDIRBASE}" /etc/vservers/.defaults/vdirbase

	elog
	elog "You have to run the vprocunhide command after every reboot"
	elog "in order to setup /proc permissions correctly for vserver"
	elog "use. An init script has been installed by this package."
	elog "To use it you should add it to a runlevel:"
	elog
	elog " rc-update add vprocunhide default"
	elog
}