[gentoo-commits] gentoo-x86 commit in sys-cluster/keepalived: ChangeLog keepalived-1.1.15.ebuild

[Robin H. Johnson (robbat2)]

robbat2     07/09/22 09:12:37

  Modified:             ChangeLog
  Added:                keepalived-1.1.15.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.3.7)

Revision  Changes    Path
1.43                 sys-cluster/keepalived/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-cluster/keepalived/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-cluster/keepalived/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-cluster/keepalived/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	30 Apr 2007 06:45:49 -0000	1.42
+++ ChangeLog	22 Sep 2007 09:12:36 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for sys-cluster/keepalived
 # Copyright 2000-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/ChangeLog,v 1.42 2007/04/30 06:45:49 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/ChangeLog,v 1.43 2007/09/22 09:12:36 robbat2 Exp $
+
+*keepalived-1.1.15 (22 Sep 2007)
+
+  22 Sep 2007; Robin H. Johnson <robbat2@g.o>
+  +keepalived-1.1.15.ebuild:
+  Version bump.
 
   30 Apr 2007; Robin H. Johnson <robbat2@g.o> files/init-keepalived:
   Make init.d baselayout2 safe.



1.1                  sys-cluster/keepalived/keepalived-1.1.15.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-cluster/keepalived/keepalived-1.1.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-cluster/keepalived/keepalived-1.1.15.ebuild?rev=1.1&content-type=text/plain

Index: keepalived-1.1.15.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/keepalived/keepalived-1.1.15.ebuild,v 1.1 2007/09/22 09:12:36 robbat2 Exp $

inherit flag-o-matic autotools

DESCRIPTION="add a strong & robust keepalive facility to the Linux Virtual Server project"
HOMEPAGE="http://www.keepalived.org/"
SRC_URI="http://www.keepalived.org/software/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="debug profile"

RDEPEND="dev-libs/popt
	sys-apps/iproute2
	dev-libs/openssl"
DEPEND="${RDEPEND}
	=sys-kernel/linux-headers-2.6*"

src_unpack() {
	unpack ${A}

	# This patch allows us to avoid needing kernel sources for the configure phase
	EPATCH_OPTS="-p1 -d${S}" epatch \
		${FILESDIR}/${PN}-1.1.13-do-not-need-kernel-sources.patch
	cd ${S}
	eautoreconf

	# Prepare a suitable copy of the IPVS headers
	# So that we don't need kernel sources at all!
	mkdir -p ${S}/include/net || die "Failed to prepare ipvs header directory"
	cp -f ${FILESDIR}/${PN}-1.1.13-linux-2.6.21-ip_vs.h \
		${S}/include/net/ip_vs.h || die "Failed to add ipvs header"

	# Ensure that keepalived can find the header that we are injecting
	append-flags -I${S}/include
}

src_compile() {
	local myconf

	myconf="--enable-vrrp"

	# This is not an error
	# The upstream makefile used to add man/, but doesn't anymore
	myconf="${myconf} --mandir=/usr/share/man"

	use debug && myconf="${myconf} --enable-debug"

	# disable -fomit-frame-pointer for profiling
	if use profile; then
		filter-flags -fomit-frame-pointer
		myconf="${myconf} --enable-profile"
	fi

	econf ${myconf} STRIP=/bin/true || die "configure failed"
	emake || die "emake failed (myconf=${myconf})"
}

src_install() {
	# Not parallel safe
	emake -j1 install DESTDIR="${D}" || die "emake install failed"

	newinitd ${FILESDIR}/init-keepalived keepalived

	dodoc doc/keepalived.conf.SYNOPSIS
	dodoc README CONTRIBUTORS INSTALL VERSION ChangeLog AUTHOR TODO

	docinto genhash
	dodoc genhash/README genhash/AUTHOR genhash/ChangeLog genhash/VERSION
	# This was badly named by upstream, it's more HOWTO than anything else.
	newdoc INSTALL INSTALL+HOWTO

	# Security risk to bundle SSL certs
	rm -f ${D}/etc/keepalived/samples/*.pem
	rm -rf ${D}/etc/sysconfig ${D}/etc/rc.d/
}

pkg_postinst() {
	elog "For internal debug support, compile with USE=debug via package.use"
}



-- 
gentoo-commits@g.o mailing list