[gentoo-commits] gentoo-x86 commit in sys-apps/pkgcore: ChangeLog pkgcore-0.9.1.ebuild

[Tim Harder (radhermit)]

radhermit    15/06/28 21:18:10

  Modified:             ChangeLog
  Added:                pkgcore-0.9.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.188                sys-apps/pkgcore/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pkgcore/ChangeLog?rev=1.188&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pkgcore/ChangeLog?rev=1.188&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pkgcore/ChangeLog?r1=1.187&r2=1.188

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v
retrieving revision 1.187
retrieving revision 1.188
diff -u -r1.187 -r1.188
--- ChangeLog	4 Jun 2015 11:06:20 -0000	1.187
+++ ChangeLog	28 Jun 2015 21:18:10 -0000	1.188
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/pkgcore
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v 1.187 2015/06/04 11:06:20 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/ChangeLog,v 1.188 2015/06/28 21:18:10 radhermit Exp $
+
+*pkgcore-0.9.1 (28 Jun 2015)
+
+  28 Jun 2015; Tim Harder <radhermit@g.o> +pkgcore-0.9.1.ebuild:
+  Version bump.
 
   04 Jun 2015; Justin Lecher <jlec@g.o> metadata.xml:
   Add pypi to remote-id in metadata.xml



1.1                  sys-apps/pkgcore/pkgcore-0.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pkgcore/pkgcore-0.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pkgcore/pkgcore-0.9.1.ebuild?rev=1.1&content-type=text/plain

Index: pkgcore-0.9.1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pkgcore/pkgcore-0.9.1.ebuild,v 1.1 2015/06/28 21:18:10 radhermit Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit distutils-r1

if [[ ${PV} == *9999 ]] ; then
	EGIT_REPO_URI="https://github.com/pkgcore/pkgcore.git"
	inherit git-r3
else
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
fi

DESCRIPTION="pkgcore package manager"
HOMEPAGE="https://github.com/pkgcore/pkgcore"

LICENSE="|| ( BSD GPL-2 )"
SLOT="0"
IUSE="doc test"

RDEPEND=">=dev-python/snakeoil-0.6.4[${PYTHON_USEDEP}]"
DEPEND="${RDEPEND}
	dev-python/pyparsing[${PYTHON_USEDEP}]
	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
	test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )
"

pkg_setup() {
	# disable snakeoil 2to3 caching...
	unset PY2TO3_CACHEDIR

	mydistutilsargs=(
		build
		--disable-html-docs
		--disable-man-pages
	)
}

python_compile_all() {
	esetup.py $(use doc && echo 'build_docs')

	if [[ ${PV} == *9999 ]]; then
		esetup.py build_man
		ln -s "${BUILD_DIR}/sphinx/man" man || die
	fi

	# symlinks generated manpages into source root
	# dead symlinks are tolerated
	ln -s "${BUILD_DIR}/sphinx/html" html || die
}

python_test() {
	esetup.py test
}

src_install() {
	mydistutilsargs+=(
		install
		--disable-html-docs
		--disable-man-pages
	)

	distutils-r1_src_install
}

python_install_all() {
	local cmds=(
		install_man
	)
	use doc && cmds+=(
		install_docs --path="${ED%/}"/usr/share/doc/${PF}/html
	)

	distutils-r1_python_install "${cmds[@]}"
	distutils-r1_python_install_all
}

pkg_postinst() {
	python_foreach_impl pplugincache
}