[gentoo-commits] gentoo-x86 commit in gnome-extra/cjs: cjs-2.6.1.ebuild ChangeLog cjs-2.4.1.ebuild

[Pacho Ramos (pacho)]

pacho       15/07/04 19:34:51

  Modified:             ChangeLog
  Added:                cjs-2.6.1.ebuild
  Removed:              cjs-2.4.1.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.18                 gnome-extra/cjs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cjs/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cjs/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cjs/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/cjs/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	26 Jun 2015 09:22:21 -0000	1.17
+++ ChangeLog	4 Jul 2015 19:34:51 -0000	1.18
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/cjs
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cjs/ChangeLog,v 1.17 2015/06/26 09:22:21 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cjs/ChangeLog,v 1.18 2015/07/04 19:34:51 pacho Exp $
+
+*cjs-2.6.1 (04 Jul 2015)
+
+  04 Jul 2015; Pacho Ramos <pacho@g.o> +cjs-2.6.1.ebuild,
+  -cjs-2.4.1.ebuild:
+  Version bump, drop old
 
   26 Jun 2015; Agostino Sarubbo <ago@g.o> cjs-2.4.2.ebuild:
   Stable for x86, wrt bug #551814



1.1                  gnome-extra/cjs/cjs-2.6.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cjs/cjs-2.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/cjs/cjs-2.6.1.ebuild?rev=1.1&content-type=text/plain

Index: cjs-2.6.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/cjs/cjs-2.6.1.ebuild,v 1.1 2015/07/04 19:34:51 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit autotools eutils gnome2 pax-utils virtualx

DESCRIPTION="Linux Mint's fork of gjs for Cinnamon"
HOMEPAGE="http://cinnamon.linuxmint.com/"
SRC_URI="https://github.com/linuxmint/cjs/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT || ( MPL-1.1 LGPL-2+ GPL-2+ )"
SLOT="0"
IUSE="+cairo examples gtk test"
KEYWORDS="~amd64 ~x86"

RDEPEND="
	dev-lang/spidermonkey:24
	>=dev-libs/glib-2.37.3:2
	>=dev-libs/gobject-introspection-1.38:=
	sys-libs/readline:0
	virtual/libffi
	cairo? ( x11-libs/cairo[X,glib] )
	gtk? ( x11-libs/gtk+:3 )
"
DEPEND="${RDEPEND}
	gnome-base/gnome-common
	sys-devel/gettext
	virtual/pkgconfig
	test? ( sys-apps/dbus )
"
# Cinnamon 2.2 does not work with this release.
RDEPEND="${RDEPEND}
	!<gnome-extra/cinnamon-2.4
"

src_prepare() {
	# Disable broken unittests
	epatch "${FILESDIR}"/${PN}-2.4.0-disable-unittest-*.patch

	epatch_user
	eautoreconf
	gnome2_src_prepare
}

src_configure() {
	# FIXME: add systemtap/dtrace support, like in glib:2
	# FIXME: --enable-systemtap installs files in ${D}/${D} for some reason
	# XXX: Do NOT enable coverage, completely useless for portage installs
	gnome2_src_configure \
		--disable-systemtap \
		--disable-dtrace \
		--disable-coverage \
		$(use_with cairo) \
		$(use_with gtk)
}

src_test() {
	Xemake check
}

src_install() {
	# installation sometimes fails in parallel
	gnome2_src_install -j1

	if use examples; then
		insinto /usr/share/doc/"${PF}"/examples
		doins "${S}"/examples/*
	fi

	# Required for cjs-console to run correctly on PaX systems
	pax-mark mr "${ED}/usr/bin/cjs-console"
}