[gentoo-commits] gentoo-x86 commit in media-gfx/nip2: metadata.xml ChangeLog nip2-7.22.1.ebuild

[Peter Volkov (pva)]

pva         10/06/25 11:06:16

  Modified:             metadata.xml ChangeLog
  Added:                nip2-7.22.1.ebuild
  Log:
  Version bump. Fixed tests failure #314099, thank Diego E. 'Flameeyes' Pettenò for report.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  media-gfx/nip2/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/nip2/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	3 Jun 2005 16:19:30 -0000	1.2
+++ metadata.xml	25 Jun 2010 11:06:15 -0000	1.3
@@ -1,8 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
-
 <pkgmetadata>
-
 	<herd>graphics</herd>
-
+	<maintainer>
+		<email>pva@g.o</email>
+		<name>Peter Volkov</name>
+	</maintainer>
+	<use>
+	<flag name='goffice'>use <pkg>x11-libs/goffice</pkg> to show plots</flag>
+	</use>
 </pkgmetadata>



1.25                 media-gfx/nip2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	18 Apr 2010 12:06:00 -0000	1.24
+++ ChangeLog	25 Jun 2010 11:06:16 -0000	1.25
@@ -1,6 +1,16 @@
 # ChangeLog for media-gfx/nip2
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v 1.24 2010/04/18 12:06:00 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/ChangeLog,v 1.25 2010/06/25 11:06:16 pva Exp $
+
+  25 Jun 2010; Peter Volkov <pva@g.o> +nip2-7.22.1.ebuild,
+  metadata.xml:
+  Version bump. Fixed tests failure #314099, thank Diego E. 'Flameeyes'
+  Pettenò for report.
+
+*nip2-7.22.1 (25 Jun 2010)
+
+  25 Jun 2010; Peter Volkov <pva@g.o> +nip2-7.22.1.ebuild:
+  Version bump.
 
   18 Apr 2010; Markus Meier <maekke@g.o> nip2-7.20.7.ebuild:
   x86 stable, bug #304787



1.1                  media-gfx/nip2/nip2-7.22.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/nip2-7.22.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/nip2/nip2-7.22.1.ebuild?rev=1.1&content-type=text/plain

Index: nip2-7.22.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/nip2/nip2-7.22.1.ebuild,v 1.1 2010/06/25 11:06:16 pva Exp $

EAPI=2
inherit eutils autotools fdo-mime gnome2-utils versionator

MY_MAJ_VER=$(get_version_component_range 1-2)
DESCRIPTION="VIPS Image Processing Graphical User Interface"
SRC_URI="http://www.vips.ecs.soton.ac.uk/supported/${MY_MAJ_VER}/${P}.tar.gz"
HOMEPAGE="http://vips.sourceforge.net"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="fftw goffice gsl test"

RDEPEND=">=dev-libs/glib-2.14:2
	dev-libs/libxml2
	x11-misc/xdg-utils
	>=media-libs/vips-${MY_MAJ_VER}
	>=x11-libs/gtk+-2.18:2
	goffice? ( x11-libs/goffice:0.8 )
	gsl? ( sci-libs/gsl )
	fftw? ( sci-libs/fftw:3.0 )"
DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex
	test? ( media-libs/vips[jpeg,lcms] )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-7.16.4-fftw3-build.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-update-desktop \
		$(use_with goffice libgoffice) \
		$(use_with gsl) \
		$(use_with fftw fftw3)
}

src_test() {
	if ! use gsl; then
		ewarn "Some tests require USE=gsl. Disabling test_math.ws tests."
		rm test/workspaces/test_math.ws
	fi
	make check || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README* || die
	insinto /usr/share/icons/hicolor/128x128/apps
	newins share/nip2/data/vips-128.png nip2.png || die
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
	gnome2_icon_cache_update
}