Gentoo Archives: gentoo-commits

From: "Mike Gilbert (floppym)" <floppym@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in www-client/google-chrome-unstable: google-chrome-unstable-36.0.1964.2_p1.ebuild ChangeLog google-chrome-unstable-36.0.1951.5_p1.ebuild
Date: Wed, 30 Apr 2014 22:57:52
Message-Id: 20140430225747.07D0E2004B@flycatcher.gentoo.org
floppym     14/04/30 22:57:46

  Modified:             ChangeLog
  Added:                google-chrome-unstable-36.0.1964.2_p1.ebuild
  Removed:              google-chrome-unstable-36.0.1951.5_p1.ebuild
  Log:
  Automated update.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.25                 www-client/google-chrome-unstable/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-unstable/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-unstable/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-unstable/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/google-chrome-unstable/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	24 Apr 2014 23:54:48 -0000	1.24
+++ ChangeLog	30 Apr 2014 22:57:46 -0000	1.25
@@ -1,6 +1,13 @@
 # ChangeLog for www-client/google-chrome-unstable
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome-unstable/ChangeLog,v 1.24 2014/04/24 23:54:48 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome-unstable/ChangeLog,v 1.25 2014/04/30 22:57:46 floppym Exp $
+
+*google-chrome-unstable-36.0.1964.2_p1 (30 Apr 2014)
+
+  30 Apr 2014; Mike Gilbert <floppym@g.o>
+  +google-chrome-unstable-36.0.1964.2_p1.ebuild,
+  -google-chrome-unstable-36.0.1951.5_p1.ebuild:
+  Automated update.
 
 *google-chrome-unstable-36.0.1951.5_p1 (24 Apr 2014)
 



1.1                  www-client/google-chrome-unstable/google-chrome-unstable-36.0.1964.2_p1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-unstable/google-chrome-unstable-36.0.1964.2_p1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/google-chrome-unstable/google-chrome-unstable-36.0.1964.2_p1.ebuild?rev=1.1&content-type=text/plain

Index: google-chrome-unstable-36.0.1964.2_p1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/google-chrome-unstable/google-chrome-unstable-36.0.1964.2_p1.ebuild,v 1.1 2014/04/30 22:57:46 floppym Exp $

EAPI="5"

CHROMIUM_LANGS="am ar bg bn ca cs da de el en_GB es es_LA et fa fi fil fr gu he
	hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt_BR pt_PT ro ru sk sl sr
	sv sw ta te th tr uk vi zh_CN zh_TW"

inherit readme.gentoo chromium eutils multilib pax-utils unpacker

DESCRIPTION="The web browser from Google"
HOMEPAGE="http://www.google.com/chrome"

if [[ ${PN} == google-chrome ]]; then
	MY_PN=${PN}-stable
else
	MY_PN=${PN}
fi

MY_P="${MY_PN}_${PV/_p/-}"

SRC_URI="
	amd64? (
		http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_amd64.deb
	)
	x86? (
		http://dl.google.com/linux/chrome/deb/pool/main/g/${MY_PN}/${MY_P}_i386.deb
	)
"

LICENSE="google-chrome"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="+plugins"
RESTRICT="bindist mirror strip"

RDEPEND="
	app-arch/bzip2
	app-misc/ca-certificates
	dev-libs/atk
	dev-libs/expat
	dev-libs/glib:2
	|| ( dev-libs/libgcrypt:11 dev-libs/libgcrypt:0/11 )
	dev-libs/nspr
	dev-libs/nss
	gnome-base/gconf:2
	media-libs/alsa-lib
	media-libs/fontconfig
	media-libs/freetype
	net-print/cups
	sys-apps/dbus
	>=sys-devel/gcc-4.4.0[cxx]
	sys-libs/libcap
	x11-libs/cairo
	x11-libs/gdk-pixbuf
	x11-libs/gtk+:2
	>=x11-libs/libX11-1.5.0
	x11-libs/libXcomposite
	x11-libs/libXdamage
	x11-libs/libXext
	x11-libs/libXfixes
	x11-libs/libXi
	x11-libs/libXrandr
	x11-libs/libXrender
	x11-libs/libXScrnSaver
	x11-libs/libXtst
	x11-libs/pango
	x11-misc/xdg-utils
"

QA_PREBUILT="*"
S=${WORKDIR}
CHROME_HOME="opt/google/chrome${PN#google-chrome}"

DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="
Some web pages may require additional fonts to display properly.
Try installing some of the following packages if some characters
are not displayed properly:
- media-fonts/arphicfonts
- media-fonts/bitstream-cyberbit
- media-fonts/droid
- media-fonts/ipamonafont
- media-fonts/ja-ipafonts
- media-fonts/takao-fonts
- media-fonts/wqy-microhei
- media-fonts/wqy-zenhei

Depending on your desktop environment, you may need
to install additional packages to get icons on the Downloads page.

For KDE, the required package is kde-base/oxygen-icons.

For other desktop environments, try one of the following:
- x11-themes/gnome-icon-theme
- x11-themes/tango-icon-theme

Please notice the bundled flash player (PepperFlash).
You can (de)activate all flash plugins via chrome://plugins
"

pkg_nofetch() {
	eerror "Please wait 24 hours before reporting a bug for google-chrome fetch failures."
}

pkg_setup() {
	chromium_suid_sandbox_check_kernel_config
}

src_install() {
	rm -r usr/share/menu || die
	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die

	pushd "${CHROME_HOME}/locales" > /dev/null || die
	chromium_remove_language_paks
	popd > /dev/null || die

	if use plugins ; then
		local plugins="--extra-plugin-dir=/usr/$(get_libdir)/nsbrowser/plugins"
		sed -e "/^exec/ i set -- \"${plugins}\" \"\$@\"" \
			-i "${CHROME_HOME}/${PN}" || die
	fi

	local size
	for size in 16 22 24 32 48 64 128 256 ; do
		newicon -s ${size} "${CHROME_HOME}/product_logo_${size}.png" ${PN}.png
	done

	insinto /
	doins -r opt usr

	chmod 755 "${ED}${CHROME_HOME}"/{chrome,${PN},nacl_helper{,_bootstrap},xdg-{mime,settings}} || die
	chmod 4755 "${ED}${CHROME_HOME}/chrome-sandbox" || die
	pax-mark m "${ED}${CHROME_HOME}/chrome"

	readme.gentoo_create_doc
}

any_cpu_missing_flag() {
	local value=$1
	grep '^flags' /proc/cpuinfo | grep -qv "$value"
}

pkg_preinst() {
	chromium_pkg_preinst
	if any_cpu_missing_flag sse2; then
		ewarn "The bundled PepperFlash plugin requires a CPU that supports the"
		ewarn "SSE2 instruction set, and at least one of your CPUs does not"
		ewarn "support this feature. Disabling PepperFlash."
		sed -e "/^exec/ i set -- --disable-bundled-ppapi-flash \"\$@\"" \
			-i "${ED}${CHROME_HOME}/google-chrome" || die
	fi
}

pkg_postinst() {
	local lib libdir target
	for libdir in {,usr/}$(get_libdir); do
		lib=${EROOT}${libdir}/libudev.so.1
		if [[ -e ${lib} ]]; then
			target=$(realpath -ms --relative-to="${EROOT}${CHROME_HOME}" "${lib}")
			ln -fs "${target}" "${EROOT}${CHROME_HOME}/libudev.so.0"
			break
		fi
	done

	fdo-mime_desktop_database_update
	gnome2_icon_cache_update
	readme.gentoo_print_elog
}

pkg_prerm() {
	rm -f "${EROOT}${CHROME_HOME}/libudev.so.0"
}