[gentoo-commits] gentoo-x86 commit in sci-libs/libsvm: ChangeLog libsvm-2.90.ebuild

[Justin Lecher (jlec)]

jlec        10/02/10 21:21:08

  Modified:             ChangeLog
  Added:                libsvm-2.90.ebuild
  Log:
  Version bump per bug 304329
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 sci-libs/libsvm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/libsvm/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/libsvm/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/libsvm/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/libsvm/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	15 Aug 2009 00:08:44 -0000	1.15
+++ ChangeLog	10 Feb 2010 21:21:07 -0000	1.16
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/libsvm
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/ChangeLog,v 1.15 2009/08/15 00:08:44 bicatali Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/ChangeLog,v 1.16 2010/02/10 21:21:07 jlec Exp $
+
+*libsvm-2.90 (10 Feb 2010)
+
+  10 Feb 2010; Justin Lecher (jlec) <jlec@g.o>
+  +files/2.90-fpic.patch, +libsvm-2.90.ebuild, +files/2.90-ldflags.patch:
+  Version bump per bug 304329
 
 *libsvm-2.89 (15 Aug 2009)
 



1.1                  sci-libs/libsvm/libsvm-2.90.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/libsvm/libsvm-2.90.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sci-libs/libsvm/libsvm-2.90.ebuild?rev=1.1&content-type=text/plain

Index: libsvm-2.90.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/libsvm/libsvm-2.90.ebuild,v 1.1 2010/02/10 21:21:07 jlec Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"

inherit eutils java-pkg-opt-2 python toolchain-funcs multilib

MY_P="${PN}-${PV%0}"

DESCRIPTION="Library for Support Vector Machines"
HOMEPAGE="http://www.csie.ntu.edu.tw/~cjlin/libsvm/"
SRC_URI="http://www.csie.ntu.edu.tw/~cjlin/libsvm/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="java python tools"

DEPEND="java? ( >=virtual/jdk-1.4 )"
RDEPEND="${DEPEND}
	tools? ( sci-visualization/gnuplot )"

RESTRICT_PYTHON_ABIS="3.*"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${PV}-fpic.patch
	epatch "${FILESDIR}"/${PV}-ldflags.patch
	python_copy_sources --no-link
}

src_compile() {
	emake \
		CXX="$(tc-getCXX)" \
		LDFLAGS="${LDFLAGS}" \
		CFLAGS="${CXXFLAGS}" \
		|| die "emake failed"

	sed -i -e 's@\.\./@/usr/bin/@g' tools/*.py \
		|| die "Failed to fix paths in python files"

	if use python ; then
		compilation () {
			pushd python
			emake \
				CXX="$(tc-getCXX)" \
				LDFLAGS="${LDFLAGS} -shared" \
				CFLAGS="${CXXFLAGS} -I$(python_get_includedir) -I.." \
				all || die "emake for python modules failed"
			popd
		}
		python_execute_function -s compilation
	fi

	if use java ; then
		pushd java
		local JAVAC_FLAGS="$(java-pkg_javac-args)"
		sed -i \
			-e "s/JAVAC_FLAGS =/JAVAC_FLAGS=${JAVAC_FLAGS}/g" \
			Makefile || die "Failed to fix java makefile"
		emake || die "emake for java modules failed"
		popd
	fi
}

src_install() {
	dobin svm-train svm-predict svm-scale \
		|| die "Failed to install binaries"
	dohtml FAQ.html || die
	dodoc README || die

	if use tools; then
		pushd tools
		insinto /usr/share/${PN}/tools
		doins easy.py grid.py subset.py \
			|| die "Failed to install python tools"
		docinto tools
		dodoc README || die
		popd
	fi

	if use python ; then
		installation() {
			pushd python
			insinto $(python_get_sitedir)
			doins svmc.so svm.py \
				|| die "Failed to install python scripts"
			docinto python
			dodoc README || die
			popd
		}
		python_execute_function -s installation
	fi

	if use java; then
		pushd java
		java-pkg_dojar libsvm.jar
		docinto java
		dohtml test_applet.html || die
		popd
	fi
}