[gentoo-commits] gentoo-x86 commit in app-arch/file-roller: ChangeLog file-roller-2.32.1.ebuild file-roller-2.32.0.ebuild

[Pacho Ramos (pacho)]

pacho       10/11/28 22:55:47

  Modified:             ChangeLog
  Added:                file-roller-2.32.1.ebuild
  Removed:              file-roller-2.32.0.ebuild
  Log:
  Version bump, remove old.
  
  (Portage version: 2.1.9.25/cvs/Linux x86_64)

Revision  Changes    Path
1.286                app-arch/file-roller/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/file-roller/ChangeLog?rev=1.286&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/file-roller/ChangeLog?rev=1.286&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/file-roller/ChangeLog?r1=1.285&r2=1.286

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v
retrieving revision 1.285
retrieving revision 1.286
diff -u -r1.285 -r1.286
--- ChangeLog	20 Nov 2010 12:08:01 -0000	1.285
+++ ChangeLog	28 Nov 2010 22:55:47 -0000	1.286
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/file-roller
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.285 2010/11/20 12:08:01 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/ChangeLog,v 1.286 2010/11/28 22:55:47 pacho Exp $
+
+*file-roller-2.32.1 (28 Nov 2010)
+
+  28 Nov 2010; Pacho Ramos <pacho@g.o> -files/rpm2cpio-file-roller,
+  -file-roller-2.32.0.ebuild, +file-roller-2.32.1.ebuild:
+  Version bump, remove old.
 
   20 Nov 2010; Raúl Porcel <armin76@g.o> file-roller-2.32.0.ebuild:
   Add ~arm, thanks to steev for testing



1.1                  app-arch/file-roller/file-roller-2.32.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/file-roller/file-roller-2.32.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/file-roller/file-roller-2.32.1.ebuild?rev=1.1&content-type=text/plain

Index: file-roller-2.32.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/file-roller/file-roller-2.32.1.ebuild,v 1.1 2010/11/28 22:55:47 pacho Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit eutils gnome2

DESCRIPTION="Archive manager for GNOME"
HOMEPAGE="http://fileroller.sourceforge.net/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
IUSE="nautilus"

RDEPEND=">=dev-libs/glib-2.25.5
	>=x11-libs/gtk+-2.21.4:2
	>=gnome-base/gconf-2.6
	nautilus? ( >=gnome-base/nautilus-2.22.2 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	dev-util/pkgconfig
	app-text/gnome-doc-utils"
# eautoreconf needs:
#	gnome-base/gnome-common

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-dependency-tracking
		--disable-scrollkeeper
		--disable-run-in-place
		--disable-static
		--disable-packagekit
		--disable-deprecations
		--with-gtk=2.0
		$(use_enable nautilus nautilus-actions)"
	DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"
}

src_prepare() {
	gnome2_src_prepare

	# Use absolute path to GNU tar since star doesn't have the same
	# options. On Gentoo, star is /usr/bin/tar, GNU tar is /bin/tar
	epatch "${FILESDIR}"/${PN}-2.10.3-use_bin_tar.patch
}

src_install() {
	gnome2_src_install
	if use nautilus; then
		find "${ED}"usr/$(get_libdir)/nautilus -name "*.la" -delete \
			|| die "la file removal failed"
	fi
}

pkg_postinst() {
	gnome2_pkg_postinst

	elog "${PN} is a frontend for several archiving utilities. If you want a"
	elog "particular achive format support, see ${HOMEPAGE}"
	elog "and install the relevant package."
	elog
	elog "for example:"
	elog "  7-zip   - app-arch/p7zip"
	elog "  ace     - app-arch/unace"
	elog "  arj     - app-arch/arj"
	elog "  cpio    - app-arch/cpio"
	elog "  deb     - app-arch/dpkg"
	elog "  iso     - app-cdr/cdrtools"
	elog "  jar,zip - app-arch/zip and app-arch/unzip"
	elog "  lha     - app-arch/lha"
	elog "  lzma    - app-arch/xz-utils"
	elog "  lzop    - app-arch/lzop"
	elog "  rar     - app-arch/unrar"
	elog "  rpm     - app-arch/rpm"
	elog "  unstuff - app-arch/stuffit"
	elog "  zoo     - app-arch/zoo"
}