[gentoo-commits] repo/gentoo:master commit in: net-wireless/gnuradio/

[Michael Weber]

commit:     466390e8aa5675a886c5d3b01a281fec285ff9f2
Author:     Michael Weber <xmw <AT> gentoo <DOT> org>
AuthorDate: Fri Apr  7 23:02:50 2017 +0000
Commit:     Michael Weber <xmw <AT> gentoo <DOT> org>
CommitDate: Mon Apr 10 07:54:00 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=466390e8

net-wireless/gnuradio: Version bump.

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 net-wireless/gnuradio/Manifest               |   1 +
 net-wireless/gnuradio/gnuradio-3.7.11.ebuild | 236 +++++++++++++++++++++++++++
 2 files changed, 237 insertions(+)

diff --git a/net-wireless/gnuradio/Manifest b/net-wireless/gnuradio/Manifest
index 95e5faa13b4..60f211a7272 100644
--- a/net-wireless/gnuradio/Manifest
+++ b/net-wireless/gnuradio/Manifest
@@ -1,6 +1,7 @@
 DIST gnuradio-3.6.5.1.tar.gz 3150283 SHA256 0875d2f0a7da0f3bcc1771b528b0f98f79d9ab69aa1ef953651bbbe1f57b4621 SHA512 23a22aed482da11005b17e5197ee3ba24d442b30309522b0858e694b58f46b76cc050143d365623c7dd4241cdf8b9f988e1a4dabe2e1f98d0fd4cca71bbb82e8 WHIRLPOOL 7cf55be5fac7891a737d228d83718bbc43f9069c6275c5ac465ae11088559dca5e7fa31239e281271b529aa8b9ae1a0efe3850a16a40e53c0f1fe57e351ff2a8
 DIST gnuradio-3.7.10.1.tar.gz 4272430 SHA256 63d7b65cc4abe22f47b8f41caaf7370a0a502b91e36e29901ba03e8838ab4937 SHA512 101ea704e25d8ddc1b124c3be23b5020f3f504cab7b2762ba41172d8d07822018e583179e8d15d2b4c224fb8fad68ea4b5e135bcb40126aa6317ee51c47883f6 WHIRLPOOL 07d66f0eb84472992b7e9434a4f4e92aea7e54e54ebe9d095d34adb771d5ff8670f7f282ab286557e2c7dbb81df4c2f1aa2269d14edab0c0af1746096eeb618c
 DIST gnuradio-3.7.10.2.tar.gz 4354889 SHA256 30373d8410f7590f3dcb8046dd142b8179a395c34e9759644128186cd6b4c8fb SHA512 caf389314708c219ef77a6b7111ecffdb074bc5be047fa127706cad7b785ec1262f60b0416d8c4ce1baf769f822f2f571d6e14eef8066636a53568fcfa68dbe2 WHIRLPOOL 990f588fa2f35bbf582ee518f5a80fd2603614df424f906737d57b532006a0f36e0401d5685c13a915f735fc0cc1038d2f66554de388afa169fabe6333449ef4
+DIST gnuradio-3.7.11.tar.gz 4357123 SHA256 87d9ba3183858efdbb237add3f9de40f7d65f25e16904a9bc8d764a7287252d4 SHA512 a3b44e04e63056ad5238ddbda7967ebaf5802d2ed7e24649190bde67a533b50780ec1260dc7710c5388c966b71e153d3d21468bbfee4529c62ac5b89b589dd14 WHIRLPOOL 4f5a7fe93dd88773df85206a3fc07f51977f7d05f728222f211ce95f4d34590060e7b3637ef1e720b74f3cb0e0d7cdb0889435de73eb7b56ffbdf4313be01151
 DIST gnuradio-3.7.6.1.tar.gz 3588833 SHA256 39dede70eec36f430c4895900bbd7ed266aa9e846d0a362987e806b7197c4c0b SHA512 88ec30b2bd93ca032c29f4606856a8e70b0123474fd84115657804429f381dea78f97a7523c9684acad6a27b357ddf876632e957de5c6e0170045dc38d121939 WHIRLPOOL 97d70e403fe46b0afbd1e6f0812f8d9de4ea506dcb2190a23d9a0f0499662f9e2bbaa86d1b624f7c621ae1675094f92cd295bc273db0759b2647e2dfb2a49b43
 DIST gnuradio-3.7.7.1.tar.gz 3845988 SHA256 2b27b13fc734ab5882e42c1661d433c0c097fd8b55b682f00626fa96c356584e SHA512 7be9568d19cbe03f3c229dbda5fc8d448a4a57d84bd9f8b91a400c65b526414539536c0a391b15d5f0e63bf22ef5675dc3ed8a6ed94ce3b1e4328948fa202ba1 WHIRLPOOL c54e26af37ecb27dd515d1ca320ccf363f6a9bbff61724f7d98f751d69a32ba21f2a631ce07caf273596f4297ff92359d2469768cd927ae9d680c8a8bbd25dbd
 DIST gnuradio-3.7.8.1.tar.gz 3962961 SHA256 8406f49d085fdc2ef5d8ea90f3e19ad8782d2a2f5154bbe4f076591ddf7ae5aa SHA512 21468335d698963ce5090b03b980ecc3714c301f3cd5d071d8a1b083c3c985479c42ee6d842b1b600ac85640ce875fb2bbfd6f51d30144cb612ac55e648c0c9a WHIRLPOOL 94d1b357539299b74b9f08659426ade1fa6ac3ae6950ec4ffe6797eadaca06785c4707ea1db3500c5b57395e6f7e8c0f14718d00c556aaf6537835ebb6969b7a

diff --git a/net-wireless/gnuradio/gnuradio-3.7.11.ebuild b/net-wireless/gnuradio/gnuradio-3.7.11.ebuild
new file mode 100644
index 00000000000..6a1a788a7f6
--- /dev/null
+++ b/net-wireless/gnuradio/gnuradio-3.7.11.ebuild
@@ -0,0 +1,236 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+CMAKE_BUILD_TYPE="None"
+inherit cmake-utils fdo-mime gnome2-utils python-single-r1 eutils
+
+DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
+HOMEPAGE="http://gnuradio.org/"
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="http://gnuradio.org/git/gnuradio.git"
+	inherit git-r3
+	KEYWORDS=""
+else
+	SRC_URI="http://gnuradio.org/releases/gnuradio/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~x86"
+fi
+
+IUSE="+audio +alsa atsc +analog +digital channels doc dtv examples fcd fec +filter grc jack log noaa oss pager performance-counters portaudio +qt4 sdl test trellis uhd vocoder +utils wavelet wxwidgets zeromq"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+		audio? ( || ( alsa oss jack portaudio ) )
+		alsa? ( audio )
+		oss? ( audio )
+		jack? ( audio )
+		portaudio? ( audio )
+		analog? ( filter )
+		digital? ( filter analog )
+		dtv? ( fec )
+		pager? ( filter analog )
+		qt4? ( filter )
+		uhd? ( filter analog )
+		fcd? ( || ( alsa oss ) )
+		wavelet? ( analog )
+		wxwidgets? ( filter analog )"
+
+# bug #348206
+# comedi? ( >=sci-electronics/comedilib-0.8 )
+# boost-1.52.0 is blacklisted, bug #461578, upstream #513, boost #7669
+RDEPEND="${PYTHON_DEPS}
+	>=dev-lang/orc-0.4.12
+	dev-libs/boost:0=[${PYTHON_USEDEP}]
+	!<=dev-libs/boost-1.52.0-r6:0/1.52
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/fftw:3.0=
+	alsa? (
+		media-libs/alsa-lib[${PYTHON_USEDEP}]
+	)
+	fcd? ( virtual/libusb:1 )
+	filter? ( sci-libs/scipy )
+	grc? (
+		dev-python/cheetah[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		>=dev-python/pygtk-2.10:2[${PYTHON_USEDEP}]
+	)
+	jack? (
+		media-sound/jack-audio-connection-kit
+	)
+	log? ( dev-libs/log4cpp )
+	portaudio? (
+		>=media-libs/portaudio-19_pre
+	)
+	qt4? (
+		>=dev-python/PyQt4-4.4[X,opengl,${PYTHON_USEDEP}]
+		>=dev-python/pyqwt-5.2:5[${PYTHON_USEDEP}]
+		>=dev-qt/qtcore-4.4:4
+		>=dev-qt/qtgui-4.4:4
+		x11-libs/qwt:6[qt4(+)]
+	)
+	sdl? ( >=media-libs/libsdl-1.2.0 )
+	uhd? ( >=net-wireless/uhd-3.4.3-r1:=[${PYTHON_USEDEP}] )
+	utils? ( dev-python/matplotlib[${PYTHON_USEDEP}] )
+	vocoder? ( media-sound/gsm )
+	wavelet? (
+		>=sci-libs/gsl-1.10
+	)
+	wxwidgets? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/wxpython:2.8[${PYTHON_USEDEP}]
+	)
+	zeromq? ( >=net-libs/zeromq-2.1.11 )
+	"
+
+DEPEND="${RDEPEND}
+	>=dev-lang/swig-3.0.5
+	dev-python/cheetah[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? (
+		>=app-doc/doxygen-1.5.7.1
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	grc? ( x11-misc/xdg-utils )
+	oss? ( virtual/os-headers )
+	test? ( >=dev-util/cppunit-1.9.14 )
+	zeromq? ( net-libs/cppzmq )
+"
+
+src_prepare() {
+	gnome2_environment_reset #534582
+
+	# Useless UI element would require qt3support, bug #365019
+	sed -i '/qPixmapFromMimeSource/d' "${S}"/gr-qtgui/lib/spectrumdisplayform.ui || die
+	epatch_user
+}
+
+src_configure() {
+	# SYSCONFDIR/GR_PREFSDIR default to install below CMAKE_INSTALL_PREFIX
+	#audio provider is still automagic
+	#zeromq missing deps isn't fatal
+	mycmakeargs=(
+		-DENABLE_DEFAULT=OFF
+		-DENABLE_GNURADIO_RUNTIME=ON
+		-DENABLE_VOLK=ON
+		-DENABLE_PYTHON=ON
+		-DENABLE_GR_BLOCKS=ON
+		-DENABLE_GR_FFT=ON
+		-DENABLE_GR_AUDIO=ON
+		$(cmake-utils_use_enable alsa GR_AUDIO_ALSA) \
+		$(cmake-utils_use_enable analog GR_ANALOG) \
+		$(cmake-utils_use_enable atsc GR_ATSC) \
+		$(cmake-utils_use_enable channels GR_CHANNELS) \
+		$(cmake-utils_use_enable digital GR_DIGITAL) \
+		$(cmake-utils_use_enable doc DOXYGEN) \
+		$(cmake-utils_use_enable doc SPHINX) \
+		$(cmake-utils_use_enable dtv GR_DTV) \
+		$(cmake-utils_use_enable fcd GR_FCD) \
+		$(cmake-utils_use_enable fec GR_FEC) \
+		$(cmake-utils_use_enable filter GR_FILTER) \
+		$(cmake-utils_use_enable grc GRC) \
+		$(cmake-utils_use_enable jack GR_AUDIO_JACK) \
+		$(cmake-utils_use_enable log GR_LOG) \
+		$(cmake-utils_use_enable noaa GR_NOAA) \
+		$(cmake-utils_use_enable oss GR_AUDIO_OSS) \
+		$(cmake-utils_use_enable pager GR_PAGER) \
+		$(cmake-utils_use_enable performance-counters ENABLE_PERFORMANCE_COUNTERS) \
+		$(cmake-utils_use_enable portaudio GR_AUDIO_PORTAUDIO) \
+		$(cmake-utils_use_enable test TESTING) \
+		$(cmake-utils_use_enable trellis GR_TRELLIS) \
+		$(cmake-utils_use_enable uhd GR_UHD) \
+		$(cmake-utils_use_enable utils GR_UTILS) \
+		$(cmake-utils_use_enable vocoder GR_VOCODER) \
+		$(cmake-utils_use_enable wavelet GR_WAVELET) \
+		$(cmake-utils_use_enable wxwidgets GR_WXGUI) \
+		$(cmake-utils_use_enable qt4 GR_QTGUI) \
+		$(cmake-utils_use_enable sdl GR_VIDEO_SDL) \
+		$(cmake-utils_use_enable zeromq GR_ZEROMQ) \
+		-DENABLE_GR_CORE=ON \
+		-DSYSCONFDIR="${EPREFIX}"/etc \
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DGR_PKG_DOC_DIR="${EPREFIX}/usr/share/doc/${PF}"
+	)
+	use vocoder && mycmakeargs+=( -DGR_USE_SYSTEM_LIBGSM=TRUE )
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use examples ; then
+		dodir /usr/share/doc/${PF}/
+		mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
+		docompress -x /usr/share/doc/${PF}/examples
+	else
+	# It seems that the examples are always installed
+		rm -rf "${ED}"/usr/share/${PN}/examples || die
+	fi
+
+	if use doc || use examples; then
+		#this doesn't appear useful
+		rm -rf "${ED}"/usr/share/doc/${PF}/xml || die
+	fi
+
+	# We install the mimetypes to the correct locations from the ebuild
+	rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
+	rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
+
+	# Install icons, menu items and mime-types for GRC
+	if use grc ; then
+		local fd_path="${S}/grc/scripts/freedesktop"
+		insinto /usr/share/mime/packages
+		doins "${fd_path}/${PN}-grc.xml"
+
+		domenu "${fd_path}/"*.desktop
+		doicon "${fd_path}/"*.png
+	fi
+
+	python_fix_shebang "${ED}"
+}
+
+src_test()
+{
+	ctest -E qtgui
+}
+
+pkg_postinst()
+{
+	local GRC_ICON_SIZES="32 48 64 128 256"
+
+	if use grc ; then
+		fdo-mime_desktop_database_update
+		fdo-mime_mime_database_update
+		for size in ${GRC_ICON_SIZES} ; do
+			xdg-icon-resource install --noupdate --context mimetypes --size ${size} \
+				"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" application-gnuradio-grc \
+				|| die "icon resource installation failed"
+			xdg-icon-resource install --noupdate --context apps --size ${size} \
+				"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" gnuradio-grc \
+				|| die "icon resource installation failed"
+		done
+		xdg-icon-resource forceupdate
+	fi
+}
+
+pkg_postrm()
+{
+	local GRC_ICON_SIZES="32 48 64 128 256"
+
+	if use grc ; then
+		fdo-mime_desktop_database_update
+		fdo-mime_mime_database_update
+		for size in ${GRC_ICON_SIZES} ; do
+			xdg-icon-resource uninstall --noupdate --context mimetypes --size ${size} \
+				application-gnuradio-grc || ewarn "icon uninstall failed"
+			xdg-icon-resource uninstall --noupdate --context apps --size ${size} \
+				gnuradio-grc || ewarn "icon uninstall failed"
+
+		done
+		xdg-icon-resource forceupdate
+	fi
+}