[gentoo-commits] repo/gentoo:master commit in: sys-apps/cpu-x/

[Ben Kohler]

commit:     7ec8be12b8b0b0a122b3abdd4986cbf315adfde8
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Mon Aug 29 13:00:37 2022 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Mon Aug 29 13:00:50 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ec8be12

sys-apps/cpu-x: add 4.4.0

Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 sys-apps/cpu-x/Manifest           |  1 +
 sys-apps/cpu-x/cpu-x-4.4.0.ebuild | 78 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/sys-apps/cpu-x/Manifest b/sys-apps/cpu-x/Manifest
index 68c0a54eff09..7e3ad9c5e255 100644
--- a/sys-apps/cpu-x/Manifest
+++ b/sys-apps/cpu-x/Manifest
@@ -1 +1,2 @@
 DIST cpu-x-4.3.1.tar.gz 1846968 BLAKE2B bcf13a302ad108f76d3c170993385178e7b44123af6b6f3192960f69d8ee493719a408ef4e95ee82e4cbf3f151fe4dcb91a9fc9d4e53c1170c95a9ed2ad3417b SHA512 43e7bc4b82a15545e4c2f69f598a94706ef2c5f5594ff50763f71722d1b98e6dd56e907a4f35917500debf11522c5908dbebf51f515fe5a51af7282254210bc1
+DIST cpu-x-4.4.0.tar.gz 1873126 BLAKE2B f914152098effbebe6cae5cd6a2f9ae408b996c4dba7675f1eb991de107bfe7259d8615e647829155963fe93ea585b37486081450ac41e93939bf909f145e20c SHA512 57c960f6c3007455f4d36ccc6d500b18195b305b3d3bdbbdc4b6804f9c1219460c31f854f38d18a49b1c4c0b870970cfcfe6abae4e5c0cdc83e452c5614c13fb

diff --git a/sys-apps/cpu-x/cpu-x-4.4.0.ebuild b/sys-apps/cpu-x/cpu-x-4.4.0.ebuild
new file mode 100644
index 000000000000..e1f02ebb7d26
--- /dev/null
+++ b/sys-apps/cpu-x/cpu-x-4.4.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="CPU-X"
+
+inherit cmake gnome2-utils xdg
+
+DESCRIPTION="A Free software that gathers information on CPU, motherboard and more"
+HOMEPAGE="https://x0rg.github.io/CPU-X/"
+SRC_URI="https://github.com/X0rg/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+cpu force-libstatgrab +gpu +gui +ncurses +nls opencl +pci test"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	force-libstatgrab? ( sys-libs/libstatgrab )
+	!force-libstatgrab? ( sys-process/procps:= )
+	gui? ( >=x11-libs/gtk+-3.12:3 )
+	cpu? ( >=dev-libs/libcpuid-0.3.0:= )
+	gpu? ( >=media-libs/glfw-3.3
+		media-libs/libglvnd )
+	pci? ( sys-apps/pciutils )
+	ncurses? ( sys-libs/ncurses:=[tinfo] )
+	opencl? ( virtual/opencl )
+"
+
+DEPEND="
+	test? (
+		sys-apps/mawk
+		sys-apps/nawk
+	)
+
+	${COMMON_DEPEND}
+"
+
+BDEPEND="
+	dev-lang/nasm
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="${COMMON_DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFORCE_LIBSTATGRAB=$(usex force-libstatgrab)
+		-DGSETTINGS_COMPILE=OFF
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_GTK=$(usex gui)
+		-DWITH_LIBCPUID=$(usex cpu)
+		-DWITH_LIBGLFW=$(usex gpu)
+		-DWITH_LIBPCI=$(usex pci)
+		-DWITH_LIBSTATGRAB=OFF
+		-DWITH_NCURSES=$(usex ncurses)
+		-DWITH_OPENCL=$(usex opencl)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}