[gentoo-commits] repo/gentoo:master commit in: media-sound/qmmp/

[Lars Wendler]

commit:     3d36bbfb873cc051b0b22c97da0698e9578af8bf
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 25 20:01:55 2016 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Jul 25 20:02:10 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d36bbfb

media-sound/qmmp: Bump to versions 0.10.2 and 1.1.2

Package-Manager: portage-2.3.0
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 media-sound/qmmp/Manifest           |   2 +
 media-sound/qmmp/qmmp-0.10.2.ebuild | 125 ++++++++++++++++++++++++++++++++++
 media-sound/qmmp/qmmp-1.1.2.ebuild  | 129 ++++++++++++++++++++++++++++++++++++
 3 files changed, 256 insertions(+)

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index e82671b..513141a 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1,7 +1,9 @@
 DIST qmmp-0.10.1.tar.bz2 1336767 SHA256 37f4014e3ded7f221b88b8de94ba8c75bb6dababa21f05f690059c9fee3508af SHA512 2e4dedd7a01b1cb9226e58086079feb8e1a8dd704509d2663876119b78ae37f4f81ace38874db6f8c4d25e4e8058768d9c092a2d0f970667cc58a19c46d42d86 WHIRLPOOL 3ad59a485719123c7907f36b4163e3393ec52fb60e15cef2d53eed99b171c2ccefd568cd820aaa7fdddbfd458d3dea540fd65be2c93553abaeddf1849db9ef08
+DIST qmmp-0.10.2.tar.bz2 1337240 SHA256 142478d8b8367848d0db360c79ab24c17ecf1a80616a876abf1c4ad174b90c5a SHA512 4fa8de5d5cff3d06413be5c572d04394082c33798e1708a88d4f11121b8138f26e703cf3cd98cf348b6ea6b9ce05813ae9ddde20675ba5b00285deafe17a4fe2 WHIRLPOOL dbff1a1155bfc426bd9e23f7c974a39ffb12cbdb78091ca80202c9fb20c7f3602950d19b1901bb8ed1960dd3ed1e089bd773d6ac8ab6277ce2e0f5a39c968feb
 DIST qmmp-0.9.10.tar.bz2 1126355 SHA256 a93ca43b2407b917602a47b5728cd4d72d694069a3ea329572c01ff66845f7e1 SHA512 2326ac6ca91b68c0b68888a98bd4f6f6596b50aa7442edca3686bf7516a9947954ad95a6107f74f8ea6e3013325eeb2e59d53d034410e27845208e2486916556 WHIRLPOOL 4716e4f40915a37049195450b005e387069a02171dcfe331d2898f8059c956f4d1e48ea14a8e9258103f21b7728ec4546c6666259b43bbb809d39aa322890464
 DIST qmmp-0.9.2.tar.bz2 1112974 SHA256 90ac69a21779df5073efe71b25f28a7461d6a928deb1afbaa1ef8268f62ae9c5 SHA512 fc6cb0ec4bbf52e2ceb9e87a3585f25bd58b3a323ef07ddb9fd9f21a065ef0f5deb0b014f29b9648fe9e0a8b412f3b04643f8128638558089a25d867577690ad WHIRLPOOL 47a596b0f7d9e516737bfeb10a962f79edb74f61e2985b01f2cee80c8ff252a1709459f5712700784faef824e24ff3567d73f0d5759e2cd2c0c53c267cc6a026
 DIST qmmp-0.9.8.tar.bz2 1125404 SHA256 83ca64e222b8b02a0515511d8187667f1d44a71281cf36eb0fe05560c88b1911 SHA512 1a86cd1c3552f64005d49e2a9baa2fd65bdc8fefad4e72e265cd3afdb45fd22d57c712a9c6e693e0308cd5607f8fe5905bb3a5e51747b11273f3e4eb60c4fd81 WHIRLPOOL 3d036fb3d7dd8ce7282f97d6e89a04e10c71c3bc615d0529ab0ef262f5b0d3d7b2bc9e2ed3f9e29e06be8a6b3b764ba52345b9100ead371985c00ae99c597f6e
 DIST qmmp-1.0.10.tar.bz2 1107784 SHA256 02bcd01b1d8f6ca8b805a5deaeaa059ee44a38fafd20bec7ee3560a021250ee3 SHA512 45231ef8b1f0a0825336752fe9314cc0df1b937ebcf85b18c89c66e52f38cf69583eccd8ffcf92d89add11643e1f40ccf0fe720fd6279f3cf4f73db336d4d59b WHIRLPOOL 0bb7d873e58b8cdbbb71576af3080031fc0e03cc3fc3153812e2a105bad40f02ac4a3838454aef5551890e278d050bbe04caf0e77ddb1cd3b43f7fd2c77cd5e7
 DIST qmmp-1.0.7.tar.bz2 1107565 SHA256 adb8c4338a22bc80e75aa667e866789b970eb3c7662fdb374f03388f45e5e09b SHA512 d9c5be464ba2c4e2eb4b0ffbb938cb277e8c483fcb1ec97100dc862acfc2f1c6c1110a3d45c5c5713c7e30bd508a7c0828ff48587ea875ac7befe5b23544cabd WHIRLPOOL d766bd45c9bb18a5cec37d23a4ca123021e79dc1ffc275e38c99a9ee88b03120534aa845a0df007b1c93e44d4867e883fd6720079333b85420e4ca4b1364e992
 DIST qmmp-1.1.1.tar.bz2 1126907 SHA256 c82364b76d23d8bba52466737349493593802576bee57979553a3de67163b518 SHA512 ef9f0f4294523abb0d77f6af91b2d5bf976a25c3a142d3a3c269832ea3a607827cd5ce96fb2ed12814b781ab9208250c05238842573a74d5c1a64ae70f6e9b98 WHIRLPOOL 4b8d12390fd60511111392a18eb9eb4acbcdaa025cf39568e95374f4883d54a226e5ffbe46af25235c510275a3f755e628e846fb69bbd41c200b0ab3ff526af1
+DIST qmmp-1.1.2.tar.bz2 1127322 SHA256 b858b8a3263ddeda247667ab2d59f95c159b24021ff858c79fcb9b09d9db6f08 SHA512 7a071fd1b7f00177a689fa26aafb684742ee55e4fe23de9c269ca7bd0a9ba14571cdfc4207e43671df40d14ce62f7675464cb41eb1c82b462408ccc6a3033c1e WHIRLPOOL 08720f16d9ea45d2a3a574d6bcaf1ee677cfca798443ae8037016f54a1dae04dacf7315be79738b6821be8326c899f41da9e99abe66c31f1b00df5397dc061db

diff --git a/media-sound/qmmp/qmmp-0.10.2.ebuild b/media-sound/qmmp/qmmp-0.10.2.ebuild
new file mode 100644
index 0000000..64c3f9f
--- /dev/null
+++ b/media-sound/qmmp/qmmp-0.10.2.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
+
+DESCRIPTION="Qt4-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~x86"
+else
+	SRC_URI=""
+	ESVN_REPO_URI="https://qmmp.googlecode.com/svn/trunk/qmmp/"
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="analyzer aac +alsa bs2b cdda cover crossfade cue curl enca ffmpeg flac jack game kde ladspa
+lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss projectm
+pulseaudio qsui scrobbler sndfile soxr stereo tray udisks +vorbis wavpack"
+
+RDEPEND="media-libs/taglib
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtgui:4
+	dev-qt/qtmultimedia:4
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	aac? ( media-libs/faad2 )
+	enca? ( app-i18n/enca )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	ffmpeg? ( virtual/ffmpeg )
+	opus? ( media-libs/opusfile )
+	projectm? ( media-libs/libprojectm
+		dev-qt/qtopengl:4 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	wavpack? ( media-sound/wavpack )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${RDEPEND}"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FFMPEG_LEGACY=OFF
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_KDENOTIFY="$(usex kde)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPRIS="$(usex mpris)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_UDISKS=OFF
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+		)
+
+	cmake-utils_src_configure
+}

diff --git a/media-sound/qmmp/qmmp-1.1.2.ebuild b/media-sound/qmmp/qmmp-1.1.2.ebuild
new file mode 100644
index 0000000..488c726
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.1.2.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+[ "$PV" == "9999" ] && inherit subversion
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	QMMP_DEV_BRANCH="1.1"
+	SRC_URI=""
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+	KEYWORDS=""
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="analyzer aac +alsa bs2b cdda cover crossfade cue curl enca ffmpeg flac jack game kde ladspa
+lyrics +mad midi mms modplug mplayer mpris musepack notifier opus oss projectm
+pulseaudio qsui scrobbler sndfile soxr stereo tray udisks +vorbis wavpack"
+
+RDEPEND="media-libs/taglib
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	alsa? ( media-libs/alsa-lib )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( dev-libs/libcdio-paranoia )
+	cue? ( media-libs/libcue )
+	curl? ( net-misc/curl )
+	aac? ( media-libs/faad2 )
+	enca? ( app-i18n/enca )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	ladspa? ( media-libs/ladspa-cmt )
+	mad? ( media-libs/libmad )
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( media-video/mplayer )
+	mpris? ( dev-qt/qtdbus:5 )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	modplug? ( >=media-libs/libmodplug-0.8.4 )
+	vorbis? ( media-libs/libvorbis
+		media-libs/libogg )
+	jack? ( media-sound/jack-audio-connection-kit
+		media-libs/libsamplerate )
+	ffmpeg? ( virtual/ffmpeg )
+	opus? ( media-libs/opusfile )
+	projectm? ( media-libs/libprojectm
+		dev-qt/qtopengl:5
+		dev-qt/qtgui:5[-gles2] )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	wavpack? ( media-sound/wavpack )
+	scrobbler? ( net-misc/curl )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+DOCS="AUTHORS ChangeLog README"
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_KDENOTIFY="$(usex kde)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MODPLUG="$(usex modplug)"
+		-DUSE_MPRIS="$(usex mpris)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+	)
+
+	cmake-utils_src_configure
+}