Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status

Gentoo Archives: gentoo-commits

From: "Michael Sterrett (mr_bones_)" <mr_bones_@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in media-libs/allegro: allegro-4.4.2.ebuild ChangeLog allegro-5.0.4.ebuild
Date: Sat, 03 Sep 2011 08:57:21
Message-Id: 20110903085709.A842220054@flycatcher.gentoo.org
1 mr_bones_ 11/09/03 08:57:09
2
3 Modified: ChangeLog
4 Added: allegro-4.4.2.ebuild allegro-5.0.4.ebuild
5 Log:
6 version bump (bug #380657)
7
8 (Portage version: 2.1.10.11/cvs/Linux i686)
9
10 Revision Changes Path
11 1.110 media-libs/allegro/ChangeLog
12
13 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/ChangeLog?rev=1.110&view=markup
14 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/ChangeLog?rev=1.110&content-type=text/plain
15 diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/ChangeLog?r1=1.109&r2=1.110
16
17 Index: ChangeLog
18 ===================================================================
19 RCS file: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v
20 retrieving revision 1.109
21 retrieving revision 1.110
22 diff -u -r1.109 -r1.110
23 --- ChangeLog 9 Aug 2011 12:29:55 -0000 1.109
24 +++ ChangeLog 3 Sep 2011 08:57:09 -0000 1.110
25 @@ -1,6 +1,15 @@
26 # ChangeLog for media-libs/allegro
27 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
28 -# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v 1.109 2011/08/09 12:29:55 xarthisius Exp $
29 +# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v 1.110 2011/09/03 08:57:09 mr_bones_ Exp $
30 +
31 +*allegro-5.0.4 (03 Sep 2011)
32 +*allegro-4.4.2 (03 Sep 2011)
33 +
34 + 03 Sep 2011; Michael Sterrett <mr_bones_@g.o> +allegro-4.4.2.ebuild,
35 + +files/allegro-4.4.2-rpath.patch, +files/allegro-4.4.2-shared.patch,
36 + +files/allegro-4.4.2-underlink.patch, +allegro-5.0.4.ebuild,
37 + +files/allegro-5.0.4-underlink.patch:
38 + version bump (bug #380657)
39
40 09 Aug 2011; Kacper Kowalik <xarthisius@g.o> allegro-5.0.3.ebuild:
41 ppc/ppc64 stable wrt #375491
42
43
44
45 1.1 media-libs/allegro/allegro-4.4.2.ebuild
46
47 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/allegro-4.4.2.ebuild?rev=1.1&view=markup
48 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/allegro-4.4.2.ebuild?rev=1.1&content-type=text/plain
49
50 Index: allegro-4.4.2.ebuild
51 ===================================================================
52 # Copyright 1999-2011 Gentoo Foundation
53 # Distributed under the terms of the GNU General Public License v2
54 # $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-4.4.2.ebuild,v 1.1 2011/09/03 08:57:09 mr_bones_ Exp $
55
56 EAPI=2
57 CMAKE_IN_SOURCE_BUILD=1
58 inherit cmake-utils eutils
59
60 DESCRIPTION="cross-platform multimedia library"
61 HOMEPAGE="http://alleg.sourceforge.net/"
62 SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"
63
64 LICENSE="Allegro as-is GPL-2 ZLIB"
65 SLOT="0"
66 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
67 IUSE="alsa fbcon jack jpeg opengl oss png svga test vga vorbis X"
68
69 RDEPEND="alsa? ( media-libs/alsa-lib )
70 jack? ( media-sound/jack-audio-connection-kit )
71 jpeg? ( virtual/jpeg )
72 png? ( >=media-libs/libpng-1.4 )
73 svga? ( media-libs/svgalib )
74 vorbis? ( media-libs/libvorbis )
75 X? (
76 x11-libs/libX11
77 x11-libs/libXcursor
78 x11-libs/libXext
79 x11-libs/libXpm
80 x11-libs/libXt
81 x11-libs/libXxf86dga
82 x11-libs/libXxf86vm
83 opengl? ( virtual/opengl
84 virtual/glu )
85 )
86 !media-libs/allegrogl
87 !media-libs/jpgalleg"
88 DEPEND="${RDEPEND}
89 dev-util/pkgconfig
90 X? (
91 x11-proto/xextproto
92 x11-proto/xf86dgaproto
93 x11-proto/xf86vidmodeproto
94 x11-proto/xproto
95 )"
96
97 src_prepare() {
98 epatch "${FILESDIR}"/${P}-shared.patch \
99 "${FILESDIR}"/${P}-underlink.patch \
100 "${FILESDIR}"/${P}-rpath.patch
101
102 sed -i \
103 -e "s:allegro-\${ALLEGRO_VERSION}:${PF}:" \
104 docs/CMakeLists.txt || die
105 }
106
107 src_configure() {
108 # WANT_LINUX_CONSOLE is by default OFF
109 # WANT_EXAMPLES doesn't install anything
110
111 mycmakeargs=(
112 "-DDOCDIR=share/doc"
113 "-DINFODIR=share/info"
114 "-DMANDIR=share/man"
115 $(cmake-utils_use_want alsa)
116 "-DWANT_EXAMPLES=OFF"
117 $(cmake-utils_use_want jack)
118 $(cmake-utils_use_want jpeg JPGALLEG)
119 "-DWANT_LINUX_CONSOLE=OFF"
120 $(cmake-utils_use_want fbcon LINUX_FBCON)
121 $(cmake-utils_use_want svga LINUX_SVGALIB)
122 $(cmake-utils_use_want vga LINUX_VGA)
123 $(cmake-utils_use_want png LOADPNG)
124 $(cmake-utils_use_want vorbis LOGG)
125 $(cmake-utils_use_want oss)
126 $(cmake-utils_use_want test TESTS)
127 $(cmake-utils_use_want X TOOLS)
128 $(cmake-utils_use_want X X11)
129 )
130
131 if use X; then
132 mycmakeargs+=(
133 $(cmake-utils_use_want opengl ALLEGROGL)
134 )
135 else
136 mycmakeargs+=(
137 "-DWANT_ALLEGROGL=OFF"
138 )
139 fi
140
141 cmake-utils_src_configure
142 }
143
144 src_install() {
145 cmake-utils_src_install
146
147 dohtml docs/html/*.html || die
148 doman docs/man/*.3 || die
149
150 if use X; then
151 newbin setup/setup ${PN}-setup || die
152 insinto /usr/share/${PN}
153 doins {keyboard,language,setup/setup}.dat || die
154 newicon misc/icon.png ${PN}.png
155 make_desktop_entry ${PN}-setup "Allegro Setup" ${PN} "Settings"
156 fi
157
158 rm -f "${D}"/usr/share/man/man3/init_dialog.3* #176020
159 newman docs/man/init_dialog.3 allegro_init_dialog.3
160 }
161
162
163
164 1.1 media-libs/allegro/allegro-5.0.4.ebuild
165
166 file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/allegro-5.0.4.ebuild?rev=1.1&view=markup
167 plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/allegro/allegro-5.0.4.ebuild?rev=1.1&content-type=text/plain
168
169 Index: allegro-5.0.4.ebuild
170 ===================================================================
171 # Copyright 1999-2011 Gentoo Foundation
172 # Distributed under the terms of the GNU General Public License v2
173 # $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-5.0.4.ebuild,v 1.1 2011/09/03 08:57:09 mr_bones_ Exp $
174
175 EAPI=2
176 inherit cmake-utils
177
178 DESCRIPTION="A game programming library"
179 HOMEPAGE="http://alleg.sourceforge.net/"
180 SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"
181
182 LICENSE="BSD ZLIB"
183 SLOT="5"
184 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
185 IUSE="alsa dumb flac gtk jpeg openal oss physfs png pulseaudio test truetype vorbis X xinerama"
186
187 RDEPEND="alsa? ( media-libs/alsa-lib )
188 dumb? ( media-libs/dumb )
189 flac? ( media-libs/flac )
190 jpeg? ( virtual/jpeg )
191 openal? ( media-libs/openal )
192 physfs? ( dev-games/physfs )
193 png? ( >=media-libs/libpng-1.4 )
194 pulseaudio? ( >=media-sound/pulseaudio-0.9.15 )
195 truetype? ( >=media-libs/freetype-2 )
196 vorbis? ( media-libs/libvorbis )
197 x11-libs/libXcursor
198 x11-libs/libXxf86vm
199 x11-libs/libXrandr
200 x11-libs/libX11
201 gtk? ( x11-libs/gtk+:2 )
202 virtual/opengl
203 xinerama? ( x11-libs/libXinerama )"
204
205 DEPEND="${RDEPEND}
206 dev-util/pkgconfig
207 x11-proto/xextproto
208 x11-proto/xf86vidmodeproto
209 x11-proto/xproto"
210
211 PATCHES=( "${FILESDIR}"/${P}-underlink.patch )
212
213 src_configure() {
214 local mycmakeargs=(
215 $(cmake-utils_use_want alsa)
216 -DWANT_DEMO=OFF
217 -DWANT_EXAMPLES=OFF
218 $(cmake-utils_use_want flac)
219 $(cmake-utils_use_want jpeg IMAGE_JPG)
220 $(cmake-utils_use_want png IMAGE_PNG)
221 $(cmake-utils_use_want dumb MODAUDIO)
222 $(cmake-utils_use_want openal)
223 $(cmake-utils_use_want oss)
224 $(cmake-utils_use_want physfs)
225 $(cmake-utils_use_want pulseaudio)
226 $(cmake-utils_use_want test TESTS)
227 $(cmake-utils_use_want truetype TTF)
228 $(cmake-utils_use_want vorbis)
229 $(cmake-utils_use_want gtk NATIVE_DIALOG)
230 $(cmake-utils_use_want X opengl)
231 $(cmake-utils_use_want xinerama X11_XINERAMA)
232 )
233
234 cmake-utils_src_configure
235 }
236
237 src_install() {
238 cmake-utils_src_install
239
240 dodoc CHANGES-5.0.txt || die
241 dohtml -r docs/html/refman/* || die
242 doman docs/man/*.3 || die
243 }
Report Message
Find on MARC Find on Google Groups