[gentoo-commits] repo/gentoo:master commit in: app-emacs/pdf-tools/

[Maciej Barć]

commit:     66f4d61002e78b55973aa85cb79b60c1b6cc0dcf
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 30 00:27:46 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Wed Nov 30 01:04:23 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=66f4d610

app-emacs/pdf-tools: bump to 1.0.0

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/pdf-tools/Manifest               |  1 +
 app-emacs/pdf-tools/pdf-tools-1.0.0.ebuild | 64 ++++++++++++++++++++++++++++++
 2 files changed, 65 insertions(+)

diff --git a/app-emacs/pdf-tools/Manifest b/app-emacs/pdf-tools/Manifest
index 9209c7b44bff..298c61e0ea48 100644
--- a/app-emacs/pdf-tools/Manifest
+++ b/app-emacs/pdf-tools/Manifest
@@ -1 +1,2 @@
+DIST pdf-tools-1.0.0.tar.gz 459584 BLAKE2B 54e6f48e593552135c9264baa8040aed6a543e361f5ee951f925ef72d8c62db9e15f97de52eaa4b6013a17dce6170f73e16f1e9d25c9cde33ac8eba1f71ebb7a SHA512 dcf44a45865061c191dcfc03504c707f2170224167d3ec493465c789d8c1433f17c706c5f15dac4fab65e3da45ca3c194aad9b7c599209a7a10b72c17dbbeb77
 DIST pdf-tools-1.0.0_pre20220619.tar.gz 459416 BLAKE2B 79a7c7a59faf9c11047bfb6218a8055cb9c757b928e52ff59ffb910e5aedb95ca7efe1dda1ae821d98a687fc6e700d8194311fc850f534f425534a1572bd34b5 SHA512 74ca8c05ad238c07ca1b6d6a594889d048220bb984b78b83e7af4c59eedfa7a35a03e153aa4d1296781f910eb0b3a68a5148876a30ad0f6e9fdecf831ff58f8e

diff --git a/app-emacs/pdf-tools/pdf-tools-1.0.0.ebuild b/app-emacs/pdf-tools/pdf-tools-1.0.0.ebuild
new file mode 100644
index 000000000000..e2a64f5d79f4
--- /dev/null
+++ b/app-emacs/pdf-tools/pdf-tools-1.0.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=26.3
+
+inherit autotools elisp
+
+DESCRIPTION="Emacs Lisp support library for PDF documents"
+HOMEPAGE="https://github.com/vedang/pdf-tools/"
+SRC_URI="https://github.com/vedang/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+
+# Cask is a hard dependency for tests; it is ran by helper functions too.
+RESTRICT="test"
+
+BDEPEND="app-emacs/tablist"
+DEPEND="
+	app-text/poppler:=[cairo,png]
+	dev-libs/glib:2=
+	media-libs/freetype:2=
+	media-libs/harfbuzz:=
+	media-libs/libpng:=
+	x11-libs/cairo:=
+"
+RDEPEND="
+	${DEPEND}
+	${BDEPEND}
+"
+
+DOCS=( NEWS README.org )
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	cd server || die
+	eautoreconf
+}
+
+src_configure() {
+	cd server || die
+	econf
+}
+
+src_compile() {
+	BYTECOMPFLAGS="-L lisp" elisp-compile lisp/*.el
+	elisp-make-autoload-file lisp/${PN}-autoloads.el lisp
+
+	emake -C server
+}
+
+src_install() {
+	elisp-install ${PN} lisp/*.el*
+	elisp-site-file-install "${FILESDIR}"/${SITEFILE}
+
+	emake -C server DESTDIR="${D}" install
+
+	einstalldocs
+}