[gentoo-commits] gentoo-x86 commit in dev-util/suse-build: ChangeLog suse-build-2013.12.05.ebuild

[Michal HruAeckA (miska)]

miska       14/02/02 15:11:16

  Modified:             ChangeLog
  Added:                suse-build-2013.12.05.ebuild
  Log:
  New upstream version, bumping to 2013.12.05
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key D39CB7C5)

Revision  Changes    Path
1.21                 dev-util/suse-build/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/suse-build/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/suse-build/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/suse-build/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/suse-build/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	28 Jan 2014 13:35:22 -0000	1.20
+++ ChangeLog	2 Feb 2014 15:11:16 -0000	1.21
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/suse-build
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/suse-build/ChangeLog,v 1.20 2014/01/28 13:35:22 miska Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/suse-build/ChangeLog,v 1.21 2014/02/02 15:11:16 miska Exp $
+
+*suse-build-2013.12.05 (02 Feb 2014)
+
+  02 Feb 2014; Michal Hrusecky <miska@g.o>
+  +suse-build-2013.12.05.ebuild:
+  New upstream version, bumping to 2013.12.05
 
 *suse-build-2013.10.15-r1 (28 Jan 2014)
 



1.1                  dev-util/suse-build/suse-build-2013.12.05.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/suse-build/suse-build-2013.12.05.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/suse-build/suse-build-2013.12.05.ebuild?rev=1.1&content-type=text/plain

Index: suse-build-2013.12.05.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/suse-build/suse-build-2013.12.05.ebuild,v 1.1 2014/02/02 15:11:16 miska Exp $

EAPI=5

EGIT_REPO_URI="git://github.com/openSUSE/obs-build.git"

if [[ "${PV}" == "9999" ]]; then
	EXTRA_ECLASS="git-2"
else
	OBS_PACKAGE="build"
	OBS_PROJECT="openSUSE:Tools"
	EXTRA_ECLASS="obs-download"
fi

inherit eutils ${EXTRA_ECLASS}
unset EXTRA_ECLASS

DESCRIPTION="Script to build SUSE Linux RPMs"
HOMEPAGE="https://build.opensuse.org/package/show/openSUSE:Tools/build"

[[ "${PV}" == "9999" ]] || SRC_URI="${OBS_URI}/${PN/suse/obs}-${PV//.}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE="symlink"
[[ "${PV}" == "9999" ]] || \
KEYWORDS="~amd64 ~x86"

RDEPEND="
	virtual/perl-Digest-MD5
	virtual/perl-Getopt-Long
	dev-perl/XML-Parser
	dev-perl/TimeDate
	app-shells/bash
	app-arch/cpio
	app-arch/rpm
"

S="${WORKDIR}/${PN/suse/obs}-${PV//.}"

src_prepare() {
	epatch "${FILESDIR}/suse-build-20131015-libexec-paths.patch"
}

src_compile() { :; }

src_install() {
	emake DESTDIR="${ED}" pkglibdir=/usr/libexec/suse-build install
	cd "${ED}"/usr
	find bin -type l | while read i; do
		mv "${i}" "${i/bin\//bin/suse-}"
		use !symlink || dosym "${i/bin\//suse-}" "/usr/${i}"
	done
	find share/man/man1 -type f | while read i; do
		mv "${i}" "${i/man1\//man1/suse-}"
		use !symlink || dosym "${i/man1\//suse-}" "/usr/${i}"
	done

	# create symlink for default build config
	dosym /usr/libexec/suse-build/configs/sl13.2.conf /usr/libexec/suse-build/configs/default.conf
}