[gentoo-commits] gentoo-x86 commit in app-office/abiword: metadata.xml ChangeLog abiword-2.6.4.ebuild abiword-2.8.4.ebuild abiword-2.6.5.ebuild abiword-2.6.6.ebuild

[Gilles Dartiguelongue (eva)]

eva         10/04/19 23:16:35

  Modified:             metadata.xml ChangeLog abiword-2.6.4.ebuild
  Added:                abiword-2.8.4.ebuild
  Removed:              abiword-2.6.5.ebuild abiword-2.6.6.ebuild
  Log:
  Major version bump, bug #272097. Drop usage of a couple of old libraries. Clean up old revisions.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  app-office/abiword/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/abiword/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	1 Nov 2005 16:21:48 -0000	1.2
+++ metadata.xml	19 Apr 2010 23:16:35 -0000	1.3
@@ -2,4 +2,16 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>gnome-office</herd>
+<use>
+  <flag name='collab'>Enable collaborative editing plugin</flag>
+  <flag name='grammar'>Enable grammar checking via
+    <pkg>dev-libs/link-grammar</pkg></flag>
+  <flag name='math'>Enable support for <pkg>x11-libs/gtkmathview</pkg></flag>
+  <flag name='openxml'>Enable OpenXML support</flag>
+  <flag name='ots'>Enable Text Summarizer plugin</flag>
+  <flag name='plugins'>Enable plugins build</flag>
+  <flag name='thesaurus'>Enable thesaurus support</flag>
+  <flag name='wordperfect'>Enable wordperfect file support via
+    <pkg>app-text/libwpd</pkg></flag>
+</use>
 </pkgmetadata>



1.215                app-office/abiword/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/ChangeLog?rev=1.215&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/ChangeLog?rev=1.215&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/ChangeLog?r1=1.214&r2=1.215

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/abiword/ChangeLog,v
retrieving revision 1.214
retrieving revision 1.215
diff -u -r1.214 -r1.215
--- ChangeLog	31 Mar 2010 18:47:09 -0000	1.214
+++ ChangeLog	19 Apr 2010 23:16:35 -0000	1.215
@@ -1,6 +1,14 @@
 # ChangeLog for app-office/abiword
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/abiword/ChangeLog,v 1.214 2010/03/31 18:47:09 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/abiword/ChangeLog,v 1.215 2010/04/19 23:16:35 eva Exp $
+
+*abiword-2.8.4 (19 Apr 2010)
+
+  19 Apr 2010; Gilles Dartiguelongue <eva@g.o> abiword-2.6.4.ebuild,
+  -abiword-2.6.5.ebuild, -abiword-2.6.6.ebuild, +abiword-2.8.4.ebuild,
+  metadata.xml:
+  Major version bump, bug #272097. Drop usage of a couple of old libraries.
+  Clean up old revisions.
 
   31 Mar 2010; Raúl Porcel <armin76@g.o> abiword-2.6.8.ebuild:
   alpha/ia64/sparc stable wrt #283031



1.11                 app-office/abiword/abiword-2.6.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/abiword-2.6.4.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/abiword-2.6.4.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/abiword-2.6.4.ebuild?r1=1.10&r2=1.11

Index: abiword-2.6.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-office/abiword/abiword-2.6.4.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- abiword-2.6.4.ebuild	4 Jan 2009 22:51:26 -0000	1.10
+++ abiword-2.6.4.ebuild	19 Apr 2010 23:16:35 -0000	1.11
@@ -1,6 +1,6 @@
-# Copyright 1999-2009 Gentoo Foundation
+# Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/abiword/abiword-2.6.4.ebuild,v 1.10 2009/01/04 22:51:26 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/abiword/abiword-2.6.4.ebuild,v 1.11 2010/04/19 23:16:35 eva Exp $
 
 EAPI="1"
 
@@ -14,7 +14,7 @@
 
 LICENSE="GPL-2"
 SLOT="2"
-KEYWORDS="alpha amd64 hppa ia64 ppc ppc64 sparc x86"
+KEYWORDS="hppa"
 IUSE="debug gnome spell xml"
 
 # FIXME: gsf could probably be conditional



1.1                  app-office/abiword/abiword-2.8.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/abiword-2.8.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-office/abiword/abiword-2.8.4.ebuild?rev=1.1&content-type=text/plain

Index: abiword-2.8.4.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/abiword/abiword-2.8.4.ebuild,v 1.1 2010/04/19 23:16:35 eva Exp $

EAPI="3"

inherit alternatives gnome2 versionator

MY_MAJORV=$(get_version_component_range 1-2)

DESCRIPTION="Fully featured yet light and fast cross platform word processor"
HOMEPAGE="http://www.abisource.com/"
SRC_URI="http://www.abisource.com/downloads/${PN}/${PV}/source/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="2"
KEYWORDS="~amd64 ~x86"
IUSE="collab cups gnome grammar latex libgda math ots openxml plugins readline spell wordperfect wmf thesaurus" # svg

# libgsf raised to make sure it provides gio backend (ebuild)
# not enabling telepathy backend for collab, it depends on libempathy-gtk which
# has be removed from empathy-2.30 already
RDEPEND="
	>=app-text/wv-1.2
	>=dev-libs/fribidi-0.10.4
	>=dev-libs/glib-2.16
	>=gnome-base/librsvg-2.16
	>=gnome-extra/libgsf-1.14.15
	>=media-libs/libpng-1.2
	media-libs/jpeg:0
	>=x11-libs/cairo-1.8[X]
	>=x11-libs/gtk+-2.14[cups?]
	gnome? (
		>=gnome-extra/gucharmap-2
		>=x11-libs/goffice-0.8:0.8 )
	plugins? (
		collab? (
			dev-cpp/asio
			>=dev-libs/boost-1.33.1
			>=dev-libs/libxml2-2.4
			>=net-libs/loudmouth-1
			net-libs/libsoup:2.4
			net-libs/gnutls )
		grammar? ( >=dev-libs/link-grammar-4.2.1 )
		latex? ( dev-libs/libxslt )
		libgda? (
			=gnome-extra/libgda-1*
			=gnome-extra/libgnomedb-1* )
		math? ( >=x11-libs/gtkmathview-0.7.5 )
		openxml? ( dev-libs/boost )
		ots? ( >=app-text/ots-0.5 )
		readline? ( sys-libs/readline )
		thesaurus? ( >=app-text/aiksaurus-1.2[gtk] )
		wordperfect? (
			>=app-text/libwpd-0.8
			>=media-libs/libwpg-0.1 )
		wmf? ( >=media-libs/libwmf-0.2.8 )
	)
	spell? ( >=app-text/enchant-1.2 )
	!<app-office/abiword-plugins-2.8"
#		svg? ( >=gnome-base/librsvg-2 )

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9"

pkg_setup() {
	# do not enable gnome-vfs
	G2CONF="${G2CONF}
		--enable-shave
		--disable-static
		--disable-maintainer-mode
		--disable-default-plugins
		--disable-builtin-plugins
		--disable-collab-backend-telepathy
		--enable-clipart
		--enable-statusbar
		--enable-templates
		--with-gio
		--without-gnomevfs
		$(use_with gnome goffice)
		$(use_enable cups print)
		$(use_enable collab collab-backend-xmpp)
		$(use_enable collab collab-backend-tcp)
		$(use_enable collab collab-backend-service)
		$(use_enable spell)"
}

src_configure() {
	local plugins=""

	if use plugins; then
		# Plugins depending on libgsf
		plugins="t602 docbook clarisworks wml kword hancom openwriter pdf
			loadbindings mswrite garble pdb applix opendocument sdw xslfo"

		# Plugins not depending on anything
		plugins="${plugins} gimp bmp freetranslation iscii s5 babelfish opml eml
			wikipedia gdict passepartout google presentation urldict hrtext mif"

		# inter7eps: eps.h
		# libtidy: gsf + tidy.h
		# paint: windows only ?
		use collab && plugins="${plugins} collab"
		use gnome && plugins="${plugins} goffice"
		use latex && plugins="${plugins} latex"
		use libgda && plugins="${plugins} gda"
		use math && plugins="${plugins} mathview"
		use openxml && plugins="${plugins} openxml"
		use ots && plugins="${plugins} ots"
		# psion: >=psiconv-0.9.4
		use readline && plugins="${plugins} command"
		# plugin doesn't build
		#use svg && plugins="${plugins} rsvg"
		use thesaurus && plugins="${plugins} aiksaurus"
		use wmf && plugins="${plugins} wmf"
		# wordperfect: >=wpd-0.8 >=wps-0.1
		use wordperfect && plugins="${plugins} wpg"
	fi

	gnome2_src_configure --enable-plugins="$(echo ${plugins})"
}

src_prepare() {
	gnome2_src_prepare

	# install icon to pixmaps (bug #220097)
	sed 's:icondir= $(datadir)/icons:icondir = $(datadir)/pixmaps:' \
		-i Makefile.am Makefile.in || die "sed 1 failed"
	# readme.txt will be installed using dodoc
	sed '/readme\.txt\|abw/d' \
		-i user/wp/Makefile.am user/wp/Makefile.in || die "sed 2 failed"
}

src_install() {
	gnome2_src_install

	sed "s:Exec=abiword:Exec=abiword-${MY_MAJORV}:" \
		-i "${D}"/usr/share/applications/abiword.desktop || die "sed 3 failed"

	mv "${D}/usr/bin/abiword" "${D}/usr/bin/AbiWord-${MY_MAJORV}"
	dosym AbiWord-${MY_MAJORV} /usr/bin/abiword-${MY_MAJORV}

	dodoc AUTHORS user/wp/readme.txt || die "dodoc failed"

	# Not needed
	find "${D}" -name "*.la" -delete || die "failed *.la removal"
}

pkg_postinst() {
	gnome2_pkg_postinst

	alternatives_auto_makesym "/usr/bin/abiword" "/usr/bin/abiword-[0-9].[0-9]"
}

pkg_postrm() {
	gnome2_pkg_postrm

	alternatives_auto_makesym "/usr/bin/abiword" "/usr/bin/abiword-[0-9].[0-9]"
}