[gentoo-commits] gentoo-x86 commit in sys-fs/ntfs3g: ntfs3g-2013.1.13.ebuild ChangeLog ntfs3g-2014.2.15.ebuild ntfs3g-2012.1.15-r1.ebuild ntfs3g-2012.1.15-r2.ebuild

[Patrick McLean (chutzpah)]

chutzpah    14/02/27 00:25:13

  Modified:             ntfs3g-2013.1.13.ebuild ChangeLog
  Added:                ntfs3g-2014.2.15.ebuild
  Removed:              ntfs3g-2012.1.15-r1.ebuild
                        ntfs3g-2012.1.15-r2.ebuild
  Log:
  Version bump. Drop old versions. Update libgcrypt dep in 2013.1.13 to specify less than 1.6.0.
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

Revision  Changes    Path
1.12                 sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild?r1=1.11&r2=1.12

Index: ntfs3g-2013.1.13.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ntfs3g-2013.1.13.ebuild	24 Feb 2014 01:18:23 -0000	1.11
+++ ntfs3g-2013.1.13.ebuild	27 Feb 2014 00:25:13 -0000	1.12
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild,v 1.11 2014/02/24 01:18:23 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2013.1.13.ebuild,v 1.12 2014/02/27 00:25:13 chutzpah Exp $
 
 EAPI=5
 inherit eutils linux-info udev
@@ -21,6 +21,7 @@
 	!sys-fs/ntfsprogs
 	ntfsdecrypt? (
 		>=dev-libs/libgcrypt-1.2.2
+		<dev-libs/libgcrypt-1.6.0
 		>=net-libs/gnutls-1.4.4
 		)
 	external-fuse? ( >=sys-fs/fuse-2.8.0 )"



1.156                sys-fs/ntfs3g/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ChangeLog?rev=1.156&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ChangeLog?rev=1.156&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ChangeLog?r1=1.155&r2=1.156

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ChangeLog,v
retrieving revision 1.155
retrieving revision 1.156
diff -u -r1.155 -r1.156
--- ChangeLog	24 Feb 2014 01:18:23 -0000	1.155
+++ ChangeLog	27 Feb 2014 00:25:13 -0000	1.156
@@ -1,6 +1,14 @@
 # ChangeLog for sys-fs/ntfs3g
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ChangeLog,v 1.155 2014/02/24 01:18:23 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ChangeLog,v 1.156 2014/02/27 00:25:13 chutzpah Exp $
+
+*ntfs3g-2014.2.15 (27 Feb 2014)
+
+  27 Feb 2014; Patrick McLean <chutzpah@g.o>
+  -ntfs3g-2012.1.15-r1.ebuild, -ntfs3g-2012.1.15-r2.ebuild,
+  ntfs3g-2013.1.13.ebuild, +ntfs3g-2014.2.15.ebuild:
+  Version bump. Drop old versions. Update libgcrypt dep in 2013.1.13 to specify
+  less than 1.6.0.
 
   24 Feb 2014; Pawel Hajdan jr <phajdan.jr@g.o> ntfs3g-2013.1.13.ebuild:
   x86 stable wrt bug #495310



1.1                  sys-fs/ntfs3g/ntfs3g-2014.2.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2014.2.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2014.2.15.ebuild?rev=1.1&content-type=text/plain

Index: ntfs3g-2014.2.15.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/ntfs3g/ntfs3g-2014.2.15.ebuild,v 1.1 2014/02/27 00:25:13 chutzpah Exp $

EAPI=5
inherit eutils linux-info udev

MY_PN=${PN/3g/-3g}
MY_P=${MY_PN}_ntfsprogs-${PV}

DESCRIPTION="Open source read-write NTFS driver that runs under FUSE"
HOMEPAGE="http://www.tuxera.com/community/ntfs-3g-download/"
SRC_URI="http://tuxera.com/opensource/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
IUSE="acl debug +external-fuse ntfsdecrypt +ntfsprogs static-libs suid xattr"

RDEPEND="!<sys-apps/util-linux-2.20.1-r2
	!sys-fs/ntfsprogs
	ntfsdecrypt? (
		>=dev-libs/libgcrypt-1.2.2
		>=net-libs/gnutls-1.4.4
		)
	external-fuse? ( >=sys-fs/fuse-2.8.0 )"
DEPEND="${RDEPEND}
	sys-apps/attr
	virtual/pkgconfig"

S=${WORKDIR}/${MY_P}

DOCS="AUTHORS ChangeLog CREDITS README"

pkg_setup() {
	if use external-fuse && use kernel_linux; then
		if kernel_is lt 2 6 9; then
			die "Your kernel is too old."
		fi
		CONFIG_CHECK="~FUSE_FS"
		FUSE_FS_WARNING="You need to have FUSE module built to use ntfs-3g"
		linux-info_pkg_setup
	fi
}

src_prepare() {
	# add missing $(sbindir) references
	sed -e 's:sbin\($\|/\):$(sbindir)\1:g' \
		-i ntfsprogs/Makefile.in src/Makefile.in || die
}

src_configure() {
	econf \
		--prefix="${EPREFIX}"/usr \
		--exec-prefix="${EPREFIX}"/usr \
		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
		$(use_enable debug) \
		--enable-ldscript \
		--disable-ldconfig \
		$(use_enable acl posix-acls) \
		$(use_enable xattr xattr-mappings) \
		$(use_enable ntfsdecrypt crypto) \
		$(use_enable ntfsprogs) \
		--without-uuid \
		--enable-extras \
		$(use_enable static-libs static) \
		--with-fuse=$(usex external-fuse external internal)
}

src_install() {
	default

	use suid && fperms u+s /usr/bin/${MY_PN}
	udev_dorules "${FILESDIR}"/99-ntfs3g.rules
	prune_libtool_files

	# http://bugs.gentoo.org/398069
	rmdir "${D}"/sbin

	dosym mount.ntfs-3g /usr/sbin/mount.ntfs #374197
}

pkg_pretend() {
	if [[ ${MERGE_TYPE} != binary ]]; then
		# Bug 450024
		if $(tc-getLD) --version | grep -q "GNU gold"; then
			eerror "ntfs-3g does not function correctly when built with the gold linker."
			eerror "Please select the bfd linker with binutils-config."
			die "GNU gold detected"
		fi
	fi
}