[gentoo-commits] gentoo-x86 commit in games-fps/alephone: ChangeLog alephone-20091015.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    09/11/02 18:05:22

  Modified:             ChangeLog
  Added:                alephone-20091015.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.27                 games-fps/alephone/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alephone/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alephone/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alephone/ChangeLog?r1=1.26&r2=1.27

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-fps/alephone/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog	4 Mar 2009 21:25:35 -0000	1.26
+++ ChangeLog	2 Nov 2009 18:05:21 -0000	1.27
@@ -1,6 +1,12 @@
 # ChangeLog for games-fps/alephone
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-fps/alephone/ChangeLog,v 1.26 2009/03/04 21:25:35 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-fps/alephone/ChangeLog,v 1.27 2009/11/02 18:05:21 mr_bones_ Exp $
+
+*alephone-20091015 (02 Nov 2009)
+
+  02 Nov 2009; Michael Sterrett <mr_bones_@g.o>
+  +alephone-20091015.ebuild:
+  version bump
 
 *alephone-20081226 (04 Mar 2009)
 



1.1                  games-fps/alephone/alephone-20091015.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alephone/alephone-20091015.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-fps/alephone/alephone-20091015.ebuild?rev=1.1&content-type=text/plain

Index: alephone-20091015.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-fps/alephone/alephone-20091015.ebuild,v 1.1 2009/11/02 18:05:21 mr_bones_ Exp $

EAPI=2
inherit autotools games

MY_P=AlephOne-${PV}
DESCRIPTION="An enhanced version of the game engine from the classic Mac game, Marathon"
HOMEPAGE="http://source.bungie.org/"
SRC_URI="mirror://sourceforge/marathon/${MY_P}.tar.bz2"

LICENSE="GPL-2 BitstreamVera"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="alsa mad mpeg opengl sndfile speex truetype vorbis"

RDEPEND="media-libs/sdl-net
	media-libs/sdl-image
	media-libs/libsdl
	dev-libs/expat
	alsa? ( media-libs/alsa-lib )
	mad? ( media-libs/libmad )
	mpeg? ( media-libs/smpeg )
	opengl? ( virtual/opengl )
	sndfile? ( media-libs/libsndfile )
	speex? ( media-libs/speex )
	truetype? ( media-libs/sdl-ttf )
	vorbis? ( media-libs/libvorbis )"
DEPEND="${RDEPEND}
	dev-libs/boost"

S=${WORKDIR}/${MY_P}

src_prepare() {
	sed "s:GAMES_DATADIR:${GAMES_DATADIR}:g" \
		"${FILESDIR}"/${PN}.sh > "${T}"/${PN}.sh \
		|| die "sed failed"

	# try using the system expat - bug #251108
	sed -i \
		-e '/SUBDIRS/ s/Expat//' \
		-e 's/Expat\/libexpat.a/-lexpat/' \
		Source_Files/Makefile.am \
		|| die "sed failed"
	sed -i \
		-e '/Expat/d' \
		configure.ac \
		|| die "sed failed"
	rm -rf Source_Files/Expat

	eautoreconf
}

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		--enable-lua \
		$(use_enable alsa) \
		$(use_enable mad) \
		$(use_enable mpeg smpeg) \
		$(use_enable opengl) \
		$(use_enable sndfile) \
		$(use_enable speex) \
		$(use_enable truetype ttf) \
		$(use_enable vorbis)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dogamesbin "${T}"/${PN}.sh || die "dogamesbin failed"
	doman docs/${PN}.6
	dodoc AUTHORS ChangeLog README
	dohtml docs/*.html
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	echo
	elog "Read the docs and install the data files accordingly to play."
	echo
	elog "If you only want to install one scenario, read"
	elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Single_scenario_3"
	elog "If you want to install multiple scenarios, read"
	elog "http://traxus.bungie.org/index.php/Aleph_One_install_guide#Multiple_scenarios_3"
	echo
}