[gentoo-commits] gentoo-x86 commit in dev-libs/dbus-glib: ChangeLog dbus-glib-0.98.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/10/03 11:58:38

  Modified:             ChangeLog
  Added:                dbus-glib-0.98.ebuild
  Log:
  Version bump wrt #385435 by Rafał Mużyło
  
  (Portage version: 2.2.0_alpha60/cvs/Linux x86_64)

Revision  Changes    Path
1.89                 dev-libs/dbus-glib/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/ChangeLog?rev=1.89&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/ChangeLog?rev=1.89&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/ChangeLog?r1=1.88&r2=1.89

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/ChangeLog,v
retrieving revision 1.88
retrieving revision 1.89
diff -u -r1.88 -r1.89
--- ChangeLog	29 Sep 2011 10:32:59 -0000	1.88
+++ ChangeLog	3 Oct 2011 11:58:37 -0000	1.89
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/dbus-glib
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/ChangeLog,v 1.88 2011/09/29 10:32:59 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/ChangeLog,v 1.89 2011/10/03 11:58:37 ssuominen Exp $
+
+*dbus-glib-0.98 (03 Oct 2011)
+
+  03 Oct 2011; Samuli Suominen <ssuominen@g.o> +dbus-glib-0.98.ebuild:
+  Version bump wrt #385435 by Rafał Mużyło
 
   05 Aug 2011; Samuli Suominen <ssuominen@g.o> -dbus-glib-0.94.ebuild:
   remove old



1.1                  dev-libs/dbus-glib/dbus-glib-0.98.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.98.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.98.ebuild?rev=1.1&content-type=text/plain

Index: dbus-glib-0.98.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.98.ebuild,v 1.1 2011/10/03 11:58:37 ssuominen Exp $

EAPI=4
inherit bash-completion-r1

DESCRIPTION="D-Bus bindings for glib"
HOMEPAGE="http://dbus.freedesktop.org/"
SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"

LICENSE="|| ( GPL-2 AFL-2.1 )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="debug doc static-libs test"

RDEPEND=">=sys-apps/dbus-1.4.1
	>=dev-libs/glib-2.26
	>=dev-libs/expat-1.95.8"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( >=dev-util/gtk-doc-1.4 )"

# out of sources build directory
BD=${WORKDIR}/${P}-build
# out of sources build dir for make check
TBD=${WORKDIR}/${P}-tests-build

src_configure() {
	local my_conf

	my_conf="--localstatedir=/var
		--enable-bash-completion
		$(use_enable debug verbose-mode)
		$(use_enable debug asserts)
		$(use_enable static-libs static)
		$(use_enable doc gtk-doc)
		--with-html-dir=/usr/share/doc/${PF}/html"

	mkdir "${BD}"
	cd "${BD}"
	einfo "Running configure in ${BD}"
	ECONF_SOURCE="${S}" econf ${my_conf}

	if use test; then
		mkdir "${TBD}"
		cd "${TBD}"
		einfo "Running configure in ${TBD}"
		ECONF_SOURCE="${S}" econf \
			${my_conf} \
			$(use_enable test checks) \
			$(use_enable test tests) \
			$(use_enable test asserts) \
			$(use_with test test-socket-dir "${T}"/dbus-test-socket)
	fi
}

src_compile() {
	cd "${BD}"
	einfo "Running make in ${BD}"
	emake

	if use test; then
		cd "${TBD}"
		einfo "Running make in ${TBD}"
		emake
	fi
}

src_test() {
	cd "${TBD}"
	emake check
}

src_install() {
	# NEWS file is obsolete
	dodoc AUTHORS ChangeLog HACKING README

	cd "${BD}"
	emake DESTDIR="${D}" install

	# FIXME: We need --with-bash-completion-dir
	newbashcomp "${D}"/etc/bash_completion.d/dbus-bash-completion.sh dbus
	rm -rf "${D}"/etc/bash_completion.d || die

	find "${D}" -name '*.la' -exec rm -f {} +
}