[gentoo-commits] gentoo-x86 commit in sys-power/cpufreqd: ChangeLog cpufreqd-2.4.2-r1.ebuild

[Nathan Phillip Brink (binki)]

binki       11/10/30 04:58:02

  Modified:             ChangeLog
  Added:                cpufreqd-2.4.2-r1.ebuild
  Log:
  Add patch from bug #318287 by Sven Eden <yamakuzure@×××.net> fixing glibc abort() for potential buffer overflow on startup when compiled with gcc-4.5 and CFLAGS="-O1" and passed the -f flag. OKed by steev_.
  
  (Portage version: 2.2.0_alpha71-r1/cvs/Linux x86_64)

Revision  Changes    Path
1.64                 sys-power/cpufreqd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufreqd/ChangeLog?rev=1.64&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufreqd/ChangeLog?rev=1.64&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufreqd/ChangeLog?r1=1.63&r2=1.64

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/ChangeLog,v
retrieving revision 1.63
retrieving revision 1.64
diff -u -r1.63 -r1.64
--- ChangeLog	19 Jul 2010 19:18:34 -0000	1.63
+++ ChangeLog	30 Oct 2011 04:58:01 -0000	1.64
@@ -1,6 +1,14 @@
 # ChangeLog for sys-power/cpufreqd
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/ChangeLog,v 1.63 2010/07/19 19:18:34 josejx Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/ChangeLog,v 1.64 2011/10/30 04:58:01 binki Exp $
+
+*cpufreqd-2.4.2-r1 (30 Oct 2011)
+
+  30 Oct 2011; Nathan Phillip Brink <binki@g.o>
+  +cpufreqd-2.4.2-r1.ebuild, +files/cpufreqd-2.4.2-PATH_MAX.patch:
+  Add patch from bug #318287 by Sven Eden <yamakuzure@×××.net> fixing glibc
+  abort() for potential buffer overflow on startup when compiled with gcc-4.5
+  and CFLAGS="-O1" and passed the -f flag. OKed by steev_.
 
   19 Jul 2010; Joseph Jezak <josejx@g.o> cpufreqd-2.4.2.ebuild:
   Marked ppc stable for bug #323195.



1.1                  sys-power/cpufreqd/cpufreqd-2.4.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufreqd/cpufreqd-2.4.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/cpufreqd/cpufreqd-2.4.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: cpufreqd-2.4.2-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/cpufreqd-2.4.2-r1.ebuild,v 1.1 2011/10/30 04:58:01 binki Exp $

EAPI="2"

inherit eutils

NVCLOCK_VERSION="0.8b"

DESCRIPTION="CPU Frequency Daemon"
HOMEPAGE="http://www.linux.it/~malattia/wiki/index.php/Cpufreqd"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
		nvidia? ( http://www.linuxhardware.org/nvclock/nvclock${NVCLOCK_VERSION}.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

IUSE="acpi apm lm_sensors nforce2 nvidia pmu"
RDEPEND=">=sys-power/cpufrequtils-002
		sys-fs/sysfsutils
		lm_sensors? ( >sys-apps/lm_sensors-3 )"
DEPEND="sys-apps/sed
		${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-conf.d.patch
	epatch "${FILESDIR}"/${P}-PATH_MAX.patch #318287

	if use nvidia; then
		cd "${WORKDIR}"/nvclock${NVCLOCK_VERSION}
		epatch "${FILESDIR}"/nvclock${NVCLOCK_VERSION}-fpic.patch
	fi
}

src_configure() {
	local config

	if use nvidia; then
		cd "${WORKDIR}"/nvclock${NVCLOCK_VERSION}
		econf \
			--disable-gtk \
			--disable-qt \
			--disable-nvcontrol \
			|| die "econf nvclock failed"
		emake -j1 || die "emake nvclock failed"
		config="--enable-nvclock=${WORKDIR}/nvclock${NVCLOCK_VERSION}"
	fi

	cd "${S}"
	econf \
		$(use_enable acpi) \
		$(use_enable apm) \
		$(use_enable lm_sensors sensors) \
		$(use_enable nforce2) \
		$(use_enable pmu) \
		${config} \
		|| die "econf failed"
}

src_compile() {
	if use nvidia; then
		cd "${WORKDIR}"/nvclock${NVCLOCK_VERSION}
	fi

	cd "${S}"
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	rm -rf "${D}"/usr/$(get_libdir)/*.la
	dodoc AUTHORS ChangeLog NEWS README TODO
	newinitd "${FILESDIR}"/${PN}-init.d ${PN}
}

pkg_postinst() {
	if [ -f "${ROOT}"/etc/conf.d/cpufreqd ] ; then
		ewarn "An old \"/etc/conf.d/cpufreqd\" file was found. It breaks"
		ewarn "the new init script! Please remove it."
		ewarn "# rm /etc/conf.d/cpufreqd"
	fi
}