[gentoo-commits] gentoo-x86 commit in app-forensics/openscap: ChangeLog openscap-0.7.3.ebuild openscap-0.7.1-r1.ebuild openscap-0.7.2.ebuild

[Markos Chandras (hwoarang)]

hwoarang    11/07/05 08:00:52

  Modified:             ChangeLog
  Added:                openscap-0.7.3.ebuild
  Removed:              openscap-0.7.1-r1.ebuild openscap-0.7.2.ebuild
  Log:
  Version bump. Add missing dev-libs/libxslt dependency. Bug #373037. Thanks to LABBE Corentin (Montjoie)
  
  (Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  app-forensics/openscap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	27 Apr 2011 20:04:42 -0000	1.5
+++ ChangeLog	5 Jul 2011 08:00:51 -0000	1.6
@@ -1,6 +1,13 @@
 # ChangeLog for app-forensics/openscap
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v 1.5 2011/04/27 20:04:42 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/ChangeLog,v 1.6 2011/07/05 08:00:51 hwoarang Exp $
+
+*openscap-0.7.3 (05 Jul 2011)
+
+  05 Jul 2011; Markos Chandras <hwoarang@g.o> -openscap-0.7.1-r1.ebuild,
+  -openscap-0.7.2.ebuild, +openscap-0.7.3.ebuild:
+  Version bump. Add missing dev-libs/libxslt dependency. Bug #373037. Thanks to
+  LABBE Corentin (Montjoie)
 
 *openscap-0.7.2 (27 Apr 2011)
 



1.1                  app-forensics/openscap/openscap-0.7.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-0.7.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-forensics/openscap/openscap-0.7.3.ebuild?rev=1.1&content-type=text/plain

Index: openscap-0.7.3.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-forensics/openscap/openscap-0.7.3.ebuild,v 1.1 2011/07/05 08:00:51 hwoarang Exp $

EAPI=3

PYTHON_DEPEND="2"

inherit eutils multilib python bash-completion

DESCRIPTION="Framework which enables integration with the Security Content Automation Protocol (SCAP)"
HOMEPAGE="http://www.open-scap.org/"
SRC_URI="http://www.open-scap.org/download/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="bash-completion doc nss perl python sql"

RDEPEND="!nss? ( dev-libs/libgcrypt )
	nss? ( dev-libs/nss )
	sql? ( dev-db/opendbx )
	dev-libs/libpcre
	dev-libs/libxml2
	dev-libs/libxslt
	net-misc/curl"
DEPEND="${RDEPEND}
	perl? ( dev-lang/swig )
	python? ( dev-lang/swig )"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_configure() {
	local myconf
	if use python || use perl ; then
		myconf+=" --enable-bindings"
	else
		myconf+=" --disable-bindings"
	fi
	if use nss ; then
		myconf+=" --with-crypto=nss3"
	else
		myconf+=" --with-crypto=gcrypt"
	fi
	econf ${myconf}
}

src_install() {
	emake install DESTDIR="${D}" || die
	sed -i 's/^Description/&:/'	"${D}"/usr/$(get_libdir)/pkgconfig/libopenscap.pc || die
	#--enable-bindings enable all bindings, clean unwanted bindings
	if use python && ! use perl ; then
		rm -rf "${D}"/usr/$(get_libdir)/perl5 || die
	fi
	if ! use python && use perl ; then
		rm -rf "${D}"/$(python_get_sitedir) || die
	fi
	if use doc ; then
		dohtml -r docs/html/* || die
		dodoc docs/examples/* || die
	fi
	if ! use bash-completion ; then
		rm -rf "${D}"/etc/bash_completion.d || die
	fi
}