[gentoo-commits] gentoo-x86 commit in app-laptop/pommed: ChangeLog pommed-1.31.ebuild

[Cedric Krier (cedk)]

cedk        10/02/28 16:33:11

  Modified:             ChangeLog
  Added:                pommed-1.31.ebuild
  Log:
  Version bump
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.50                 app-laptop/pommed/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/pommed/ChangeLog?rev=1.50&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/pommed/ChangeLog?rev=1.50&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/pommed/ChangeLog?r1=1.49&r2=1.50

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-laptop/pommed/ChangeLog,v
retrieving revision 1.49
retrieving revision 1.50
diff -u -r1.49 -r1.50
--- ChangeLog	7 Jan 2010 16:07:28 -0000	1.49
+++ ChangeLog	28 Feb 2010 16:33:11 -0000	1.50
@@ -1,6 +1,12 @@
 # ChangeLog for app-laptop/pommed
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-laptop/pommed/ChangeLog,v 1.49 2010/01/07 16:07:28 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-laptop/pommed/ChangeLog,v 1.50 2010/02/28 16:33:11 cedk Exp $
+
+*pommed-1.31 (28 Feb 2010)
+
+  28 Feb 2010; Cédric Krier <cedk@g.o> +pommed-1.31.ebuild,
+  +files/pommed-1.31.patch:
+  Version bump
 
   07 Jan 2010; Joseph Jezak <josejx@g.o> pommed-1.30.ebuild:
   Fix for x86/amd64 kernel check not needed on ppc.



1.1                  app-laptop/pommed/pommed-1.31.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/pommed/pommed-1.31.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/pommed/pommed-1.31.ebuild?rev=1.1&content-type=text/plain

Index: pommed-1.31.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-laptop/pommed/pommed-1.31.ebuild,v 1.1 2010/02/28 16:33:11 cedk Exp $

inherit eutils toolchain-funcs linux-info

DESCRIPTION="Manage special features such as screen and keyboard backlight on Apple MacBook Pro/PowerBook"
HOMEPAGE="http://technologeek.org/projects/pommed/index.html"
ALIOTH_NUMBER="3202"
SRC_URI="http://alioth.debian.org/frs/download.php/${ALIOTH_NUMBER}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="gtk X"

COMMON_DEPEND="media-libs/alsa-lib
	x86? ( sys-apps/pciutils )
	amd64? (  sys-apps/pciutils )
	dev-libs/confuse
	>=sys-apps/dbus-1.1
	dev-libs/dbus-glib
	sys-libs/zlib
	media-libs/audiofile
	gtk? ( >=x11-libs/gtk+-2
		>=gnome-base/libglade-2 )
	X? ( x11-libs/libX11
		x11-libs/libXpm )"
DEPEND="${COMMON_DEPEND}
	dev-util/pkgconfig"
RDEPEND="${COMMON_DEPEND}
	media-sound/alsa-utils
	virtual/eject"

pkg_setup() {
	if ! use ppc; then
		linux-info_pkg_setup

		CONFIG_CHECK="DMIID"
		check_extra_config
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}/${P}.patch"
}

src_compile() {
	cd "${S}"/pommed
	emake CC="$(tc-getCC)" OFLIB=1 || die "emake pommed failed"

	if use gtk; then
		cd "${S}"/gpomme
		local POFILES=""
		for LANG in ${LINGUAS}; do
			if [ -f po/${LANG}.po ]; then
				POFILES="${POFILES} po/${LANG}.po"
			fi
		done
		emake CC="$(tc-getCC)" POFILES="${POFILES}" || die "emake gpomme failed"
	fi
	if use X; then
		cd "${S}"/wmpomme
		emake CC="$(tc-getCC)" || die "emake wmpomme failed"
	fi
}

src_install() {
	insinto /etc
	if use x86 || use amd64; then
		newins pommed.conf.mactel pommed.conf
	elif use ppc; then
		newins pommed.conf.pmac pommed.conf
	fi

	insinto /etc/dbus-1/system.d
	newins dbus-policy.conf pommed.conf

	insinto /usr/share/pommed
	doins pommed/data/*.wav

	dobin pommed/pommed

	newinitd "${FILESDIR}"/pommed.rc pommed

	dodoc AUTHORS ChangeLog README TODO

	if use gtk ; then
		dobin gpomme/gpomme
		for LANG in ${LINGUAS}; do
			if [ -f gpomme/po/${LANG}.mo ]; then
				einfo "Installing lang ${LANG}"
				insinto /usr/share/locale/${LANG}/LC_MESSAGES/
				doins gpomme/po/${LANG}.mo
			fi
		done

		insinto /usr/share/applications
		doins gpomme/gpomme.desktop
		doins gpomme/gpomme-c.desktop
		insinto /usr/share/gpomme/
		doins -r gpomme/themes
		doins gpomme/gpomme.glade
	fi

	if use X ; then
		dobin wmpomme/wmpomme
	fi
}