[gentoo-commits] gentoo-x86 commit in gnome-base/librsvg: librsvg-2.40.3.ebuild ChangeLog librsvg-2.40.1-r1.ebuild

[Pacho Ramos (pacho)]

pacho       14/09/04 10:10:30

  Modified:             ChangeLog
  Added:                librsvg-2.40.3.ebuild
  Removed:              librsvg-2.40.1-r1.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.360                gnome-base/librsvg/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/librsvg/ChangeLog?rev=1.360&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/librsvg/ChangeLog?rev=1.360&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/librsvg/ChangeLog?r1=1.359&r2=1.360

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/librsvg/ChangeLog,v
retrieving revision 1.359
retrieving revision 1.360
diff -u -r1.359 -r1.360
--- ChangeLog	25 Aug 2014 10:59:05 -0000	1.359
+++ ChangeLog	4 Sep 2014 10:10:30 -0000	1.360
@@ -1,6 +1,16 @@
 # ChangeLog for gnome-base/librsvg
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/librsvg/ChangeLog,v 1.359 2014/08/25 10:59:05 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/librsvg/ChangeLog,v 1.360 2014/09/04 10:10:30 pacho Exp $
+
+*librsvg-2.40.3 (04 Sep 2014)
+
+  04 Sep 2014; Pacho Ramos <pacho@g.o> +librsvg-2.40.3.ebuild,
+  -files/librsvg-2.36.0-rsvg-view-automagic.patch,
+  -files/librsvg-2.36.4-resource-uri-1.patch,
+  -files/librsvg-2.36.4-resource-uri-2.patch,
+  -files/librsvg-2.36.4-resource-uri-3.patch,
+  -files/librsvg-2.39.0-canonicalize-realpath.patch, -librsvg-2.40.1-r1.ebuild:
+  Version bump, drop old
 
   25 Aug 2014; Agostino Sarubbo <ago@g.o> librsvg-2.40.2-r1.ebuild:
   Stable for alpha, wrt bug #512012



1.1                  gnome-base/librsvg/librsvg-2.40.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/librsvg/librsvg-2.40.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-base/librsvg/librsvg-2.40.3.ebuild?rev=1.1&content-type=text/plain

Index: librsvg-2.40.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/librsvg/librsvg-2.40.3.ebuild,v 1.1 2014/09/04 10:10:30 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
VALA_MIN_API_VERSION="0.18"
VALA_USE_DEPEND="vapigen"

inherit autotools gnome2 multilib-minimal vala

DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
HOMEPAGE="https://wiki.gnome.org/Projects/LibRsvg"

LICENSE="LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="+introspection vala tools"
REQUIRED_USE="
	vala? ( introspection )
"

RDEPEND="
	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
	>=x11-libs/cairo-1.12.14-r4[${MULTILIB_USEDEP}]
	>=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}]
	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
	>=dev-libs/libcroco-0.6.8-r1[${MULTILIB_USEDEP}]
	>=x11-libs/gdk-pixbuf-2.30.7:2[introspection?,${MULTILIB_USEDEP}]
	introspection? ( >=dev-libs/gobject-introspection-0.10.8 )
	tools? ( >=x11-libs/gtk+-3.2.0:3 )
"
DEPEND="${RDEPEND}
	dev-libs/gobject-introspection-common
	dev-libs/vala-common
	>=dev-util/gtk-doc-am-1.13
	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
	vala? ( $(vala_depend) )
"
# >=gtk-doc-am-1.13, gobject-introspection-common, vala-common needed by eautoreconf

src_prepare() {
	# https://bugzilla.gnome.org/show_bug.cgi?id=712693
	epatch "${FILESDIR}/${PN}-2.40.1-gtk-optional.patch"

	# https://bugzilla.gnome.org/show_bug.cgi?id=731826
	epatch "${FILESDIR}/${PN}-2.40.2-vala-out-of-source.patch"

	eautoreconf

	use vala && vala_src_prepare
	gnome2_src_prepare
}

multilib_src_configure() {
	local myconf=()

	# -Bsymbolic is not supported by the Darwin toolchain
	if [[ ${CHOST} == *-darwin* ]]; then
		myconf+=( --disable-Bsymbolic )
	fi

	# --disable-tools even when USE=tools; the tools/ subdirectory is useful
	# only for librsvg developers
	ECONF_SOURCE=${S} \
	gnome2_src_configure \
		--disable-static \
		--disable-tools \
		$(multilib_native_use_enable introspection) \
		$(multilib_native_use_with tools gtk3) \
		$(multilib_native_use_enable vala) \
		--enable-pixbuf-loader \
		"${myconf[@]}"

	if multilib_is_native_abi; then
		ln -s "${S}"/doc/html doc/html || die
	fi
}

multilib_src_compile() {
	# causes segfault if set, see bug #411765
	unset __GL_NO_DSO_FINALIZER
	gnome2_src_compile
}

multilib_src_install() {
	gnome2_src_install
}

pkg_postinst() {
	# causes segfault if set, see bug 375615
	unset __GL_NO_DSO_FINALIZER
	multilib_foreach_abi gnome2_pkg_postinst
}

pkg_postrm() {
	# causes segfault if set, see bug 375615
	unset __GL_NO_DSO_FINALIZER
	multilib_foreach_abi gnome2_pkg_postrm
}