[gentoo-commits] repo/gentoo:master commit in: dev-python/jaraco-functools/

[Louis Sautier]

commit:     86cd6883fad465a19c481b7ea697419edc4b9c15
Author:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
AuthorDate: Wed Jul  4 19:46:19 2018 +0000
Commit:     Louis Sautier <sbraz <AT> gentoo <DOT> org>
CommitDate: Wed Jul  4 20:29:48 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86cd6883

dev-python/jaraco-functools: bump to 1.20

Package-Manager: Portage-2.3.41, Repoman-2.3.9

 dev-python/jaraco-functools/Manifest               |  1 +
 .../jaraco-functools/jaraco-functools-1.20.ebuild  | 60 ++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-python/jaraco-functools/Manifest b/dev-python/jaraco-functools/Manifest
index 9e081706ca7..b7319d7b87b 100644
--- a/dev-python/jaraco-functools/Manifest
+++ b/dev-python/jaraco-functools/Manifest
@@ -1,2 +1,3 @@
 DIST jaraco.functools-1.15.1.tar.gz 8744 BLAKE2B 191e37d977256fe92158cb2057af42a62f86a866428719fddc8ef6487f55c6ca6403e9dc41c8bb4370752182653574f9d9ddba15878f76c48fb176de6b25667f SHA512 0b65bc36a2338775d4879dd7502b50b930a12458512061ceba65ada86df2658f4fcce4a4e523580239b302a34a8bf90adcfdeaf8f0b2169d704a3a74457424bb
 DIST jaraco.functools-1.19.tar.gz 10588 BLAKE2B c71eb4e0c611f6a0bd82e04cacb7933961ba5e50091439c274bd8ceeda68b69789423994fe43f44af6cdd643b7a04418bc32ce2f937d118520298a019c5c6638 SHA512 7fbf1956ff8a132021e1f7fae5e98f40199a5d0e705b08b44ad5b2588fdd7d1088db9d7457b985c1852b50285a8f03cc9795fff0c4f53f9155f7c8ec371ff307
+DIST jaraco.functools-1.20.tar.gz 11063 BLAKE2B c202c3cda86c0f32fb3299a083ebb8d584eec444d9d8f0eff536f5e663634dab03c5831aef18d683dddde7eafff311b66a724d9004ad46f5ef92e90df16a9c7d SHA512 ba17b567dfcadb0d8ff1cc7a6ed07f2a23abfd42e73f3d815a6fa19d9be97d6af0c90bff7fb5e7ef67012ea5d931e9babc963da8a7105ba6a92d5c43c7126e04

diff --git a/dev-python/jaraco-functools/jaraco-functools-1.20.ebuild b/dev-python/jaraco-functools/jaraco-functools-1.20.ebuild
new file mode 100644
index 00000000000..74eb81aba71
--- /dev/null
+++ b/dev-python/jaraco-functools/jaraco-functools-1.20.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Additional functions used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.functools"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/namespace-jaraco[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-functools-lru-cache[${PYTHON_USEDEP}]' python2_7)
+"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	PYTHONPATH=. py.test --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+	}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}