[gentoo-commits] repo/gentoo:master commit in: dev-db/pgadmin4/

[Aaron Swenson]

commit:     4be4856d252001212065b46eb8dbc0acb21b6ede
Author:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
AuthorDate: Mon Oct  8 10:21:57 2018 +0000
Commit:     Aaron Swenson <titanofold <AT> gentoo <DOT> org>
CommitDate: Mon Oct  8 10:22:06 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4be4856d

dev-db/pgadmin4: Bump to 3.4

Package-Manager: Portage-2.3.49, Repoman-2.3.11
Signed-off-by: Aaron Swenson <titanofold <AT> gentoo.org>

 dev-db/pgadmin4/Manifest            |   1 +
 dev-db/pgadmin4/pgadmin4-3.4.ebuild | 124 ++++++++++++++++++++++++++++++++++++
 2 files changed, 125 insertions(+)

diff --git a/dev-db/pgadmin4/Manifest b/dev-db/pgadmin4/Manifest
index 5be8e557718..8d01298482e 100644
--- a/dev-db/pgadmin4/Manifest
+++ b/dev-db/pgadmin4/Manifest
@@ -1,2 +1,3 @@
 DIST pgadmin4-3.0.tar.gz 28915010 BLAKE2B 7e6dccd91f082f7b5514f5d3abdf4653a9961b4efc706e10ce58d817785d514508233e25068762fe0e4bca4c1a3cf10a2515afa38e6f9ba3c99b4af3fa32f3d2 SHA512 5921340176e6748ef13112d906061f195d4bb2f73917d762371bbaeb44ef66cf8e0edcd1cd241eb78dae46ed0b3af014c749468a930fb0c0983b38b2c54dfc3a
 DIST pgadmin4-3.3.tar.gz 30471775 BLAKE2B 06fe13d4e87709aa7ea5a7eef0aa5c7f3aae6891da0c4414fdf5e8936bb6bb7ac9092fd1e4f32f2f253fad7ace5fb8bdf07fed7ccb6dac68175fee5db2d27f4f SHA512 25027298a51d2ce01902fcd2314e35a44dfb5e3d7f6f5f1620841488bd5b8215436ffcad102fe9846ed4a9dee550232cb0b03c2ee0d5f46f53c753c8107e7ec3
+DIST pgadmin4-3.4.tar.gz 30743447 BLAKE2B 4476989dc9bd672810ced56f4c3e6b87f27ec28d693ab6a909b1cdd4ddc0ae51552fe7ac5a3db4382ccded433b1dab239de01697c0709474381c117460a45163 SHA512 57160827a7577b89029a3a621653f2fec9f3b5379a554ea8bcaf80225f32f1ed93e4560ce5d5b499aff2091589e641bdfe82987be46b6155bca3fb072cf2c5e2

diff --git a/dev-db/pgadmin4/pgadmin4-3.4.ebuild b/dev-db/pgadmin4/pgadmin4-3.4.ebuild
new file mode 100644
index 00000000000..635fba4bdbc
--- /dev/null
+++ b/dev-db/pgadmin4/pgadmin4-3.4.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 qmake-utils
+
+DESCRIPTION="GUI administration and development platform for PostgreSQL"
+HOMEPAGE="https://www.pgadmin.org/"
+SRC_URI="mirror://postgresql/pgadmin/${PN}/v${PV}/source/${P}.tar.gz"
+
+LICENSE="POSTGRESQL"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="doc"
+
+RESTRICT="test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	dev-qt/qtwidgets:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwebengine:5[widgets]
+"
+
+DEPEND="${COMMON_DEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=app-text/htmlmin-0.1.12[${PYTHON_USEDEP}]
+	>=dev-python/Babel-2.3.4[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/blinker-1.4[${PYTHON_USEDEP}]
+	>=dev-python/click-6.6[${PYTHON_USEDEP}]
+	>=dev-python/extras-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-babel-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-babelex-0.9.3[${PYTHON_USEDEP}]
+	>=dev-python/flask-gravatar-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-htmlmin-1.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-login-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-mail-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-migrate-2.1.1[${PYTHON_USEDEP}]
+	>=dev-python/flask-paranoid-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-principal-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-security-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-sqlalchemy-2.3.2[${PYTHON_USEDEP}]
+	>=dev-python/flask-wtf-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.24[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.7.3[${PYTHON_USEDEP}]
+	>=dev-python/linecache2-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-0.23[${PYTHON_USEDEP}]
+	>=dev-python/mimeparse-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/passlib-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pbr-3.1.1[${PYTHON_USEDEP}]
+	>=dev-python/psycopg-2.7.4[${PYTHON_USEDEP}]
+	>=dev-python/pycrypto-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/pyrsistent-0.14.2[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.7.1[${PYTHON_USEDEP}]
+	>=dev-python/python-sqlparse-0.2.4[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2018.3[${PYTHON_USEDEP}]
+	>=dev-python/simplejson-3.13.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/speaklater-1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.2.5[${PYTHON_USEDEP}]
+	>=dev-python/sshtunnel-0.1.3[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.9.6[${PYTHON_USEDEP}]
+	>=dev-python/wtforms-2.1[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}"/${P}/runtime
+
+src_prepare() {
+	cd "${WORKDIR}"/${P} || die
+	default
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_compile() {
+	default
+	if use doc; then
+		cd "${WORKDIR}"/${P} || die
+		emake docs
+	fi
+}
+
+src_install() {
+	dobin pgAdmin4
+
+	cd "${WORKDIR}"/${P} || die
+
+	local APP_DIR=/usr/share/${PN}/web
+	insinto "${APP_DIR}"
+	doins -r web/*
+	cat > "${D}${APP_DIR}"/config_local.py <<-EOF
+		SERVER_MODE = False
+		UPGRADE_CHECK_ENABLED = False
+	EOF
+	python_optimize "${D}${APP_DIR}"
+
+	local CONFIG_DIR="/etc/xdg/pgadmin"
+	dodir "${CONFIG_DIR}"
+	cat > "${D}${CONFIG_DIR}"/pgadmin4.conf <<-EOF
+		[General]
+		ApplicationPath=${APP_DIR}
+		PythonPath=$(python_get_sitedir)
+	EOF
+
+	if use doc; then
+		rm -r docs/en_US/_build/html/_sources || die
+		insinto /usr/share/${PN}/docs/en_US/_build
+		doins -r docs/en_US/_build/html
+	fi
+}