[gentoo-commits] gentoo-x86 commit in gnome-extra/deskbar-applet: ChangeLog deskbar-applet-2.26.2-r1.ebuild

[Olivier Crete (tester)]

tester      09/10/08 03:33:31

  Modified:             ChangeLog
  Added:                deskbar-applet-2.26.2-r1.ebuild
  Log:
  Add patch for crash on opening preferences dialog
  (Portage version: 2.1.6.13/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.123                gnome-extra/deskbar-applet/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	8 Oct 2009 03:27:01 -0000	1.122
+++ ChangeLog	8 Oct 2009 03:33:30 -0000	1.123
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/deskbar-applet
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog,v 1.122 2009/10/08 03:27:01 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/ChangeLog,v 1.123 2009/10/08 03:33:30 tester Exp $
+
+*deskbar-applet-2.26.2-r1 (08 Oct 2009)
+
+  08 Oct 2009; Olivier Crête <tester@g.o>
+  +deskbar-applet-2.26.2-r1.ebuild,
+  +files/deskbar-applet-2.26.2-double-label.patch:
+  Add patch for crash on opening preferences dialog
 
   08 Oct 2009; Olivier Crête <tester@g.o>
   deskbar-applet-2.26.2.ebuild:



1.1                  gnome-extra/deskbar-applet/deskbar-applet-2.26.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/deskbar-applet/deskbar-applet-2.26.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-extra/deskbar-applet/deskbar-applet-2.26.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: deskbar-applet-2.26.2-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/deskbar-applet/deskbar-applet-2.26.2-r1.ebuild,v 1.1 2009/10/08 03:33:30 tester Exp $

GCONF_DEBUG="no"

inherit eutils gnome2 python

DESCRIPTION="An Omnipresent Versatile Search Interface"
HOMEPAGE="http://raphael.slinckx.net/deskbar/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="eds spell test"

RDEPEND=">=dev-lang/python-2.4
	>=x11-libs/gtk+-2.12
	>=gnome-base/gnome-desktop-2.10
	>=gnome-base/gconf-2

	>=dev-python/pygtk-2.12
	>=dev-python/pygobject-2.15.3
	>=dev-python/dbus-python-0.80.2

	>=dev-python/gconf-python-2.22.1
	>=dev-python/libgnome-python-2.22.1
	>=dev-python/gnome-applets-python-2.22.0
	>=dev-python/gnome-desktop-python-2.22.0
	>=dev-python/gnome-keyring-python-2.22.0
	>=dev-python/libwnck-python-2.22.0

	eds? ( >=gnome-extra/evolution-data-server-1.7.92 )
	spell? ( >=gnome-extra/gnome-utils-2.16.2 )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/intltool-0.35
	app-text/scrollkeeper
	app-text/gnome-doc-utils
	dev-util/pkgconfig
	test? ( ~app-text/docbook-xml-dtd-4.2 )"

DOCS="AUTHORS ChangeLog NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable eds evolution)
		--exec-prefix=/usr
		--disable-scrollkeeper"
}

src_unpack() {
	gnome2_src_unpack

	epatch ${FILESDIR}/deskbar-applet-2.26.2-double-label.patch

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die "sed failed"

	# disable pyc compiling
	mv py-compile py-compile.orig
	ln -s $(type -P true) py-compile
}

src_compile() {
	# Needed for import gnomedesktop in configure, bug #270524
	addpredict "$(unset HOME; echo ~)/.gnome2"

	gnome2_src_compile
}

pkg_postinst() {
	gnome2_pkg_postinst
	python_need_rebuild
	python_mod_optimize $(python_get_sitedir)/deskbar
	python_mod_optimize /usr/$(get_libdir)/deskbar-applet/modules-2.20-compatible

	ebeep 5
	ewarn "The dictionary plugin in deskbar-applet uses the dictionary from "
	ewarn "gnome-extra/gnome-utils.  If it is not present, the dictionary "
	ewarn "plugin will fail silently."
	epause 5
}

pkg_postrm() {
	gnome2_pkg_postrm
	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/deskbar
	python_mod_cleanup /usr/$(get_libdir)/deskbar-applet/modules-2.20-compatible
}