[gentoo-commits] repo/gentoo:master commit in: mail-filter/milter-regex/

[Joonas Niilola]

commit:     bbf239910090ec61430dc07c32c6c662207948c9
Author:     Ralph Seichter <github <AT> seichter <DOT> de>
AuthorDate: Tue Oct 18 07:15:20 2022 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Nov  2 14:24:25 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bbf23991

mail-filter/milter-regex: Expand LICENSE variable

Include GPL v2 (license for the init file)

Closes: https://bugs.gentoo.org/425958
Signed-off-by: Ralph Seichter <github <AT> seichter.de>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 .../milter-regex/milter-regex-2.7-r3.ebuild        | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/mail-filter/milter-regex/milter-regex-2.7-r3.ebuild b/mail-filter/milter-regex/milter-regex-2.7-r3.ebuild
new file mode 100644
index 000000000000..fcbf4fdc4295
--- /dev/null
+++ b/mail-filter/milter-regex/milter-regex-2.7-r3.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="A milter-based regular expression filter"
+HOMEPAGE="https://www.benzedrine.ch/milter-regex.html"
+SRC_URI="https://www.benzedrine.ch/${P}.tar.gz"
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="acct-user/milter-regex
+	>=mail-filter/libmilter-1.0.2_p2:="
+DEPEND="${RDEPEND}
+	virtual/yacc"
+
+src_prepare() {
+	eapply "${FILESDIR}/${PN}-2.6-gentoo.patch"
+	eapply "${FILESDIR}"/milter-regex-2.7-implicit-func-decl.patch
+	eapply_user
+	# Change default user
+	sed -i -e 's/_\(milter-regex\)/\1/g' ${PN}.[8c] || die
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" -f Makefile.linux all
+}
+
+src_install() {
+	dobin ${PN}
+	insinto /etc
+	newins rules ${PN}.conf
+	newconfd "${FILESDIR}/${PN}-conf-2.6" ${PN}
+	newinitd "${FILESDIR}/${PN}-init" ${PN}
+	doman *.8
+}
+
+pkg_postinst() {
+	elog "Postfix configuration example (add to main.cf or master.cf):"
+	elog "  smtpd_milters=unix:/run/milter-regex/socket"
+	elog "Sendmail configuration example:"
+	elog "  INPUT_MAIL_FILTER(\`${PN}',\`S=unix:/run/milter-regex/socket,T=S:30s;R:2m')"
+}