[gentoo-commits] repo/gentoo:master commit in: dev-python/pydl/

[Sebastien Fabbro]

commit:     1eba31fad08aa75170ac7093235037076a0870e5
Author:     Sébastien Fabbro <bicatali <AT> gentoo <DOT> org>
AuthorDate: Tue Sep  6 19:29:41 2016 +0000
Commit:     Sebastien Fabbro <bicatali <AT> gentoo <DOT> org>
CommitDate: Tue Sep  6 21:31:19 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1eba31fa

dev-python/pydl: initial import

Package-Manager: portage-2.3.0

 dev-python/pydl/Manifest          |  1 +
 dev-python/pydl/metadata.xml      | 18 ++++++++++++++
 dev-python/pydl/pydl-0.5.2.ebuild | 52 +++++++++++++++++++++++++++++++++++++++
 3 files changed, 71 insertions(+)

diff --git a/dev-python/pydl/Manifest b/dev-python/pydl/Manifest
new file mode 100644
index 00000000..237e241
--- /dev/null
+++ b/dev-python/pydl/Manifest
@@ -0,0 +1 @@
+DIST pydl-0.5.2.tar.gz 687455 SHA256 d6a7442b67785e4f239d1fe8a2be490b5db4b536d4365572adbb6222fddb4dcd SHA512 17608441b5a78dda2155646757e6c573030d2d2dd5bb643852cede14aca64c5a8efd66007fe63f084bdb7ef8d131df51b2f28d7e87a673cb100983f89a0899e7 WHIRLPOOL 6310c8cca95e054e70e0619e3f0150997f15efca85c788c177ce47bc1a3cd14297d7279bef338e8e5e5087530fc120158061df54ff3ccce635c1c05ae54f48f4

diff --git a/dev-python/pydl/metadata.xml b/dev-python/pydl/metadata.xml
new file mode 100644
index 00000000..9c578b9
--- /dev/null
+++ b/dev-python/pydl/metadata.xml
@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-astronomy@g.o</email>
+    <name>Gentoo Astronomy Project</name>
+  </maintainer>
+  <longdescription lang="en">
+   PyDL consists of Python replacements for functions that are part of the IDL
+   built-in library or part of astronomical IDL libraries.
+   The emphasis is on reproducing results of the astronomical library
+   functions.
+   Only the bare minimum of IDL built-in functions are implemented to support this.   
+  </longdescription>
+  <upstream>
+    <remote-id type="pypi">pydl</remote-id>
+  </upstream>
+</pkgmetadata>

diff --git a/dev-python/pydl/pydl-0.5.2.ebuild b/dev-python/pydl/pydl-0.5.2.ebuild
new file mode 100644
index 00000000..177bd96
--- /dev/null
+++ b/dev-python/pydl/pydl-0.5.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1 virtualx xdg-utils
+
+DESCRIPTION="Library of IDL astronomy routines converted to Python"
+HOMEPAGE="https://pypi.python.org/pypi/pydl/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_sphinx --no-intersphinx
+	fi
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}