[gentoo-commits] gentoo-x86 commit in app-crypt/seahorse: seahorse-3.12.2.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       14/05/31 08:19:51

  Modified:             ChangeLog
  Added:                seahorse-3.12.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.183                app-crypt/seahorse/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/seahorse/ChangeLog?rev=1.183&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/seahorse/ChangeLog?rev=1.183&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/seahorse/ChangeLog?r1=1.182&r2=1.183

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v
retrieving revision 1.182
retrieving revision 1.183
diff -u -r1.182 -r1.183
--- ChangeLog	27 Apr 2014 22:15:32 -0000	1.182
+++ ChangeLog	31 May 2014 08:19:51 -0000	1.183
@@ -1,6 +1,11 @@
 # ChangeLog for app-crypt/seahorse
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.182 2014/04/27 22:15:32 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.183 2014/05/31 08:19:51 pacho Exp $
+
+*seahorse-3.12.2 (31 May 2014)
+
+  31 May 2014; Pacho Ramos <pacho@g.o> +seahorse-3.12.2.ebuild:
+  Version bump
 
   27 Apr 2014; Gilles Dartiguelongue <eva@g.o> seahorse-3.12.0.ebuild:
   Fix .desktop macro expansion, bug #508610.



1.1                  app-crypt/seahorse/seahorse-3.12.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/seahorse/seahorse-3.12.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-crypt/seahorse/seahorse-3.12.2.ebuild?rev=1.1&content-type=text/plain

Index: seahorse-3.12.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-3.12.2.ebuild,v 1.1 2014/05/31 08:19:51 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"

inherit gnome2

DESCRIPTION="A GNOME application for managing encryption keys"
HOMEPAGE="https://wiki.gnome.org/Apps/Seahorse"

LICENSE="GPL-2+ FDL-1.1+"
SLOT="0"
IUSE="avahi debug ldap"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

COMMON_DEPEND="
	>=app-crypt/gcr-3.11.91:=
	>=dev-libs/glib-2.10:2
	>=x11-libs/gtk+-3.4:3
	>=app-crypt/libsecret-0.16
	>=net-libs/libsoup-2.33.92:2.4
	x11-misc/shared-mime-info

	net-misc/openssh
	>=app-crypt/gpgme-1
	|| (
		=app-crypt/gnupg-2.0*
		=app-crypt/gnupg-1.4* )

	avahi? ( >=net-dns/avahi-0.6:= )
	ldap? ( net-nds/openldap:= )
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/intltool-0.35
	sys-devel/gettext
	virtual/pkgconfig
"
# Need seahorse-plugins git snapshot
RDEPEND="${COMMON_DEPEND}
	!<app-crypt/seahorse-plugins-2.91.0_pre20110114
"

src_prepare() {
	# FIXME: Do not mess with CFLAGS with USE="debug"
	sed -e '/CFLAGS="$CFLAGS -g/d' \
		-e '/CFLAGS="$CFLAGS -O0/d' \
		-i configure.ac configure || die "sed 1 failed"

	gnome2_src_prepare
}

src_configure() {
	# bindir is needed due to bad macro expansion in desktop file, bug #508610
	gnome2_src_configure \
		--bindir=/usr/bin \
		--enable-pgp \
		--enable-ssh \
		--enable-pkcs11 \
		--enable-hkp \
		$(use_enable avahi sharing) \
		$(use_enable debug) \
		$(use_enable ldap) \
		ITSTOOL=$(type -P true) \
		VALAC=$(type -P true)
}