[gentoo-commits] gentoo-x86 commit in net-im/psi: psi-9999.ebuild metadata.xml ChangeLog psi-0.14-r1.ebuild psi-0.13.ebuild

[Peter Volkov (pva)]

pva         10/06/01 10:42:11

  Modified:             metadata.xml ChangeLog psi-0.14-r1.ebuild
  Added:                psi-9999.ebuild
  Removed:              psi-0.13.ebuild
  Log:
  Added VCS version of psi, thank Nikoli for this job and Rion for review.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  net-im/psi/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/metadata.xml?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/metadata.xml?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/metadata.xml?r1=1.7&r2=1.8

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/psi/metadata.xml,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- metadata.xml	4 Dec 2009 09:44:02 -0000	1.7
+++ metadata.xml	1 Jun 2010 10:42:11 -0000	1.8
@@ -7,7 +7,12 @@
 </maintainer>
 <longdescription>Psi is a very good jabber client that uses QT</longdescription>
 <use>
+	<flag name='enchant'>Use enchant spell engine instead of aspell</flag>
 	<flag name='extras'>Enables extra non official patches</flag>
+	<flag name='iconsets'>Install additional iconsets, some of them has not clear licensing</flag>
+	<flag name='plugins'>Enable plugins support</flag>
+	<flag name='powersave'>Disable some non critical timers for much less CPU usage</flag>
 	<flag name='webkit'>Enable chatlog rendering using webkit</flag>
+	<flag name='whiteboarding'>Enable experimental interactive SVG drawing</flag>
 </use>
 </pkgmetadata>



1.190                net-im/psi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/ChangeLog?rev=1.190&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/ChangeLog?rev=1.190&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/ChangeLog?r1=1.189&r2=1.190

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/psi/ChangeLog,v
retrieving revision 1.189
retrieving revision 1.190
diff -u -r1.189 -r1.190
--- ChangeLog	1 Jun 2010 10:19:34 -0000	1.189
+++ ChangeLog	1 Jun 2010 10:42:11 -0000	1.190
@@ -1,6 +1,12 @@
 # ChangeLog for net-im/psi
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/psi/ChangeLog,v 1.189 2010/06/01 10:19:34 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/psi/ChangeLog,v 1.190 2010/06/01 10:42:11 pva Exp $
+
+*psi-9999 (01 Jun 2010)
+
+  01 Jun 2010; Peter Volkov <pva@g.o> -psi-0.13.ebuild,
+  psi-0.14-r1.ebuild, +psi-9999.ebuild, metadata.xml:
+  Added VCS version of psi, thank Nikoli for this job and Rion for review.
 
   01 Jun 2010; Peter Volkov <pva@g.o> psi-0.14-r1.ebuild:
   Added app-crypt/qca-ossl:2 dependency for hmac support missing for voice



1.8                  net-im/psi/psi-0.14-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/psi-0.14-r1.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/psi-0.14-r1.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/psi-0.14-r1.ebuild?r1=1.7&r2=1.8

Index: psi-0.14-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/psi/psi-0.14-r1.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- psi-0.14-r1.ebuild	1 Jun 2010 10:19:34 -0000	1.7
+++ psi-0.14-r1.ebuild	1 Jun 2010 10:42:11 -0000	1.8
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/psi/psi-0.14-r1.ebuild,v 1.7 2010/06/01 10:19:34 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/psi/psi-0.14-r1.ebuild,v 1.8 2010/06/01 10:42:11 pva Exp $
 
 EAPI="2"
 
@@ -42,7 +42,7 @@
 	doc? ( app-doc/doxygen )"
 
 PDEPEND="crypt? ( app-crypt/qca-gnupg:2 )
-	jingle? ( net-im/psimedia 
+	jingle? ( net-im/psimedia
 		app-crypt/qca-ossl:2 )
 	ssl? ( app-crypt/qca-ossl:2 )"
 



1.1                  net-im/psi/psi-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/psi-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/psi/psi-9999.ebuild?rev=1.1&content-type=text/plain

Index: psi-9999.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/psi/psi-9999.ebuild,v 1.1 2010/06/01 10:42:11 pva Exp $

EAPI="2"

LANGS="ar be bg br ca cs da de ee el eo es et fi fr hr hu it ja mk nl pl pt pt_BR ru se sk sl sr sr@latin sv sw uk ur_PK vi zh_CN zh_TW"

EGIT_REPO_URI="git://git.psi-im.org/psi.git"
EGIT_HAS_SUBMODULES="true"
LANGS_URI="git://pv.et-inf.fho-emden.de/git/psi-l10n"

ESVN_DISABLE_DEPENDENCIES="true"
BASE_URI="http://psi-dev.googlecode.com/svn/trunk"
ESVN_PROJECT="psiplus"

inherit eutils qt4-r2 multilib git subversion

DESCRIPTION="Qt4 Jabber client, with Licq-like interface"
HOMEPAGE="http://psi-im.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="crypt dbus debug doc enchant extras jingle iconsets spell ssl xscreensaver powersave
plugins -whiteboarding webkit"

RDEPEND=">=x11-libs/qt-gui-4.4:4[qt3support,dbus?]
	>=app-crypt/qca-2.0.2:2
	whiteboarding? ( x11-libs/qt-svg:4 )
	spell? (
		enchant? ( >=app-text/enchant-1.3.0 )
		!enchant? ( app-text/aspell )
	)
	xscreensaver? ( x11-libs/libXScrnSaver )
	extras? ( webkit? ( x11-libs/qt-webkit ) )
	app-arch/unzip"

DEPEND="${RDEPEND}
	extras? (
		${SUBVERSION_DEPEND}
		sys-devel/qconf
	)
	doc? ( app-doc/doxygen )"

PDEPEND="crypt? ( app-crypt/qca-gnupg:2 )
	jingle? (
		net-im/psimedia
		app-crypt/qca-ossl:2
		)
	ssl? ( app-crypt/qca-ossl:2 )"

RESTRICT="test"

pkg_setup() {
	for x in iconsets plugins powersave webkit whiteboarding;do
	        use ${x} && use !extras && \
			ewarn "USE=${x} is only available in Psi+ and requires USE=extras, ${x} will be disabled."
	done

	if use extras; then
		ewarn
		ewarn "You're about to build heavily patched version of Psi called Psi+."
		ewarn "It has really nice features but still is under heavy development."
		ewarn "Take a look at homepage for more info: http://code.google.com/p/psi-dev"
		ewarn "If you wish to disable some patches just put"
		ewarn "MY_EPATCH_EXCLUDE=\"list of patches\""
		ewarn "into /etc/portage/env/${CATEGORY}/${PN} file."
		ewarn
		ewarn "Note: some patches depend on other. So if you disabled some patch"
		ewarn "and other started to fail to apply, you'll have to disable patches"
		ewarn "that fail too."
		ebeep

		if use iconsets; then
			ewarn
			ewarn "Some artwork is from open source projects, but some is provided 'as-is'"
			ewarn "and has not clear licensing."
			ewarn "Possibly this build is not redistributable in some countries."
		fi
	fi
}

src_unpack() {
	git_src_unpack

	# fetch translations
	mkdir "${WORKDIR}/psi-l10n"
	for x in ${LANGS}; do
		if use linguas_${x}; then
			EGIT_REPO_URI="${LANGS_URI}-${x}"
			EGIT_PROJECT="psi-l10n/${x}"
			S="${WORKDIR}/psi-l10n/${x}"
			git_fetch
		fi
	done

	if use extras; then
		S="${WORKDIR}/patches"
		ESVN_REPO_URI="${BASE_URI}/patches"
		subversion_fetch
		if use iconsets; then
			S="${WORKDIR}/${P}/iconsets"
			ESVN_REPO_URI="${BASE_URI}/iconsets"
			subversion_fetch
		else
			for x in clients moods activities system; do
				S="${WORKDIR}/${P}/iconsets/${x}/default"
				ESVN_REPO_URI="${BASE_URI}/iconsets/${x}/default"
				ESVN_PROJECT="psiplus/${x}"
				subversion_fetch
			done
		fi
	fi

	S="${WORKDIR}/${P}"
}

src_prepare() {
	rm -rf third-party/qca # We use system libraries.

	if use extras; then
		EPATCH_EXCLUDE="${MY_EPATCH_EXCLUDE}
			*-win32-*
			*dirty-check*" \
		EPATCH_SOURCE="${WORKDIR}/patches/" EPATCH_SUFFIX="diff" EPATCH_FORCE="yes" epatch

		use powersave && epatch "${WORKDIR}/patches/dev/psi-reduce-power-consumption.patch"

		if use whiteboarding; then
			sed -e 's/#CONFIG += whiteboarding/CONFIG += whiteboarding/' \
				-i src/src.pro || die "sed failed"
			epatch "${WORKDIR}/patches/dev/psi-wb.patch"

			ewarn "Whiteboarding is very unstable."
		fi

		subversion_wc_info
		sed -e "s/.xxx/.${ESVN_WC_REVISION}/" \
			-i src/applicationinfo.cpp || die "sed failed"

		qconf || die "Failed to create ./configure."
	fi
}

src_configure() {
	# unable to use econf because of non-standard configure script
	# disable growl as it is a MacOS X extension only
	local confcmd="./configure
			--prefix=/usr
			--qtdir=/usr
			--disable-bundled-qca
			--disable-growl
			$(use dbus || echo '--disable-qdbus')
			$(use debug && echo '--debug')
			$(use spell && {
				use enchant && echo '--disable-aspell' || echo '--disable-enchant'
				} || echo '--disable-aspell --disable-enchant')
			$(use xscreensaver || echo '--disable-xss')
			$(use extras && {
				use plugins && echo '--enable-plugins'
				use webkit && echo '--enable-webkit'
				} )"

	echo "${confcmd}"
	${confcmd} || die "configure failed"
}

src_compile() {
	eqmake4

	emake || die "emake failed"

	if use doc; then
		cd doc
		mkdir -p api # 259632
		make api_public || die "make api_public failed"
	fi
}

src_install() {
	emake INSTALL_ROOT="${D}" install || die "emake install failed"
	rm "${D}"/usr/share/psi/{COPYING,README}

	# this way the docs will be installed in the standard gentoo dir
	newdoc iconsets/roster/README README.roster || die
	newdoc iconsets/system/README README.system || die
	newdoc certs/README README.certs || die
	dodoc README || die

	if use doc; then
		cd doc
		dohtml -r api || die "dohtml failed"
	fi

	# install translations
	cd "${WORKDIR}/psi-l10n"
	insinto /usr/share/${PN}
	for x in ${LANGS}; do
		if use linguas_${x}; then
			lrelease "${x}/${PN}_${x}.ts" || die "lrelease ${x} failed"
			doins "${x}/${PN}_${x}.qm" || die
			newins "${x}/INFO" "INFO.${x}" || die
		fi
	done

	if use extras; then
		if use plugins; then
			cd "${S}"
			insinto /usr/share/psi/plugins
			doins src/plugins/plugins.pri || die
			doins src/plugins/psiplugin.pri || die
			doins -r src/plugins/include || die
			dosed "s:target.path.*:target.path = /usr/$(get_libdir)/psi/plugins:" \
				/usr/share/psi/plugins/psiplugin.pri \
				|| die "sed failed"
		fi
	fi
}