[gentoo-commits] gentoo-x86 commit in dev-cpp/eigen: eigen-2.0.5.ebuild ChangeLog

[Marcus Hanwell (cryos)]

cryos       09/08/22 21:51:26

  Modified:             ChangeLog
  Added:                eigen-2.0.5.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc39/cvs/Linux x86_64)

Revision  Changes    Path
1.16                 dev-cpp/eigen/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/eigen/ChangeLog?rev=1.16&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/eigen/ChangeLog?rev=1.16&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/eigen/ChangeLog?r1=1.15&r2=1.16

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v
retrieving revision 1.15
retrieving revision 1.16
diff -u -r1.15 -r1.16
--- ChangeLog	21 Aug 2009 17:35:18 -0000	1.15
+++ ChangeLog	22 Aug 2009 21:51:26 -0000	1.16
@@ -1,6 +1,11 @@
 # ChangeLog for dev-cpp/eigen
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v 1.15 2009/08/21 17:35:18 cryos Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/ChangeLog,v 1.16 2009/08/22 21:51:26 cryos Exp $
+
+*eigen-2.0.5 (22 Aug 2009)
+
+  22 Aug 2009; Marcus D. Hanwell <cryos@g.o> +eigen-2.0.5.ebuild:
+  Version bump.
 
   21 Aug 2009; Marcus D. Hanwell <cryos@g.o>
   files/eigen-2.0.4-qt-test.patch:



1.1                  dev-cpp/eigen/eigen-2.0.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/eigen/eigen-2.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-cpp/eigen/eigen-2.0.5.ebuild?rev=1.1&content-type=text/plain

Index: eigen-2.0.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-cpp/eigen/eigen-2.0.5.ebuild,v 1.1 2009/08/22 21:51:26 cryos Exp $

EAPI="2"

inherit cmake-utils

DESCRIPTION="Lightweight C++ template library for vector and matrix math, a.k.a. linear algebra"
HOMEPAGE="http://eigen.tuxfamily.org/"
SRC_URI="http://bitbucket.org/eigen/eigen2/get/${PV}.tar.bz2"

LICENSE="GPL-3"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
SLOT="2"
IUSE="debug doc examples"

DEPEND="
	examples? (
		x11-libs/qt-gui:4
		x11-libs/qt-opengl:4
	)
"
RDEPEND="${DEPEND}
	!dev-cpp/eigen:0
"

S="${WORKDIR}/eigen2"

src_prepare() {
	# fix compilation agains eigen on the PPC platform:
	epatch "${FILESDIR}/${PN}-ppc-define.patch"
}

src_configure() {
	# benchmarks (BTL) brings up damn load of external deps including fortran
	# compiler
	# library hangs up complete compilation proccess, test later
	mycmakeargs="
		-DEIGEN_BUILD_LIB=OFF
		-DEIGEN_BUILD_BTL=OFF
		$(cmake-utils_use examples EIGEN_BUILD_DEMOS)
	"
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use doc; then
		cd "${CMAKE_BUILD_DIR}"
		emake doc || die "building documentation failed"
	fi
}

src_install() {
	cmake-utils_src_install
	if use doc; then
		cd "${CMAKE_BUILD_DIR}"/doc
		dohtml -r html/* || die "dohtml failed"
	fi
	if use examples; then
		cd "${CMAKE_BUILD_DIR}"/demos
		dobin mandelbrot/mandelbrot opengl/quaternion_demo || die "dobin failed"
	fi
}

src_test() {
	mycmakeargs="${mycmakeargs}
		-DEIGEN_BUILD_TESTS=ON
		-DEIGEN_TEST_NO_FORTRAN=ON"
	cmake-utils_src_configure
	cmake-utils_src_compile
	cmake-utils_src_test
}