[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     c1e8068825fb91102d402c757ad845f162417043
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 23 06:35:51 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Sep 23 06:36:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c1e80688

sys-kernel/gentoo-kernel-bin: add 5.14.7-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.14.7-r1.ebuild             | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index f0d22dff4ac..4883f4d1a9d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -103,6 +103,7 @@ DIST gentoo-kernel-5.14.6-1.amd64.xpak 68042594 BLAKE2B e65f4a2fc48c0d5989e6b5ee
 DIST gentoo-kernel-5.14.6-1.arm64.xpak 63383231 BLAKE2B f3aaf70951c5d4e67d4488fe762db4750a6c212638625c5b10ef075711ceb32f0f43a3011ccc11c5e1d3937616d9ba285f21ac6d1dcef02071c6bff62d0286b4 SHA512 b5a0d0740f408c1db8ffdd5ff546457148e7472fa93f56814a51a2dab85a24753aae5c96b8d4e01abc812d1544a502efcffe0e8b5d93feca2fb5743ac9f098f7
 DIST gentoo-kernel-5.14.6-1.x86.xpak 59165165 BLAKE2B b376b096789549da8fb39bd6d0fd294e09d1c23b83dec963c14a1fc45ae81bd296d7de91721ff7722af12feb3547d2d8d415025d5c573a8ae35b7edee61f9937 SHA512 1c5ec62b7de43a8337496868781d44be96b846c159e7f14a382a442fbb2dd6cc49a95686302705d5d8e30eb92aea397dd18eb0da4c1183692bdc159c07502b72
 DIST gentoo-kernel-5.14.7-1.amd64.xpak 68031586 BLAKE2B 7cc01200f01a93daf5f0c84b09e066474dc5dcef76ddadf5e43843a3bb8a69710134ee9546cbfc6da0149b96e480d59cc0ceb610608c7e6710dccbb9e9e185f2 SHA512 595ce0155ef9df5809d7c27ee310d3978bde477e6778468f467c9f07a60c43dd7ce6e39320d3e298639f01c18cfed5811de480d0afd884586d13f434c533fe6b
+DIST gentoo-kernel-5.14.7-1.arm64.xpak 63383693 BLAKE2B d8780cdd6306f36530d82b9a5b6a74e1d2caf9c4e9db31d6816020bc9415fe92891e418dd08f89628f3d36189c84f97c10b570091c2d1a94a494f37a21286706 SHA512 90ef111ef0ef68dd362c458c9e6ea15959713118787ebd8c68492bd204da83a212e5def456fd550c3f175565c262581855599adeb34692c65f54c2f2d7f1d06c
 DIST gentoo-kernel-5.14.7-1.x86.xpak 59157603 BLAKE2B 2c8d5d3786f9b2aa77d0ac7eb4b3dff0d534bebbd974ec43b8b1e7e9322d3a1b9db0554ebb3bf6943f00673e087bb1067f14d341836012bb46774e5b194f1cf5 SHA512 af337483437a9819d16235e9641cb3f9893e140091e31a06ccb1015a6e946189defb5b2d2d12afd19dffaef1828a2d101b01798f107457a53a93ada2d063f023
 DIST gentoo-kernel-5.4.142-1.amd64.xpak 61382010 BLAKE2B 5753309c6f0e98adf348b332ef8acad749f0501b5a0641f2436c7ca7a48c6e57d9f2b316f06d82b5e362cbdf91aa253ba69c7425b6eda0db46531e04929ac6de SHA512 c8433c79fde6bc7b31ff2d93b24e5b327166dcf00157ef91057b006b071f6c7293940285c54f282d40a09957f91831dac9f622dd477be62ec8fea713b0a6b68e
 DIST gentoo-kernel-5.4.142-1.arm64.xpak 58037550 BLAKE2B f2f047abcfc83ed15154c617a10810c3d608106d47e8ddd7f5a70e8b3d5a77e6df34b56efeacbcd14fd479db3f7c5574026bdf4d2c6910dd8e9bb5940f4443c7 SHA512 8a9f109738071ae08ea7231964d1fda529aa5bb0810e96c19b3b82c1743868545eb254fc0604586c10645583012baaa0d2a2e930e460ba0697102b081d277521

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.7-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.7-r1.ebuild
new file mode 100644
index 00000000000..c4534b7e4c4
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.7-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}