[gentoo-commits] gentoo-x86 commit in rox-base/rox: rox-2.10-r1.ebuild ChangeLog

[Brian Evans (grknight)]

grknight    14/05/30 02:22:15

  Modified:             ChangeLog
  Added:                rox-2.10-r1.ebuild
  Log:
  Non-maintainer commit. Revbump to fix bug #464246. Move to autotools-utils, EAPI=5 and fix underlinking
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

Revision  Changes    Path
1.83                 rox-base/rox/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/rox-base/rox/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/rox-base/rox/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/rox-base/rox/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/rox-base/rox/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	2 Mar 2013 07:52:47 -0000	1.82
+++ ChangeLog	30 May 2014 02:22:15 -0000	1.83
@@ -1,6 +1,12 @@
 # ChangeLog for rox-base/rox
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/rox-base/rox/ChangeLog,v 1.82 2013/03/02 07:52:47 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/rox-base/rox/ChangeLog,v 1.83 2014/05/30 02:22:15 grknight Exp $
+
+*rox-2.10-r1 (30 May 2014)
+
+  30 May 2014; Brian Evans <grknight@g.o> +rox-2.10-r1.ebuild:
+  Non-maintainer commit. Revbump to fix bug #464246. Move to autotools-utils,
+  EAPI=5 and fix underlinking
 
   02 Mar 2013; Pacho Ramos <pacho@g.o> -rox-2.9.ebuild, metadata.xml:
   Cleanup due http://gentoo.2317880.n4.nabble.com/rox-herd-looks-inactive-for-a



1.1                  rox-base/rox/rox-2.10-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/rox-base/rox/rox-2.10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/rox-base/rox/rox-2.10-r1.ebuild?rev=1.1&content-type=text/plain

Index: rox-2.10-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/rox-base/rox/rox-2.10-r1.ebuild,v 1.1 2014/05/30 02:22:15 grknight Exp $

EAPI=5
inherit eutils multilib autotools-utils

MY_P="rox-filer-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="ROX is a desktop environment and filer based on RISC OS"
HOMEPAGE="http://rox.sourceforge.net/"
SRC_URI="mirror://sourceforge/rox/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="+svg +video"

RDEPEND="x11-libs/gtk+:2
	dev-libs/glib:2
	dev-libs/libxml2:2
	>=x11-misc/shared-mime-info-0.14
	svg? ( gnome-base/librsvg:2 )
	>=rox-base/zeroinstall-injector-0.40
	"

PDEPEND="rox-base/mime-editor
		rox-base/thumbs
		video? ( rox-extra/videothumbnail )"

DEPEND="${RDEPEND}
	virtual/pkgconfig"

APPNAME="ROX-Filer"
APPDIR="/usr/$(get_libdir)/rox"
LIBDIR="/usr/$(get_libdir)/"
WRAPPERNAME="rox"
MIMEDIR="/usr/share/mime"
MIMECONFDIR="/etc/xdg/rox.sourceforge.net"

PATCHES=( "${FILESDIR}"/${P}-nostrip.patch )
ECONF_SOURCE="${S}/${APPNAME}/src"
AUTOTOOLS_AUTORECONF="yes"

src_prepare() {
	pushd "${ECONF_SOURCE}" || die
	sed -r -i "s:(AC_CHECK_LIB\(intl, gettext\)):\1\n\nAC_SEARCH_LIBS([floor],[m])\nAC_SEARCH_LIBS([dlsym],[dl]):" "configure.in" || die
	autotools-utils_src_prepare
	popd
}

# new streamlined install

src_install() {
	doman rox.1

	dodir ${APPDIR}
	cp -r ${APPNAME}/ "${D}/${APPDIR}" || die

	# add documentation to be proper
	pushd ${APPNAME}/Help
	dodoc Changes README README-es TODO
	popd

	# install shell script
	dodir /usr/bin

	cat >"${D}/usr/bin/${WRAPPERNAME}" <<EOF
#!/bin/sh
if [ "\${LIBDIRPATH}" ]; then
	export LIBDIRPATH="\${LIBDIRPATH}:${LIBDIR}"
else
	export LIBDIRPATH="${LIBDIR}"
fi

if [ "\${APPDIRPATH}" ]; then
	export APPDIRPATH="\${APPDIRPATH}:${APPDIR}"
else
	export APPDIRPATH="${APPDIR}"
fi
exec "${APPDIR}/${APPNAME}/AppRun" "\$@"
EOF

	cat >"${D}/usr/bin/${WRAPPERNAME}uri" <<EOF
#!/bin/sh
exec "${APPDIR}/${APPNAME}/AppRun" -U "\$@"
EOF

	fperms 0755 "/usr/bin/${WRAPPERNAME}"
	fperms 0755 "/usr/bin/${WRAPPERNAME}uri"

	# Do not install rox.xml - It wrecks any app with a SVG-format .DirIcon
	#insinto ${MIMEDIR}/packages
	#doins rox.xml

	# CHOICES system is gone. Now use XDG only
	# these are shell scripts and must be +x.
	exeinto ${MIMECONFDIR}/MIME-types
	doexe Choices/MIME-types/*

	insinto /usr/share/pixmaps
	newins ${APPNAME}/.DirIcon ${APPNAME}.png

	make_desktop_entry ${WRAPPERNAME} ${APPNAME} ${APPNAME} "System;FileTools;FileManager"

	# Install the 0install feed
	local NATIVE_FEED_DIR="/usr/share/0install.net/native_feeds"
	local ICON_CACHE_DIR="/var/cache/0install.net/interface_icons"

	0distutils ${APPNAME}.xml > tmp.native_feed || die "0distutils feed edit	failed"
	insinto "${APPDIR}/${APPNAME}"
	newins tmp.native_feed ${APPNAME}.xml

	local feedname
	feedname=$(0distutils -e tmp.native_feed) || die "0distutils URI escape	failed"
	dosym "${APPDIR}/${APPNAME}/${APPNAME}.xml" "${NATIVE_FEED_DIR}/${feedname}"

	local cachedname
	cachedname=$(0distutils -c tmp.native_feed) || die "0distutils URI escape	failed"
	dosym "${APPDIR}/${APPNAME}/.DirIcon" "${ICON_CACHE_DIR}/${cachedname}"
}

pkg_postinst() {
	# Do not install rox.xml - It wrecks any app with a SVG-format .DirIcon
	#update-mime-database ${MIMEDIR}

	einfo "${APPNAME} has been installed in ${APPDIR}."
	einfo "To run, you may type ${WRAPPERNAME} at a prompt (within a WM) or"
	einfo "add it to an .xinit or other script during WM startup."
}