[gentoo-commits] gentoo-x86 commit in www-client/dillo: ChangeLog dillo-2.2.1.ebuild

[Patrick Lauer (patrick)]

patrick     11/08/01 15:38:09

  Modified:             ChangeLog
  Added:                dillo-2.2.1.ebuild
  Log:
  Bump for #376559
  
  (Portage version: 2.2.0_alpha49/cvs/Linux x86_64)

Revision  Changes    Path
1.94                 www-client/dillo/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/ChangeLog?rev=1.94&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/ChangeLog?rev=1.94&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/ChangeLog?r1=1.93&r2=1.94

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/dillo/ChangeLog,v
retrieving revision 1.93
retrieving revision 1.94
diff -u -r1.93 -r1.94
--- ChangeLog	8 Nov 2010 12:38:58 -0000	1.93
+++ ChangeLog	1 Aug 2011 15:38:08 -0000	1.94
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/dillo
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/ChangeLog,v 1.93 2010/11/08 12:38:58 nelchael Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/ChangeLog,v 1.94 2011/08/01 15:38:08 patrick Exp $
+
+*dillo-2.2.1 (01 Aug 2011)
+
+  01 Aug 2011; Patrick Lauer <patrick@g.o> +dillo-2.2.1.ebuild:
+  Bump for #376559
 
   08 Nov 2010; Krzysztof Pawlik <nelchael@g.o> dillo-2.2.ebuild,
   dillo-9999.ebuild:



1.1                  www-client/dillo/dillo-2.2.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/dillo-2.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/dillo/dillo-2.2.1.ebuild?rev=1.1&content-type=text/plain

Index: dillo-2.2.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/dillo/dillo-2.2.1.ebuild,v 1.1 2011/08/01 15:38:08 patrick Exp $

EAPI="2"
inherit eutils flag-o-matic multilib

DESCRIPTION="Lean FLTK2-based web browser"
HOMEPAGE="http://www.dillo.org/"
SRC_URI="http://www.dillo.org/download/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc +gif ipv6 +jpeg +png ssl"

RDEPEND="x11-libs/fltk:2[-cairo,jpeg=,png=]
	sys-libs/zlib
	jpeg? ( virtual/jpeg )
	png? ( media-libs/libpng )
	ssl? ( dev-libs/openssl )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

src_prepare() {
	epatch "${FILESDIR}"/dillo2-inbuf.patch
}

src_configure() {
	append-ldflags "-L/usr/$(get_libdir)/fltk"
	econf  \
		$(use_enable gif) \
		$(use_enable ipv6) \
		$(use_enable jpeg) \
		$(use_enable png) \
		$(use_enable ssl)
}

src_compile() {
	emake || die "make failed"
	if use doc ; then
		doxygen Doxyfile || die "doxygen failed"
	fi
}

src_install() {
	dodir /etc
	emake DESTDIR="${D}" install || die "install failed"

	if use doc; then
		dohtml html/* || die "install documentation failed"
	fi
	dodoc AUTHORS ChangeLog README NEWS
	docinto doc
	dodoc doc/*.txt doc/README

	doicon "${FILESDIR}"/dillo.png
	make_desktop_entry dillo Dillo dillo
}

pkg_postinst() {
	elog "Dillo has installed a default configuration into /etc/dillo/dillorc"
	elog "You can copy this to ~/.dillo/ and customize it"
}